excel-vba
वर्कशीट में लास्ट यूज्ड रो या कॉलम को खोजने के तरीके

टिप्पणियों

एक कॉलम में अंतिम गैर-खाली सेल खोजें

इस उदाहरण में, हम डेटा सेट के लिए एक कॉलम में अंतिम गैर-खाली पंक्ति को वापस करने के लिए एक विधि देखेंगे।

यह विधि डेटा सेट के भीतर खाली क्षेत्रों की परवाह किए बिना काम करेगी।

हालांकि सावधानी बरती जानी चाहिए यदि विलय की गई कोशिकाएँ शामिल हैं , क्योंकि End विधि को विलय किए गए क्षेत्र के खिलाफ "रोका" जाएगा, जो विलय किए गए क्षेत्र की पहली सेल को लौटाएगा।

इसके अलावा छिपी हुई पंक्तियों में गैर-खाली कोशिकाओं को ध्यान में नहीं रखा जाएगा।

Sub FindingLastRow()
    Dim wS As Worksheet, LastRow As Long
    Set wS = ThisWorkbook.Worksheets("Sheet1")
    
    'Here we look in Column A
    LastRow = wS.Cells(wS.Rows.Count, "A").End(xlUp).Row
    Debug.Print LastRow
End Sub

ऊपर दी गई सीमाओं को संबोधित करने के लिए, लाइन:
LastRow = wS.Cells(wS.Rows.Count, "A").End(xlUp).Row

इसके साथ प्रतिस्थापित किया जा सकता है:

1. "Sheet1" की अंतिम प्रयुक्त पंक्ति के लिए:
   LastRow = wS.UsedRange.Row - 1 + wS.UsedRange.Rows.Count ।

2. "Sheet1" में कॉलम "A" के अंतिम गैर-रिक्त सेल के लिए:

    Dim i As Long
    For i = LastRow To 1 Step -1
        If Not (IsEmpty(Cells(i, 1))) Then Exit For
    Next i
    LastRow = i
   

नामांकित सीमा का उपयोग करके अंतिम पंक्ति खोजें

यदि आपकी शीट में कोई नामांकित श्रेणी है, और आप डायनामिक रूप से उस डायनामिक नाम सीमा की अंतिम पंक्ति प्राप्त करना चाहते हैं। उन मामलों को भी शामिल करता है जहां नामांकित सीमा पहले पंक्ति से शुरू नहीं होती है।

Sub FindingLastRow()
    
Dim sht As Worksheet
Dim LastRow As Long
Dim FirstRow As Long

Set sht = ThisWorkbook.Worksheets("form")

'Using Named Range "MyNameRange"
FirstRow = sht.Range("MyNameRange").Row

' in case "MyNameRange" doesn't start at Row 1
LastRow = sht.Range("MyNameRange").Rows.count + FirstRow - 1

End Sub

अपडेट करें:
एक संभावित खामी को गैर-सन्निहित पंक्तियों के साथ @ नामित श्रेणी के लिए @Jeeped द्वारा इंगित किया गया था क्योंकि यह अप्रत्याशित परिणाम उत्पन्न करता है। उस समस्या को हल करने के लिए, कोड नीचे के रूप में संशोधित किया गया है।
मान: टैरिज शीट = form , नामित श्रेणी = MyNameRange

Sub FindingLastRow()
    Dim rw As Range, rwMax As Long
    For Each rw In Sheets("form").Range("MyNameRange").Rows
        If rw.Row > rwMax Then rwMax = rw.Row
    Next
    MsgBox "Last row of 'MyNameRange' under Sheets 'form': " & rwMax
End Sub

एक सीमा में अंतिम सेल की पंक्ति प्राप्त करें

'if only one area (not multiple areas):
With Range("A3:D20")
    Debug.Print .Cells(.Cells.CountLarge).Row
    Debug.Print .Item(.Cells.CountLarge).Row 'using .item is also possible
End With 'Debug prints: 20

'with multiple areas (also works if only one area):
Dim rngArea As Range, LastRow As Long
With Range("A3:D20, E5:I50, H20:R35")
    For Each rngArea In .Areas
        If rngArea(rngArea.Cells.CountLarge).Row > LastRow Then 
            LastRow = rngArea(rngArea.Cells.CountLarge).Row
        End If
    Next
    Debug.Print LastRow 'Debug prints: 50
End With

वर्कशीट में अंतिम गैर-खाली कॉलम खोजें

Private Sub Get_Last_Used_Row_Index()
    Dim wS As Worksheet
    
    Set wS = ThisWorkbook.Sheets("Sheet1")
    Debug.Print LastCol_1(wS)
    Debug.Print LastCol_0(wS)
End Sub

आप 2 विकल्पों के बीच चयन कर सकते हैं, यदि आप जानना चाहते हैं कि क्या कार्यपत्रक में कोई डेटा नहीं है:

• NO: LastCol_1 का उपयोग करें: आप इसे सीधे wS.Cells(...,LastCol_1(wS)) भीतर उपयोग कर सकते हैं
• YES: LastCol_0 का उपयोग करें: आपको यह परीक्षण करने की आवश्यकता है कि क्या आप फ़ंक्शन से प्राप्त परिणाम का उपयोग करने से पहले 0 या नहीं है

Public Function LastCol_1(wS As Worksheet) As Double
    With wS
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            LastCol_1 = .Cells.Find(What:="*", _
                                After:=.Range("A1"), _
                                Lookat:=xlPart, _
                                LookIn:=xlFormulas, _
                                SearchOrder:=xlByColumns, _
                                SearchDirection:=xlPrevious, _
                                MatchCase:=False).Column
        Else
            LastCol_1 = 1
        End If
    End With
End Function

एरर ऑब्जेक्ट के गुण स्वचालित रूप से फ़ंक्शन एक्ज़िट पर शून्य पर रीसेट हो जाते हैं।

Public Function LastCol_0(wS As Worksheet) As Double
    On Error Resume Next
    LastCol_0 = wS.Cells.Find(What:="*", _
                            After:=ws.Range("A1"), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByColumns, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Column
End Function

रेंज में अंतिम सेल। CurrentRegion

Range.CurrentRegion एक आयताकार रेंज क्षेत्र है जो खाली कोशिकाओं से घिरा हुआ है। रिक्त सूत्र जैसे कि ="" या ' को रिक्त नहीं माना जाता है (यहां तक कि ISBLANK एक्सेल फ़ंक्शन द्वारा भी)।

Dim rng As Range, lastCell As Range
Set rng = Range("C3").CurrentRegion       ' or Set rng = Sheet1.UsedRange.CurrentRegion
Set lastCell = rng(rng.Rows.Count, rng.Columns.Count)

वर्क्सशीट में अंतिम गैर-खाली पंक्ति ढूँढें

Private Sub Get_Last_Used_Row_Index()
    Dim wS As Worksheet
    
    Set wS = ThisWorkbook.Sheets("Sheet1")
    Debug.Print LastRow_1(wS)
    Debug.Print LastRow_0(wS)
End Sub

आप 2 विकल्पों के बीच चयन कर सकते हैं, यदि आप जानना चाहते हैं कि क्या कार्यपत्रक में कोई डेटा नहीं है:

• NO: LastRow_1 का उपयोग करें: आप इसे सीधे wS.Cells(LastRow_1(wS),...) भीतर उपयोग कर सकते हैं
• हाँ: LastRow_0 का उपयोग करें: आपको यह परीक्षण करने की आवश्यकता है कि क्या आप फ़ंक्शन से प्राप्त परिणाम का उपयोग करने से पहले 0 है या नहीं

Public Function LastRow_1(wS As Worksheet) As Double
    With wS
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            LastRow_1 = .Cells.Find(What:="*", _
                                After:=.Range("A1"), _
                                Lookat:=xlPart, _
                                LookIn:=xlFormulas, _
                                SearchOrder:=xlByRows, _
                                SearchDirection:=xlPrevious, _
                                MatchCase:=False).Row
        Else
            LastRow_1 = 1
        End If
    End With
End Function

Public Function LastRow_0(wS As Worksheet) As Double
    On Error Resume Next
    LastRow_0 = wS.Cells.Find(What:="*", _
                            After:=ws.Range("A1"), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Row
End Function

एक पंक्ति में अंतिम गैर-खाली सेल का पता लगाएं

इस उदाहरण में, हम एक पंक्ति में अंतिम गैर-रिक्त कॉलम को वापस करने के लिए एक विधि देखेंगे।

यह विधि डेटा सेट के भीतर खाली क्षेत्रों की परवाह किए बिना काम करेगी।

हालांकि सावधानी बरती जानी चाहिए यदि विलय की गई कोशिकाएँ शामिल हैं , क्योंकि End विधि को विलय किए गए क्षेत्र के खिलाफ "रोका" जाएगा, जो विलय किए गए क्षेत्र की पहली सेल को लौटाएगा।

इसके अलावा छिपे हुए स्तंभों में गैर-खाली कोशिकाओं को ध्यान में नहीं रखा जाएगा।

Sub FindingLastCol()
    Dim wS As Worksheet, LastCol As Long
    Set wS = ThisWorkbook.Worksheets("Sheet1")
    
    'Here we look in Row 1
    LastCol = wS.Cells(1, wS.Columns.Count).End(xlToLeft).Column
    Debug.Print LastCol
End Sub

वर्कशीट में अंतिम गैर-खाली सेल खोजें - प्रदर्शन (सरणी)

• सरणी का उपयोग करते हुए पहला फ़ंक्शन बहुत तेज़ है
• यदि वैकल्पिक पैरामीटर के बिना कॉल किया जाता है, तो यह .ThisWorkbook.ActiveSheet डिफ़ॉल्ट होगा
• यदि रेंज खाली है Cell( 1, 1 ) Nothing बजाय डिफ़ॉल्ट रूप से वापस आ जाएगी

गति:

GetMaxCell (Array): Duration: 0.0000790063 seconds
GetMaxCell (Find ): Duration: 0.0002903480 seconds

। MicroTimer के साथ बनाया गया

Public Function GetLastCell(Optional ByVal ws As Worksheet = Nothing) As Range
    Dim uRng As Range, uArr As Variant, r As Long, c As Long
    Dim ubR As Long, ubC As Long, lRow As Long

    If ws Is Nothing Then Set ws = Application.ThisWorkbook.ActiveSheet
    Set uRng = ws.UsedRange
    uArr = uRng
    If IsEmpty(uArr) Then
        Set GetLastCell = ws.Cells(1, 1):   Exit Function
    End If
    If Not IsArray(uArr) Then
        Set GetLastCell = ws.Cells(uRng.Row, uRng.Column):  Exit Function
    End If
    ubR = UBound(uArr, 1):  ubC = UBound(uArr, 2)
    For r = ubR To 1 Step -1    '----------------------------------------------- last row
        For c = ubC To 1 Step -1
            If Not IsError(uArr(r, c)) Then
                If Len(Trim$(uArr(r, c))) > 0 Then
                    lRow = r:   Exit For
                End If
            End If
        Next
        If lRow > 0 Then Exit For
    Next
    If lRow = 0 Then lRow = ubR
    For c = ubC To 1 Step -1    '----------------------------------------------- last col
        For r = lRow To 1 Step -1
            If Not IsError(uArr(r, c)) Then
                If Len(Trim$(uArr(r, c))) > 0 Then
                    Set GetLastCell = ws.Cells(lRow + uRng.Row - 1, c + uRng.Column - 1)
                    Exit Function
                End If
            End If
        Next
    Next
End Function

'Returns last cell (max row & max col) using Find

Public Function GetMaxCell2(Optional ByRef rng As Range = Nothing) As Range 'Using Find

    Const NONEMPTY As String = "*"

    Dim lRow As Range, lCol As Range

    If rng Is Nothing Then Set rng = Application.ThisWorkbook.ActiveSheet.UsedRange

    If WorksheetFunction.CountA(rng) = 0 Then
        Set GetMaxCell2 = rng.Parent.Cells(1, 1)
    Else
        With rng
            Set lRow = .Cells.Find(What:=NONEMPTY, LookIn:=xlFormulas, _
                                        After:=.Cells(1, 1), _
                                        SearchDirection:=xlPrevious, _
                                        SearchOrder:=xlByRows)
            If Not lRow Is Nothing Then
                Set lCol = .Cells.Find(What:=NONEMPTY, LookIn:=xlFormulas, _
                                            After:=.Cells(1, 1), _
                                            SearchDirection:=xlPrevious, _
                                            SearchOrder:=xlByColumns)

                Set GetMaxCell2 = .Parent.Cells(lRow.Row, lCol.Column)
            End If
        End With
    End If
End Function

।

माइक्रोटीमर :

Private Declare PtrSafe Function getFrequency Lib "Kernel32" Alias "QueryPerformanceFrequency" (cyFrequency As Currency) As Long
Private Declare PtrSafe Function getTickCount Lib "Kernel32" Alias "QueryPerformanceCounter" (cyTickCount As Currency) As Long

Function MicroTimer() As Double
    Dim cyTicks1 As Currency
    Static cyFrequency As Currency

    MicroTimer = 0
    If cyFrequency = 0 Then getFrequency cyFrequency        'Get frequency
    getTickCount cyTicks1                                   'Get ticks
    If cyFrequency Then MicroTimer = cyTicks1 / cyFrequency 'Returns Seconds
End Function