excel-vba
Metody znajdowania ostatnio używanego wiersza lub kolumny w arkuszu

Uwagi

Znajdź ostatnią niepustą komórkę w kolumnie

W tym przykładzie przyjrzymy się metodzie zwracania ostatniego niepustego wiersza w kolumnie dla zestawu danych.

Ta metoda będzie działać niezależnie od pustych regionów w zestawie danych.

Należy jednak zachować ostrożność, jeśli w grę wchodzą scalone komórki , ponieważ metoda End zostanie „zatrzymana” przeciwko scalonemu regionowi, zwracając pierwszą komórkę scalonego regionu.

Ponadto niepuste komórki w ukrytych wierszach nie będą brane pod uwagę.

Sub FindingLastRow()
    Dim wS As Worksheet, LastRow As Long
    Set wS = ThisWorkbook.Worksheets("Sheet1")
    
    'Here we look in Column A
    LastRow = wS.Cells(wS.Rows.Count, "A").End(xlUp).Row
    Debug.Print LastRow
End Sub

Aby rozwiązać powyższe ograniczenia, wiersz:
LastRow = wS.Cells(wS.Rows.Count, "A").End(xlUp).Row

można zastąpić:

1. dla ostatnio używanego wiersza "Sheet1" :
   LastRow = wS.UsedRange.Row - 1 + wS.UsedRange.Rows.Count .

2. dla ostatniej niepustej komórki kolumny "A" w "Sheet1" :

    Dim i As Long
    For i = LastRow To 1 Step -1
        If Not (IsEmpty(Cells(i, 1))) Then Exit For
    Next i
    LastRow = i
   

Znajdź ostatni wiersz za pomocą nazwanego zakresu

Jeśli masz w arkuszu Nazwany zakres i chcesz dynamicznie uzyskać ostatni rząd tego Dynamicznego Nazwanego zakresu. Obejmuje również przypadki, w których Nazwany zakres nie zaczyna się od pierwszego rzędu.

Sub FindingLastRow()
    
Dim sht As Worksheet
Dim LastRow As Long
Dim FirstRow As Long

Set sht = ThisWorkbook.Worksheets("form")

'Using Named Range "MyNameRange"
FirstRow = sht.Range("MyNameRange").Row

' in case "MyNameRange" doesn't start at Row 1
LastRow = sht.Range("MyNameRange").Rows.count + FirstRow - 1

End Sub

Aktualizacja:
Potencjalna luka została wskazana przez @Jeeped dla nazwanego zakresu z niesąsiadującymi wierszami, ponieważ generuje nieoczekiwany wynik. Aby rozwiązać ten problem, kod został zmieniony jak poniżej.
Założenia: kieruje arkusz = form , o nazwie zakres = MyNameRange

Sub FindingLastRow()
    Dim rw As Range, rwMax As Long
    For Each rw In Sheets("form").Range("MyNameRange").Rows
        If rw.Row > rwMax Then rwMax = rw.Row
    Next
    MsgBox "Last row of 'MyNameRange' under Sheets 'form': " & rwMax
End Sub

Uzyskaj wiersz ostatniej komórki z zakresu

'if only one area (not multiple areas):
With Range("A3:D20")
    Debug.Print .Cells(.Cells.CountLarge).Row
    Debug.Print .Item(.Cells.CountLarge).Row 'using .item is also possible
End With 'Debug prints: 20

'with multiple areas (also works if only one area):
Dim rngArea As Range, LastRow As Long
With Range("A3:D20, E5:I50, H20:R35")
    For Each rngArea In .Areas
        If rngArea(rngArea.Cells.CountLarge).Row > LastRow Then 
            LastRow = rngArea(rngArea.Cells.CountLarge).Row
        End If
    Next
    Debug.Print LastRow 'Debug prints: 50
End With

Znajdź ostatnią niepustą kolumnę w arkuszu

Private Sub Get_Last_Used_Row_Index()
    Dim wS As Worksheet
    
    Set wS = ThisWorkbook.Sheets("Sheet1")
    Debug.Print LastCol_1(wS)
    Debug.Print LastCol_0(wS)
End Sub

Możesz wybrać jedną z 2 opcji, jeśli chcesz wiedzieć, czy w arkuszu nie ma danych:

• NIE: Użyj LastCol_1: Możesz używać go bezpośrednio w wS.Cells(...,LastCol_1(wS))
• TAK: Użyj LastCol_0: Przed użyciem musisz sprawdzić, czy wynik uzyskany z funkcji wynosi 0, czy nie

Public Function LastCol_1(wS As Worksheet) As Double
    With wS
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            LastCol_1 = .Cells.Find(What:="*", _
                                After:=.Range("A1"), _
                                Lookat:=xlPart, _
                                LookIn:=xlFormulas, _
                                SearchOrder:=xlByColumns, _
                                SearchDirection:=xlPrevious, _
                                MatchCase:=False).Column
        Else
            LastCol_1 = 1
        End If
    End With
End Function

Właściwości obiektu Err są automatycznie zerowane po wyjściu z funkcji.

Public Function LastCol_0(wS As Worksheet) As Double
    On Error Resume Next
    LastCol_0 = wS.Cells.Find(What:="*", _
                            After:=ws.Range("A1"), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByColumns, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Column
End Function

Ostatnia komórka w Range.CurrentRegion

Range.CurrentRegion to prostokątny obszar zasięgu otoczony pustymi komórkami. Puste komórki z formułami takimi jak ="" lub ' nie są uważane za puste (nawet przez ISBLANK Excel ISBLANK ).

Dim rng As Range, lastCell As Range
Set rng = Range("C3").CurrentRegion       ' or Set rng = Sheet1.UsedRange.CurrentRegion
Set lastCell = rng(rng.Rows.Count, rng.Columns.Count)

Znajdź ostatni niepusty wiersz w arkuszu

Private Sub Get_Last_Used_Row_Index()
    Dim wS As Worksheet
    
    Set wS = ThisWorkbook.Sheets("Sheet1")
    Debug.Print LastRow_1(wS)
    Debug.Print LastRow_0(wS)
End Sub

Możesz wybrać jedną z 2 opcji, jeśli chcesz wiedzieć, czy w arkuszu nie ma danych:

• NIE: Użyj LastRow_1: Możesz go używać bezpośrednio w wS.Cells(LastRow_1(wS),...)
• TAK: Użyj LastRow_0: Przed użyciem musisz sprawdzić, czy wynik uzyskany z funkcji wynosi 0, czy nie

Public Function LastRow_1(wS As Worksheet) As Double
    With wS
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            LastRow_1 = .Cells.Find(What:="*", _
                                After:=.Range("A1"), _
                                Lookat:=xlPart, _
                                LookIn:=xlFormulas, _
                                SearchOrder:=xlByRows, _
                                SearchDirection:=xlPrevious, _
                                MatchCase:=False).Row
        Else
            LastRow_1 = 1
        End If
    End With
End Function

Public Function LastRow_0(wS As Worksheet) As Double
    On Error Resume Next
    LastRow_0 = wS.Cells.Find(What:="*", _
                            After:=ws.Range("A1"), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Row
End Function

Znajdź ostatnią niepustą komórkę z rzędu

W tym przykładzie przyjrzymy się metodzie zwracania ostatniej niepustej kolumny z rzędu.

Ta metoda będzie działać niezależnie od pustych regionów w zestawie danych.

Należy jednak zachować ostrożność, jeśli w grę wchodzą scalone komórki , ponieważ metoda End zostanie „zatrzymana” przeciwko scalonemu regionowi, zwracając pierwszą komórkę scalonego regionu.

Ponadto niepuste komórki w ukrytych kolumnach nie będą brane pod uwagę.

Sub FindingLastCol()
    Dim wS As Worksheet, LastCol As Long
    Set wS = ThisWorkbook.Worksheets("Sheet1")
    
    'Here we look in Row 1
    LastCol = wS.Cells(1, wS.Columns.Count).End(xlToLeft).Column
    Debug.Print LastCol
End Sub

Znajdź ostatnią niepustą komórkę w arkuszu - wydajność (macierz)

• Pierwsza funkcja, wykorzystująca tablicę, jest znacznie szybsza
• Jeśli zostanie wywołany bez opcjonalnego parametru, domyślnie będzie to .ThisWorkbook.ActiveSheet
• Jeśli zakres jest pusty, zwróci Cell( 1, 1 ) jako domyślną, zamiast Nothing

Prędkość:

GetMaxCell (Array): Duration: 0.0000790063 seconds
GetMaxCell (Find ): Duration: 0.0002903480 seconds

Mierzone za pomocą MicroTimer

Public Function GetLastCell(Optional ByVal ws As Worksheet = Nothing) As Range
    Dim uRng As Range, uArr As Variant, r As Long, c As Long
    Dim ubR As Long, ubC As Long, lRow As Long

    If ws Is Nothing Then Set ws = Application.ThisWorkbook.ActiveSheet
    Set uRng = ws.UsedRange
    uArr = uRng
    If IsEmpty(uArr) Then
        Set GetLastCell = ws.Cells(1, 1):   Exit Function
    End If
    If Not IsArray(uArr) Then
        Set GetLastCell = ws.Cells(uRng.Row, uRng.Column):  Exit Function
    End If
    ubR = UBound(uArr, 1):  ubC = UBound(uArr, 2)
    For r = ubR To 1 Step -1    '----------------------------------------------- last row
        For c = ubC To 1 Step -1
            If Not IsError(uArr(r, c)) Then
                If Len(Trim$(uArr(r, c))) > 0 Then
                    lRow = r:   Exit For
                End If
            End If
        Next
        If lRow > 0 Then Exit For
    Next
    If lRow = 0 Then lRow = ubR
    For c = ubC To 1 Step -1    '----------------------------------------------- last col
        For r = lRow To 1 Step -1
            If Not IsError(uArr(r, c)) Then
                If Len(Trim$(uArr(r, c))) > 0 Then
                    Set GetLastCell = ws.Cells(lRow + uRng.Row - 1, c + uRng.Column - 1)
                    Exit Function
                End If
            End If
        Next
    Next
End Function

'Returns last cell (max row & max col) using Find

Public Function GetMaxCell2(Optional ByRef rng As Range = Nothing) As Range 'Using Find

    Const NONEMPTY As String = "*"

    Dim lRow As Range, lCol As Range

    If rng Is Nothing Then Set rng = Application.ThisWorkbook.ActiveSheet.UsedRange

    If WorksheetFunction.CountA(rng) = 0 Then
        Set GetMaxCell2 = rng.Parent.Cells(1, 1)
    Else
        With rng
            Set lRow = .Cells.Find(What:=NONEMPTY, LookIn:=xlFormulas, _
                                        After:=.Cells(1, 1), _
                                        SearchDirection:=xlPrevious, _
                                        SearchOrder:=xlByRows)
            If Not lRow Is Nothing Then
                Set lCol = .Cells.Find(What:=NONEMPTY, LookIn:=xlFormulas, _
                                            After:=.Cells(1, 1), _
                                            SearchDirection:=xlPrevious, _
                                            SearchOrder:=xlByColumns)

                Set GetMaxCell2 = .Parent.Cells(lRow.Row, lCol.Column)
            End If
        End With
    End If
End Function

.

MicroTimer :

Private Declare PtrSafe Function getFrequency Lib "Kernel32" Alias "QueryPerformanceFrequency" (cyFrequency As Currency) As Long
Private Declare PtrSafe Function getTickCount Lib "Kernel32" Alias "QueryPerformanceCounter" (cyTickCount As Currency) As Long

Function MicroTimer() As Double
    Dim cyTicks1 As Currency
    Static cyFrequency As Currency

    MicroTimer = 0
    If cyFrequency = 0 Then getFrequency cyFrequency        'Get frequency
    getTickCount cyTicks1                                   'Get ticks
    If cyFrequency Then MicroTimer = cyTicks1 / cyFrequency 'Returns Seconds
End Function