VBA
प्रवाह नियंत्रण संरचनाएं

मामले का चयन करें

Select Case का उपयोग तब किया जा सकता है जब कई अलग-अलग स्थितियां संभव हों। शर्तों को ऊपर से नीचे तक जांचा जाता है और केवल पहला मामला जो मैच निष्पादित किया जाएगा।

Sub TestCase()
    Dim MyVar As String

    Select Case MyVar    'We Select the Variable MyVar to Work with
        Case "Hello"     'Now we simply check the cases we want to check
            MsgBox "This Case"
        Case "World"
            MsgBox "Important"
        Case "How"
            MsgBox "Stuff"
        Case "Are"
            MsgBox "I'm running out of ideas"
        Case "You?", "Today"  'You can separate several conditions with a comma
            MsgBox "Uuuhm..." 'if any is matched it will go into the case
        Case Else             'If none of the other cases is hit
            MsgBox "All of the other cases failed"
    End Select

    Dim i As Integer
    Select Case i
        Case Is > 2 '"Is" can be used instead of the variable in conditions.
            MsgBox "i is greater than 2"
        'Case 2 < Is '"Is" can only be used at the beginning of the condition.
        'Case Else is optional
    End Select
End Sub

Select Case ब्लॉक के तर्क को विभिन्न चर के परीक्षण का समर्थन करने के लिए उलटा किया जा सकता है, इस तरह के परिदृश्य में हम तार्किक निदेशकों के साथ भी काम कर सकते हैं:

Dim x As Integer
Dim y As Integer

x = 2
y = 5

Select Case True
    Case x > 3
        MsgBox "x is greater than 3"
    Case y < 2
        MsgBox "y is less than 2"
    Case x = 1
        MsgBox "x is equal to 1"
    Case x = 2 Xor y = 3
        MsgBox "Go read about ""Xor"""
    Case Not y = 5
        MsgBox "y is not 5"
    Case x = 3 Or x = 10
        MsgBox "x = 3 or 10"
    Case y < 10 And x < 10
        MsgBox "x and y are less than 10"
    Case Else
        MsgBox "No match found"
End Select

केस स्टेटमेंट्स अंकगणितीय संचालकों का भी उपयोग कर सकते हैं। जहां एक अंकगणितीय ऑपरेटर के खिलाफ इस्तेमाल किया जा रहा है Select Case मूल्य इसके साथ होनी चाहिए Is कीवर्ड:

Dim x As Integer

x = 5

Select Case x
    Case 1
        MsgBox "x equals 1"
    Case 2, 3, 4
        MsgBox "x is 2, 3 or 4"
    Case 7 To 10
        MsgBox "x is between 7 and 10 (inclusive)"
    Case Is < 2
        MsgBox "x is less than one"
    Case Is >= 7
        MsgBox "x is greater than or equal to 7"
    Case Else
        MsgBox "no match found"
End Select

प्रत्येक पाश के लिए

For Each लूप निर्माण के लिए एक संग्रह के सभी तत्वों को पुनरावृत्त करने के लिए आदर्श है।

Public Sub IterateCollection(ByVal items As Collection)

    'For Each iterator must always be variant
    Dim element As Variant

    For Each element In items
        'assumes element can be converted to a string
        Debug.Print element
    Next

End Sub

ऑब्जेक्ट संग्रह को पुनरावृत्त करते समय For Each उपयोग करें:

Dim sheet As Worksheet
For Each sheet In ActiveWorkbook.Worksheets
    Debug.Print sheet.Name
Next

सरणियों की पुनरावृत्ति करते समय For Each बचें; For लूप सरणियों के साथ काफी बेहतर प्रदर्शन की पेशकश करेगा। इसके विपरीत, For Each लूप के For Each एक Collection पुनरावृत्ति करने पर बेहतर प्रदर्शन की पेशकश की जाएगी।

वाक्य - विन्यास

For Each [item] In [collection]
    [statements]
Next [item]

Next कीवर्ड वैकल्पिक रूप से पुनरावृत्ति चर द्वारा पीछा किया जा सकता है; यह नेस्टेड लूप्स को स्पष्ट करने में मदद कर सकता है, हालांकि नेस्टेड कोड को स्पष्ट करने के बेहतर तरीके हैं, जैसे कि आंतरिक लूप को अपनी प्रक्रिया में निकालना।

Dim book As Workbook
For Each book In Application.Workbooks

    Debug.Print book.FullName

    Dim sheet As Worksheet
    For Each sheet In ActiveWorkbook.Worksheets
        Debug.Print sheet.Name
    Next sheet
Next book

लूप करें

 Public Sub DoLoop()
    Dim entry As String
    entry = ""
    'Equivalent to a While loop will ask for strings until "Stop" in given
    'Prefer using a While loop instead of this form of Do loop
    Do While entry <> "Stop"
        entry = InputBox("Enter a string, Stop to end")
        Debug.Print entry
    Loop

    'Equivalent to the above loop, but the condition is only checked AFTER the
    'first iteration of the loop, so it will execute even at least once even 
    'if entry is equal to "Stop" before entering the loop (like in this case)
    Do
        entry = InputBox("Enter a string, Stop to end")
        Debug.Print entry
    Loop While entry <> "Stop"

    
    'Equivalent to writing Do While Not entry="Stop"
    '
    'Because the Until is at the top of the loop, it will
    'not execute because entry is still equal to "Stop"
    'when evaluating the condition
    Do Until entry = "Stop"
        entry = InputBox("Enter a string, Stop to end")
        Debug.Print entry
    Loop

    'Equivalent to writing Do ... Loop While Not i >= 100
    Do
        entry = InputBox("Enter a string, Stop to end")
        Debug.Print entry
    Loop Until entry = "Stop"
End Sub

घुमाव के दौरान

'Will return whether an element is present in the array
Public Function IsInArray(values() As String, ByVal whatToFind As String) As Boolean
    Dim i As Integer
    i = 0

    While i < UBound(values) And values(i) <> whatToFind
        i = i + 1
    Wend
    
    IsInArray = values(i) = whatToFind
End Function

पाश के लिए

For पाश कोड के संलग्न अनुभाग बार की दी गई संख्या को दोहराने के लिए प्रयोग किया जाता है। निम्नलिखित सरल उदाहरण मूल सिंटैक्स दिखाता है:

Dim i as Integer           'Declaration of i
For i = 1 to 10            'Declare how many times the loop shall be executed
    Debug.Print i          'The piece of code which is repeated
Next i                     'The end of the loop

ऊपर दिए गए कोड को इंटेगर i घोषित करता है। For लूप 1 और 10 के बीच में i प्रत्येक मान प्रदान करता है और फिर Debug.Print i कार्यान्वित करता है - अर्थात कोड 10 के माध्यम से तात्कालिक विंडो में संख्या 1 को प्रिंट करता है। ध्यान दें कि लूप वैरिएबल Next स्टेटमेंट द्वारा इंक्रीमेंट किया गया है, जो कि एन्कोड किए गए कोड के निष्पादित होने से पहले विरोध के रूप में होता है।

डिफ़ॉल्ट रूप से, लूप निष्पादित होने पर प्रत्येक बार काउंटर को 1 से बढ़ा दिया जाएगा। हालांकि, एक Step एक समारोह के एक शाब्दिक या वापसी मूल्य के रूप में वेतन वृद्धि की राशि को बदलने के लिए निर्दिष्ट किया जा सकता है। यदि प्रारंभिक मान, समाप्ति मान या Step मान एक फ़्लोटिंग पॉइंट संख्या है, तो इसे निकटतम पूर्णांक मान पर गोल किया जाएगा। Step या तो सकारात्मक या नकारात्मक मूल्य हो सकता है।

Dim i As Integer
For i = 1 To 10 Step 2
    Debug.Print i       'Prints 1, 3, 5, 7, and 9
Next

सामान्य तौर पर For लूप का उपयोग उन स्थितियों में किया जाता है, जहां लूप शुरू होने से पहले यह जाना जाता है कि संलग्न कोड को निष्पादित करने के लिए कितनी बार (अन्यथा एक Do या While लूप अधिक उपयुक्त हो सकता है)। ऐसा इसलिए है क्योंकि लूप में पहली प्रविष्टि के बाद बाहर निकलने की स्थिति ठीक हो जाती है, क्योंकि यह कोड प्रदर्शित करता है:

Private Iterations As Long              'Module scope

Public Sub Example()
    Dim i As Long
    Iterations = 10
    For i = 1 To Iterations
        Debug.Print Iterations     'Prints 10 through 1, descending.
        Iterations = Iterations - 1
    Next
End Sub

ए For लूप को Exit For स्टेटमेंट के साथ जल्दी बाहर निकाला जा सकता है:

Dim i As Integer

For i = 1 To 10
    If i > 5 Then
        Exit For
    End If
    Debug.Print i       'Prints 1, 2, 3, 4, 5 before loop exits early.
Next