VBA
घोषणा करना और तार लगाना

टिप्पणियों

एक स्ट्रिंग स्थिर घोषित करें

Const appName As String = "The App For That"

एक चर-चौड़ाई स्ट्रिंग चर घोषित करें

Dim surname As String 'surname can accept strings of variable length
surname = "Smith"
surname = "Johnson"

एक निश्चित-चौड़ाई वाली स्ट्रिंग को घोषित और असाइन करें

'Declare and assign a 1-character fixed-width string
Dim middleInitial As String * 1 'middleInitial must be 1 character in length
middleInitial = "M"

'Declare and assign a 2-character fixed-width string `stateCode`,
'must be 2 characters in length
Dim stateCode As String * 2
stateCode = "TX"

घोषणा और एक स्ट्रिंग सरणी असाइन करें

'Declare, dimension and assign a string array with 3 elements
Dim departments(2) As String
departments(0) = "Engineering"
departments(1) = "Finance"
departments(2) = "Marketing"

'Declare an undimensioned string array and then dynamically assign with
'the results of a function that returns a string array
Dim stateNames() As String
stateNames = VBA.Strings.Split("Texas;California;New York", ";")

'Declare, dimension and assign a fixed-width string array
Dim stateCodes(2) As String * 2
stateCodes(0) = "TX"
stateCodes(1) = "CA"
stateCodes(2) = "NY"

मध्य कथन का उपयोग करके एक स्ट्रिंग के भीतर विशिष्ट वर्ण निर्दिष्ट करें

VBA एक स्ट्रिंग के भीतर लौटने वाले पदार्थों के लिए एक मिड फंक्शन प्रदान करता है, लेकिन यह मिड स्टेटमेंट भी प्रदान करता है, जिसका उपयोग स्ट्रिंग के साथ सबस्ट्रिंग या व्यक्तिगत वर्णों को असाइन करने के लिए किया जा सकता है।

Mid फ़ंक्शन आम तौर पर एक असाइनमेंट स्टेटमेंट के राइट-हैंड-साइड पर या किसी कंडीशन में दिखाई देगा, लेकिन Mid स्टेटमेंट आमतौर पर एक असाइनमेंट स्टेटमेंट के लेफ्ट हैंड साइड पर दिखाई देता है।

Dim surname As String
surname = "Smith"

'Use the Mid statement to change the 3rd character in a string
Mid(surname, 3, 1) = "y"
Debug.Print surname

'Output:
'Smyth

नोट: यदि आपको स्ट्रिंग के भीतर अलग-अलग वर्णों के बजाय एक स्ट्रिंग में अलग-अलग बाइट्स को असाइन करने की आवश्यकता है (मल्टी-बाइट कैरेक्टर सेट के बारे में नीचे दिए गए रिमार्क्स देखें), MidB स्टेटमेंट का उपयोग किया जा सकता है। इस उदाहरण में, MidB स्टेटमेंट के लिए दूसरा तर्क बाइट की 1-आधारित स्थिति है, जहां प्रतिस्थापन शुरू होगा, तो ऊपर दिए गए उदाहरण के समतुल्य लाइन MidB(surname, 5, 2) = "y" ।

एक बाइट सरणी से और असाइनमेंट

स्ट्रिंग्स को सीधे बाइट एरेज़ और वीज़ा-वर्सा के लिए सौंपा जा सकता है। याद रखें कि स्ट्रिंग्स को मल्टी-बाइट कैरेक्टर सेट (नीचे रिमार्क्स देखें) में संग्रहीत किया जाता है, इसलिए परिणामी सरणी के हर दूसरे इंडेक्स में ASCII रेंज के भीतर आने वाले वर्ण का हिस्सा होगा।

Dim bytes() As Byte
Dim example As String

example = "Testing."
bytes = example             'Direct assignment.

'Loop through the characters. Step 2 is used due to wide encoding.
Dim i As Long
For i = LBound(bytes) To UBound(bytes) Step 2
    Debug.Print Chr$(bytes(i))  'Prints T, e, s, t, i, n, g, .
Next

Dim reverted As String
reverted = bytes            'Direct assignment.
Debug.Print reverted        'Prints "Testing."