excel-vba
CustomDocumentProperties in pratica

introduzione

Organizzazione di nuovi numeri di fattura

Aumentare un numero di fattura e salvarne il valore è un compito frequente. L'uso di CustomDocumentProperties (CDP) è un buon metodo per archiviare tali numeri in modo relativamente sicuro all'interno dello stesso libro di lavoro, ma evitando di mostrare i relativi valori di cella semplicemente in un foglio di lavoro non protetto.

Suggerimento aggiuntivo:

In alternativa, è possibile inserire valori anche in un foglio di lavoro nascosto o anche in un cosiddetto foglio di lavoro "molto nascosto" (vedere Utilizzo di fogli xlVeryHidden . Naturalmente, è possibile salvare i dati anche su file esterni (ad esempio file ini, csv o qualsiasi altro tipo) o il registro.

Contenuto di esempio :

L'esempio qui sotto mostra

• una funzione NextInvoiceNo che imposta e restituisce il prossimo numero di fattura,
• una procedura DeleteInvoiceNo, che cancella completamente il CDP delle fatture, così come
• una procedura showAllCDP che elenca la raccolta completa dei CDP con tutti i nomi. Non utilizzando VBA, è anche possibile elencarli tramite le informazioni della cartella di lavoro: Informazioni | Proprietà [DropDown:] | Proprietà avanzate | costume

È possibile ottenere e impostare il numero di fattura successivo (l'ultimo no più uno) semplicemente chiamando la funzione sopra menzionata, restituendo un valore di stringa per facilitare l'aggiunta di prefissi. "InvoiceNo" è implicitamente utilizzato come nome CDP in tutte le procedure.

Dim sNumber As String
sNumber = NextInvoiceNo ()

Codice di esempio:

Option Explicit

Sub Test()
  Dim sNumber As String
  sNumber = NextInvoiceNo()
  MsgBox "New Invoice No: " & sNumber, vbInformation, "New Invoice Number"
End Sub

Function NextInvoiceNo() As String
' Purpose: a) Set Custom Document Property (CDP) "InvoiceNo" if not yet existing
'          b) Increment CDP value and return new value as string
' Declarations
  Dim prop As Object
  Dim ret  As String
  Dim wb   As Workbook
' Set workbook and CDPs
  Set wb = ThisWorkbook
  Set prop = wb.CustomDocumentProperties

  ' -------------------------------------------------------
  ' Generate new CDP "InvoiceNo" if not yet existing
  ' -------------------------------------------------------
    If Not CDPExists("InvoiceNo") Then
    '  set temporary starting value "0"
       prop.Add "InvoiceNo", False, msoPropertyTypeString, "0"
    End If

  ' --------------------------------------------------------
  ' Increment invoice no and return function value as string
  ' --------------------------------------------------------
       ret = Format(Val(prop("InvoiceNo")) + 1, "0")
  ' a) Set CDP "InvoiceNo" = ret
       prop("InvoiceNo").value = ret
  ' b) Return function value 
       NextInvoiceNo = ret
End Function

Private Function CDPExists(sCDPName As String) As Boolean
' Purpose: return True if custom document property (CDP) exists
' Method: loop thru CustomDocumentProperties collection and check if name parameter exists
' Site: cf. http://stackoverflow.com/questions/23917977/alternatives-to-public-variables-in-vba/23918236#23918236
' vgl.: https://answers.microsoft.com/en-us/msoffice/forum/msoffice_word-mso_other/using-customdocumentproperties-with-vba/91ef15eb-b089-4c9b-a8a7-1685d073fb9f
' Declarations
  Dim cdp As Variant      ' element of CustomDocumentProperties Collection
  Dim boo As Boolean      ' boolean value showing element exists
  For Each cdp In ThisWorkbook.CustomDocumentProperties
    If LCase(cdp.Name) = LCase(sCDPName) Then
       boo = True      ' heureka
       Exit For        ' exit loop
    End If
  Next
  CDPExists = boo          ' return value to function
End Function


Sub DeleteInvoiceNo()
' Declarations
  Dim wb     As Workbook
  Dim prop   As Object
' Set workbook and CDPs
  Set wb = ThisWorkbook
  Set prop = wb.CustomDocumentProperties

' ----------------------
' Delete CDP "InvoiceNo"
' ----------------------
 If CDPExists("InvoiceNo") Then
    prop("InvoiceNo").Delete
 End If

End Sub

Sub showAllCDPs()
' Purpose: Show all CustomDocumentProperties (CDP) and values (if set)
' Declarations
  Dim wb      As Workbook
  Dim cdp     As Object

  Dim i       As Integer
  Dim maxi   As Integer
  Dim s       As String
' Set workbook and CDPs
  Set wb = ThisWorkbook
  Set cdp = wb.CustomDocumentProperties
' Loop thru CDP getting name and value
  maxi = cdp.Count
  For i = 1 To maxi
    On Error Resume Next    ' necessary in case of unset value
    s = s & Chr(i + 96) & ") " & _
            cdp(i).Name & "=" & cdp(i).value & vbCr
  Next i
' Show result string
  Debug.Print s
End Sub