VBA
दिनांक समय हेरफेर

पंचांग

वीबीए 2 कैलेंडर का समर्थन करता है: ग्रेगोरियन और हिजरी

Calendar गुण का उपयोग वर्तमान कैलेंडर को संशोधित या प्रदर्शित करने के लिए किया जाता है।

कैलेंडर के लिए 2 मान हैं:

उदाहरण

Sub CalendarExample()
    'Cache the current setting.
    Dim Cached As Integer
    Cached = Calendar

    ' Dates in Gregorian Calendar
    Calendar = vbCalGreg
    Dim Sample As Date
    'Create sample date of 2016-07-28
    Sample = DateSerial(2016, 7, 28)

    Debug.Print "Current Calendar : " & Calendar
    Debug.Print "SampleDate = " & Format$(Sample, "yyyy-mm-dd")
    
    ' Date in Hijri Calendar
    Calendar = vbCalHijri
    Debug.Print "Current Calendar : " & Calendar
    Debug.Print "SampleDate = " & Format$(Sample, "yyyy-mm-dd")
    
    'Reset VBA to cached value.
    Cached = Calendar
End Sub

यह उप निम्नलिखित को प्रिंट करता है;

Current Calendar : 0
SampleDate = 2016-07-28
Current Calendar : 1
SampleDate = 1437-10-23

आधार कार्य

सिस्टम डेटाइम प्राप्त करें

VBA सिस्टम की घड़ी से दिनांक और / या समय को पुनः प्राप्त करने के लिए 3 अंतर्निहित कार्यों का समर्थन करता है।

Sub DateTimeExample()

    ' -----------------------------------------------------
    ' Note : EU system with default date format DD/MM/YYYY
    ' -----------------------------------------------------
    
    Debug.Print Now   ' prints 28/07/2016 10:16:01 (output below assumes this date and time)
    Debug.Print Date  ' prints 28/07/2016
    Debug.Print Time  ' prints 10:16:01
    
    ' Apply a custom format to the current date or time
    Debug.Print Format$(Now, "dd mmmm yyyy hh:nn")  ' prints 28 July 2016 10:16
    Debug.Print Format$(Date, "yyyy-mm-dd")         ' prints 2016-07-28
    Debug.Print Format$(Time, "hh") & " hour " & _
                Format$(Time, "nn") & " min " & _
                Format$(Time, "ss") & " sec "       ' prints 10 hour 16 min 01 sec
    
End Sub

टाइमर समारोह

Timer फ़ंक्शन आधी रात के बाद से बीते हुए सेकंड की संख्या का प्रतिनिधित्व करने वाला एकल देता है। सटीकता एक सेकंड का एक सौवां हिस्सा है।

Sub TimerExample()

    Debug.Print Time    ' prints 10:36:31  (time at execution)
    Debug.Print Timer   ' prints 38191,13  (seconds since midnight)

End Sub

क्योंकि Now और Time कार्य केवल सेकंड के लिए सटीक हैं, Timer समय माप की सटीकता बढ़ाने के लिए एक सुविधाजनक तरीका प्रदान करता है:

Sub GetBenchmark()
       
    Dim StartTime  As Single
    StartTime = Timer       'Store the current Time
    
    Dim i As Long
    Dim temp As String
    For i = 1 To 1000000    'See how long it takes Left$ to execute 1,000,000 times
        temp = Left$("Text", 2)
    Next i
    
    Dim Elapsed As Single
    Elapsed = Timer - StartTime
    Debug.Print "Code completed in " & CInt(Elapsed * 1000) & " ms"

End Sub

IsDate ()

IsDate () परीक्षण करता है कि कोई अभिव्यक्ति वैध तिथि है या नहीं। एक Boolean लौटाता है।

Sub IsDateExamples()

    Dim anything As Variant
       
    anything = "September 11, 2001"

    Debug.Print IsDate(anything)    'Prints True
            
    anything = #9/11/2001#

    Debug.Print IsDate(anything)    'Prints True
   
    anything = "just a string"

    Debug.Print IsDate(anything)    'Prints False

    anything = vbNull
    
    Debug.Print IsDate(anything)    'Prints False
    
End Sub

निष्कर्षण कार्य

ये फ़ंक्शंस एक Variant लेते हैं जिसे एक पैरामीटर के रूप में एक Date डाला जा सकता है और एक डेट या समय के हिस्से का प्रतिनिधित्व करने वाले Integer वापस कर सकता है। यदि पैरामीटर किसी Date को नहीं डाला जा सकता है, तो यह एक रन-टाइम त्रुटि 13 में परिणाम देगा: मिसमैच टाइप करें।

उदाहरण:

Sub ExtractionExamples()

    Dim MyDate As Date
    
    MyDate = DateSerial(2016, 7, 28) + TimeSerial(12, 34, 56)

    Debug.Print Format$(MyDate, "yyyy-mm-dd hh:nn:ss") ' prints 2016-07-28 12:34:56

    Debug.Print Year(MyDate)                           ' prints 2016
    Debug.Print Month(MyDate)                          ' prints 7
    Debug.Print Day(MyDate)                            ' prints 28
    Debug.Print Hour(MyDate)                           ' prints 12
    Debug.Print Minute(MyDate)                         ' prints 34
    Debug.Print Second(MyDate)                         ' prints 56
    
    Debug.Print Weekday(MyDate)                        ' prints 5
    'Varies by locale - i.e. will print 4 in the EU and 5 in the US
    Debug.Print Weekday(MyDate, vbUseSystemDayOfWeek)
    Debug.Print Weekday(MyDate, vbMonday)              ' prints 4
    Debug.Print Weekday(MyDate, vbSunday)              ' prints 5
    
End Sub

DatePart () फ़ंक्शन

DatePart() भी एक तारीख का एक हिस्सा लौटाने वाला एक फ़ंक्शन है, लेकिन अलग-अलग काम करता है और उपरोक्त कार्यों की तुलना में अधिक संभावनाएं देता है। उदाहरण के लिए, वर्ष का तिमाही या वर्ष का सप्ताह लौटा सकता है।

वाक्य - विन्यास:

DatePart ( interval, date  [, firstdayofweek] [, firstweekofyear] )

अंतराल तर्क हो सकता है:

Firstdayofweek वैकल्पिक है। यह एक स्थिरांक है जो सप्ताह के पहले दिन को निर्दिष्ट करता है। यदि निर्दिष्ट नहीं है, तो vbSunday मान लिया गया है।

Firstweekofyear वैकल्पिक है। यह एक स्थिरांक है जो वर्ष के पहले सप्ताह को निर्दिष्ट करता है। यदि निर्दिष्ट नहीं किया गया है, तो पहले सप्ताह को वह सप्ताह माना जाता है जिसमें 1 जनवरी होता है।

उदाहरण:

Sub DatePartExample()

    Dim MyDate As Date
    
    MyDate = DateSerial(2016, 7, 28) + TimeSerial(12, 34, 56)

    Debug.Print Format$(MyDate, "yyyy-mm-dd hh:nn:ss") ' prints 2016-07-28 12:34:56
    
    Debug.Print DatePart("yyyy", MyDate)              ' prints 2016
    Debug.Print DatePart("y", MyDate)                 ' prints 210
    Debug.Print DatePart("h", MyDate)                 ' prints 12
    Debug.Print DatePart("Q", MyDate)                 ' prints 3
    Debug.Print DatePart("w", MyDate)                 ' prints 5
    Debug.Print DatePart("ww", MyDate)                ' prints 31

End Sub

गणना कार्य

DateDiff ()

DateDiff() दो निर्दिष्ट तिथियों के बीच समय अंतराल की संख्या का प्रतिनिधित्व करने वाला एक Long रिटर्न देता है।

वाक्य - विन्यास

DateDiff ( interval, date1, date2  [, firstdayofweek] [, firstweekofyear] )

• अंतराल DatePart() फ़ंक्शन में परिभाषित अंतरालों में से कोई भी हो सकता है
• तारीख 1 और तारीख 2 वह दो तारीखें हैं जिनका आप गणना में उपयोग करना चाहते हैं
• firstdayofweek और firstweekofyear वैकल्पिक हैं। स्पष्टीकरण के लिए DatePart() फ़ंक्शन का संदर्भ लें

उदाहरण

Sub DateDiffExamples()

    ' Check to see if 2016 is a leap year.
    Dim NumberOfDays As Long
    NumberOfDays = DateDiff("d", #1/1/2016#, #1/1/2017#)
    
    If NumberOfDays = 366 Then
        Debug.Print "2016 is a leap year."              'This will output.
    End If
           
    ' Number of seconds in a day
    Dim StartTime As Date
    Dim EndTime As Date
    StartTime = TimeSerial(0, 0, 0)
    EndTime = TimeSerial(24, 0, 0)
    Debug.Print DateDiff("s", StartTime, EndTime)       'prints 86400

End Sub

DATEADD ()

DateAdd() एक Date लौटाता है जिसमें एक निर्दिष्ट तिथि या समय अंतराल जोड़ा गया है।

वाक्य - विन्यास

DateAdd ( interval, number, date  ) 

• अंतराल DatePart() फ़ंक्शन में परिभाषित अंतरालों में से कोई भी हो सकता है
• संख्या संख्यात्मक अभिव्यक्ति जो अंतराल आप जोड़ना चाहते हैं की संख्या है। यह सकारात्मक हो सकता है (भविष्य में तारीखें प्राप्त करने के लिए) या नकारात्मक (अतीत में तारीखें प्राप्त करने के लिए)।
• दिनांक एक Date या शाब्दिक प्रतिनिधित्व तिथि है जिसमें अंतराल जोड़ा जाता है

उदाहरण :

Sub DateAddExamples()

    Dim Sample As Date
    'Create sample date and time of 2016-07-28 12:34:56
    Sample = DateSerial(2016, 7, 28) + TimeSerial(12, 34, 56)
    
    ' Date 5 months previously (prints 2016-02-28):
    Debug.Print Format$(DateAdd("m", -5, Sample), "yyyy-mm-dd")
    
    ' Date 10 months previously (prints 2015-09-28):
    Debug.Print Format$(DateAdd("m", -10, Sample), "yyyy-mm-dd")
    
    ' Date in 8 months (prints 2017-03-28):
    Debug.Print Format$(DateAdd("m", 8, Sample), "yyyy-mm-dd")

    ' Date/Time 18 hours previously (prints 2016-07-27 18:34:56):
    Debug.Print Format$(DateAdd("h", -18, Sample), "yyyy-mm-dd hh:nn:ss")
    
    ' Date/Time in 36 hours (prints 2016-07-30 00:34:56):
    Debug.Print Format$(DateAdd("h", 36, Sample), "yyyy-mm-dd hh:nn:ss")

End Sub

रूपांतरण और निर्माण

CDate ()

CDate() किसी भी डेटाटाइप से किसी Date CDate() परिवर्तित करता है

Sub CDateExamples()

    Dim sample As Date

    ' Converts a String representing a date and time to a Date
    sample = CDate("September 11, 2001 12:34")
    Debug.Print Format$(sample, "yyyy-mm-dd hh:nn:ss")      ' prints 2001-09-11 12:34:00
    
    ' Converts a String containing a date to a Date
    sample = CDate("September 11, 2001")
    Debug.Print Format$(sample, "yyyy-mm-dd hh:nn:ss")      ' prints 2001-09-11 00:00:00

    ' Converts a String containing a time to a Date
    sample = CDate("12:34:56")
    Debug.Print Hour(sample)                        ' prints 12
    Debug.Print Minute(sample)                      ' prints 34
    Debug.Print Second(sample)                      ' prints 56
    
    ' Find the 10000th day from the epoch date of 1899-12-31
    sample = CDate(10000)
    Debug.Print Format$(sample, "yyyy-mm-dd")       ' prints 1927-05-18
    
End Sub

नोट VBA भी एक शिथिल टाइप किया है कि CVDate() के रूप में एक ही तरह से काम करता है CDate() एक तारीख लौटने के अलावा अन्य कार्य करते हैं टाइप किया Variant एक जोरदार टाइप किया के बजाय Date । CDate() संस्करण है जब एक के लिए गुजर प्राथमिकता दी जानी चाहिए Date पैरामीटर या एक को बताए Date चर, और CVDate() संस्करण जब जब एक के लिए गुजर प्राथमिकता दी जानी चाहिए Variant पैरामीटर या एक को बताए Variant चर। यह अंतर्निहित प्रकार की कास्टिंग से बचा जाता है।

DateSerial ()

DateSerial() फ़ंक्शन का उपयोग दिनांक बनाने के लिए किया जाता है। यह एक निर्दिष्ट वर्ष, महीने और दिन के लिए एक Date देता है।

वाक्य - विन्यास:

DateSerial ( year, month, day ) 

वर्ष के साथ, महीने और दिन के तर्क वैध इंटीजर (वर्ष 100 से 9999 तक, माह 1 से 12 तक, दिन 1 से 31 तक)।

उदाहरण

Sub DateSerialExamples()

    ' Build a specific date
    Dim sample As Date
    sample = DateSerial(2001, 9, 11)
    Debug.Print Format$(sample, "yyyy-mm-dd")                   ' prints 2001-09-11
    
    ' Find the first day of the month for a date.
    sample = DateSerial(Year(sample), Month(sample), 1)
    Debug.Print Format$(sample, "yyyy-mm-dd")                   ' prints 2001-09-11
    
    ' Find the last day of the previous month.
    sample = DateSerial(Year(sample), Month(sample), 1) - 1
    Debug.Print Format$(sample, "yyyy-mm-dd")                   ' prints 2001-09-11
    
End Sub

ध्यान दें कि DateSerial() "अमान्य" तिथियों को स्वीकार करेगा और इसकी वैध तिथि की गणना करेगा। यह रचनात्मक रूप से अच्छे के लिए इस्तेमाल किया जा सकता है:

सकारात्मक उदाहरण

Sub GoodDateSerialExample()

    'Calculate 45 days from today
    Dim today As Date
    today = DateSerial (2001, 9, 11)
    Dim futureDate As Date
    futureDate = DateSerial(Year(today), Month(today), Day(today) + 45)
    Debug.Print Format$(futureDate, "yyyy-mm-dd")            'prints 2009-10-26

End Sub

हालाँकि, यह तब होने की संभावना अधिक होती है जब अनलिमिटेड यूजर इनपुट से डेट बनाने का प्रयास किया जाता है:

नकारात्मक उदाहरण

Sub BadDateSerialExample()

    'Allow user to enter unvalidate date information
    Dim myYear As Long
    myYear = InputBox("Enter Year")                                         
            'Assume user enters 2009
    Dim myMonth As Long
    myMonth = InputBox("Enter Month")                                       
            'Assume user enters 2
    Dim myDay As Long
    myDay = InputBox("Enter Day")                                           
            'Assume user enters 31
    Debug.Print Format$(DateSerial(myYear, myMonth, myDay), "yyyy-mm-dd")   
            'prints  2009-03-03

End Sub