excel-vba
व्यवहार में CustomDocumentProperties

परिचय

नए चालान नंबर का आयोजन

एक चालान संख्या बढ़ाना और उसके मूल्य को बचाना एक लगातार काम है। CustomDocumentProperties (CDP) का उपयोग करना एक ही कार्यपुस्तिका में ऐसे नंबरों को अपेक्षाकृत सुरक्षित तरीके से संग्रहीत करने का एक अच्छा तरीका है, लेकिन संबंधित सेल मानों को केवल असुरक्षित कार्य पत्रक में दिखाने से परहेज करना।

अतिरिक्त संकेत:

वैकल्पिक रूप से, आप एक छिपे हुए वर्कशीट में या यहां तक कि तथाकथित "बहुत ही छिपे हुए" वर्कशीट में मान दर्ज कर सकते हैं (देखें xlVeryHidden शीट्स का उपयोग करना । बेशक, यह बाहरी फ़ाइलों (जैसे आईएनआई फ़ाइल, सीएसवी या किसी अन्य प्रकार) से भी डेटा को बचाने के लिए संभव है। या रजिस्ट्री।

उदाहरण सामग्री :

नीचे दिए गए उदाहरण से पता चलता है

• एक फ़ंक्शन NextInvoiceNo सेट करता है और अगला चालान नंबर देता है,
• एक प्रक्रिया DeleteInvoiceNo, जो चालान CDP को पूरी तरह से हटा देती है, साथ ही साथ
• एक प्रक्रिया showAllCDPs सभी नामों के साथ पूरा CDPs संग्रह सूचीबद्ध करता है। VBA का उपयोग नहीं करते हुए, आप उन्हें कार्यपुस्तिका की जानकारी के माध्यम से भी सूचीबद्ध कर सकते हैं: जानकारी | गुण [ड्रॉपडाउन:] | उन्नत गुण | रिवाज

आप उपर्युक्त फ़ंक्शन को कॉल करके, अगले उपर्युक्त फ़ंक्शन को कॉल करके, अगली स्ट्रिंग नंबर को प्राप्त कर सकते हैं और सेट कर सकते हैं, ताकि उपसर्गों को जोड़ने में सुविधा हो। "इनवॉइसनो" का सभी प्रक्रियाओं में सीडीपी नाम के रूप में उपयोग किया जाता है।

Dim sNumber As String
sNumber = NextInvoiceNo ()

उदाहरण कोड:

Option Explicit

Sub Test()
  Dim sNumber As String
  sNumber = NextInvoiceNo()
  MsgBox "New Invoice No: " & sNumber, vbInformation, "New Invoice Number"
End Sub

Function NextInvoiceNo() As String
' Purpose: a) Set Custom Document Property (CDP) "InvoiceNo" if not yet existing
'          b) Increment CDP value and return new value as string
' Declarations
  Dim prop As Object
  Dim ret  As String
  Dim wb   As Workbook
' Set workbook and CDPs
  Set wb = ThisWorkbook
  Set prop = wb.CustomDocumentProperties

  ' -------------------------------------------------------
  ' Generate new CDP "InvoiceNo" if not yet existing
  ' -------------------------------------------------------
    If Not CDPExists("InvoiceNo") Then
    '  set temporary starting value "0"
       prop.Add "InvoiceNo", False, msoPropertyTypeString, "0"
    End If

  ' --------------------------------------------------------
  ' Increment invoice no and return function value as string
  ' --------------------------------------------------------
       ret = Format(Val(prop("InvoiceNo")) + 1, "0")
  ' a) Set CDP "InvoiceNo" = ret
       prop("InvoiceNo").value = ret
  ' b) Return function value 
       NextInvoiceNo = ret
End Function

Private Function CDPExists(sCDPName As String) As Boolean
' Purpose: return True if custom document property (CDP) exists
' Method: loop thru CustomDocumentProperties collection and check if name parameter exists
' Site: cf. http://stackoverflow.com/questions/23917977/alternatives-to-public-variables-in-vba/23918236#23918236
' vgl.: https://answers.microsoft.com/en-us/msoffice/forum/msoffice_word-mso_other/using-customdocumentproperties-with-vba/91ef15eb-b089-4c9b-a8a7-1685d073fb9f
' Declarations
  Dim cdp As Variant      ' element of CustomDocumentProperties Collection
  Dim boo As Boolean      ' boolean value showing element exists
  For Each cdp In ThisWorkbook.CustomDocumentProperties
    If LCase(cdp.Name) = LCase(sCDPName) Then
       boo = True      ' heureka
       Exit For        ' exit loop
    End If
  Next
  CDPExists = boo          ' return value to function
End Function


Sub DeleteInvoiceNo()
' Declarations
  Dim wb     As Workbook
  Dim prop   As Object
' Set workbook and CDPs
  Set wb = ThisWorkbook
  Set prop = wb.CustomDocumentProperties

' ----------------------
' Delete CDP "InvoiceNo"
' ----------------------
 If CDPExists("InvoiceNo") Then
    prop("InvoiceNo").Delete
 End If

अंत उप

Sub showAllCDPs()
' Purpose: Show all CustomDocumentProperties (CDP) and values (if set)
' Declarations
  Dim wb      As Workbook
  Dim cdp     As Object

  Dim i       As Integer
  Dim maxi   As Integer
  Dim s       As String
' Set workbook and CDPs
  Set wb = ThisWorkbook
  Set cdp = wb.CustomDocumentProperties
' Loop thru CDP getting name and value
  maxi = cdp.Count
  For i = 1 To maxi
    On Error Resume Next    ' necessary in case of unset value
    s = s & Chr(i + 96) & ") " & _
            cdp(i).Name & "=" & cdp(i).value & vbCr
  Next i
' Show result string
  Debug.Print s
End Sub