VBA
Tableaux

Déclaration d'un tableau dans VBA

Déclarer un tableau est très similaire à déclarer une variable, sauf que vous devez déclarer la dimension du tableau juste après son nom:

Dim myArray(9) As String 'Declaring an array that will contain up to 10 strings

Par défaut, les tableaux de VBA sont indexés à partir de ZERO . Le nombre entre parenthèses ne fait donc pas référence à la taille du tableau, mais plutôt à l’index du dernier élément.

Accéder aux éléments

L'accès à un élément du tableau se fait en utilisant le nom du tableau, suivi de l'index de l'élément, entre parenthèses:

myArray(0) = "first element"
myArray(5) = "sixth element"
myArray(9) = "last element"

Indexation de tableau

Vous pouvez modifier l'indexation des tableaux en plaçant cette ligne en haut d'un module:

Option Base 1

Avec cette ligne, tous les tableaux déclarés dans le module seront indexés depuis ONE .

Index spécifique

Vous pouvez également déclarer chaque tableau avec son propre index en utilisant le mot clé To et les limites inférieure et supérieure (= index):

Dim mySecondArray(1 To 12) As String 'Array of 12 strings indexed from 1 to 12
Dim myThirdArray(13 To 24) As String 'Array of 12 strings indexed from 13 to 24

Déclaration dynamique

Lorsque vous ne connaissez pas la taille de votre tableau avant sa déclaration, vous pouvez utiliser la déclaration dynamique et le mot clé ReDim :

Dim myDynamicArray() As Strings 'Creates an Array of an unknown number of strings
ReDim myDynamicArray(5) 'This resets the array to 6 elements

Notez que l'utilisation du mot-clé ReDim effacera tout contenu précédent de votre tableau. Pour éviter cela, vous pouvez utiliser le mot-clé Preserve après ReDim :

Dim myDynamicArray(5) As String
myDynamicArray(0) = "Something I want to keep"

ReDim Preserve myDynamicArray(8) 'Expand the size to up to 9 strings
Debug.Print myDynamicArray(0) ' still prints the element

Utilisation de Split pour créer un tableau à partir d'une chaîne

Fonction Split

renvoie un tableau à une dimension, basé sur zéro, contenant un nombre spécifié de sous-chaînes.

Syntaxe

Split (expression [, delimiter [, limit [, compare ]]] )

Paramètres

L'argument de comparaison peut avoir les valeurs suivantes:

Exemple

Dans cet exemple, il est démontré comment Split fonctionne en affichant plusieurs styles. Les commentaires afficheront le jeu de résultats pour chacune des différentes options de Split effectuées. Enfin, il est démontré comment effectuer une boucle sur le tableau de chaînes renvoyé.

Sub Test
    
    Dim textArray() as String

    textArray = Split("Tech on the Net")
    'Result: {"Tech", "on", "the", "Net"}

    textArray = Split("172.23.56.4", ".")
    'Result: {"172", "23", "56", "4"}

    textArray = Split("A;B;C;D", ";")
    'Result: {"A", "B", "C", "D"}

    textArray = Split("A;B;C;D", ";", 1)
    'Result: {"A;B;C;D"}

    textArray = Split("A;B;C;D", ";", 2)
    'Result: {"A", "B;C;D"}

    textArray = Split("A;B;C;D", ";", 3)
    'Result: {"A", "B", "C;D"}

    textArray = Split("A;B;C;D", ";", 4)
    'Result: {"A", "B", "C", "D"}

    'You can iterate over the created array
    Dim counter As Long

    For counter = LBound(textArray) To UBound(textArray)
        Debug.Print textArray(counter)
    Next
 End Sub

Éléments itératifs d'un tableau

Pour ... Suivant

L'utilisation de la variable itérateur comme numéro d'index est le moyen le plus rapide d'itérer les éléments d'un tableau:

Dim items As Variant
items = Array(0, 1, 2, 3)

Dim index As Integer
For index = LBound(items) To UBound(items)
    'assumes value can be implicitly converted to a String:
    Debug.Print items(index) 
Next

Les boucles imbriquées peuvent être utilisées pour itérer des tableaux multidimensionnels:

Dim items(0 To 1, 0 To 1) As Integer
items(0, 0) = 0
items(0, 1) = 1
items(1, 0) = 2
items(1, 1) = 3

Dim outer As Integer
Dim inner As Integer
For outer = LBound(items, 1) To UBound(items, 1)
    For inner = LBound(items, 2) To UBound(items, 2)
        'assumes value can be implicitly converted to a String:
        Debug.Print items(outer, inner)
    Next
Next

Pour chacun ... Suivant

Une boucle For Each...Next peut également être utilisée pour itérer des tableaux, si les performances importent peu:

Dim items As Variant
items = Array(0, 1, 2, 3)

Dim item As Variant 'must be variant
For Each item In items
    'assumes value can be implicitly converted to a String:
    Debug.Print item
Next

Une boucle For Each itère toutes les dimensions de l'extérieur vers l'intérieur (le même ordre que les éléments sont mis en mémoire), donc il n'y a pas besoin de boucles imbriquées:

Dim items(0 To 1, 0 To 1) As Integer
items(0, 0) = 0
items(1, 0) = 1
items(0, 1) = 2
items(1, 1) = 3

Dim item As Variant 'must be Variant
For Each item In items
    'assumes value can be implicitly converted to a String:
    Debug.Print item
Next

Notez que les boucles For Each sont mieux utilisées pour itérer les objets Collection , si les performances sont importantes.

Les 4 extraits ci-dessus produisent la même sortie:

 0
 1
 2
 3

Tableaux dynamiques (redimensionnement de matrice et traitement dynamique)

Tableaux dynamiques

L'ajout et la réduction dynamiques de variables dans un tableau est un avantage considérable lorsque les informations que vous traitez ne comportent pas un nombre défini de variables.

Ajout dynamique de valeurs

Vous pouvez simplement redimensionner le tableau avec l'instruction ReDim , cela redimensionnera le tableau, mais si vous souhaitez conserver les informations déjà stockées dans le tableau, vous aurez besoin du composant Preserve .

Dans l'exemple ci-dessous, nous créons un tableau et l'augmentons d'une variable supplémentaire dans chaque itération tout en préservant les valeurs déjà présentes dans le tableau.

Dim Dynamic_array As Variant
' first we set Dynamic_array as variant

For n = 1 To 100

    If IsEmpty(Dynamic_array) Then
        'isempty() will check if we need to add the first value to the array or subsequent ones
    
        ReDim Dynamic_array(0)
        'ReDim Dynamic_array(0) will resize the array to one variable only
        Dynamic_array(0) = n

    Else
        ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) + 1)
        'in the line above we resize the array from variable 0 to the UBound() = last variable, plus one effectivelly increeasing the size of the array by one
        Dynamic_array(UBound(Dynamic_array)) = n
        'attribute a value to the last variable of Dynamic_array
    End If

Next

Suppression dynamique des valeurs

Nous pouvons utiliser la même logique pour diminuer le tableau. Dans l'exemple, la valeur "last" sera supprimée du tableau.

Dim Dynamic_array As Variant
Dynamic_array = Array("first", "middle", "last")
    
ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) - 1)
' Resize Preserve while dropping the last value

Réinitialisation d'un tableau et réutilisation dynamique

Nous pouvons également réutiliser les tableaux que nous créons pour ne pas en avoir beaucoup en mémoire, ce qui ralentirait le temps d'exécution. Ceci est utile pour les tableaux de différentes tailles. Un extrait que vous pourriez utiliser pour réutiliser le tableau est de ReDim le tableau sur (0) , d'attribuer une variable au tableau et d'augmenter à nouveau librement le tableau.

Dans l'extrait ci-dessous, je construis un tableau avec les valeurs 1 à 40, vide le tableau et remplit le tableau avec les valeurs 40 à 100, tout cela de manière dynamique.

Dim Dynamic_array As Variant

For n = 1 To 100

    If IsEmpty(Dynamic_array) Then
        ReDim Dynamic_array(0)
        Dynamic_array(0) = n
    
    ElseIf Dynamic_array(0) = "" Then
        'if first variant is empty ( = "") then give it the value of n
        Dynamic_array(0) = n
    Else
        ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) + 1)
        Dynamic_array(UBound(Dynamic_array)) = n
    End If
    If n = 40 Then
        ReDim Dynamic_array(0)
        'Resizing the array back to one variable without Preserving,
        'leaving the first value of the array empty
    End If

Next

Tableaux dentelés (tableaux de tableaux)

Tableaux dentelés PAS de tableaux multidimensionnels

Les tableaux de tableaux (Jagged Arrays) ne sont pas les mêmes que les tableaux multidimensionnels si vous les considérez visuellement. Les tableaux multidimensionnels ressemblent à des matrices (rectangulaires) avec un nombre défini d'éléments sur leurs dimensions (tableaux internes). calendrier avec les tableaux intérieurs ayant un nombre différent d'éléments, comme des jours dans des mois différents.

Bien que les baies Jagged soient assez compliquées et délicates à utiliser en raison de leurs niveaux imbriqués et qu’elles n’ont pas beaucoup de sécurité, mais elles sont très flexibles, elles vous permettent de manipuler assez facilement différents types de données et vous n'avez pas besoin de éléments vides.

Créer un tableau dentelé

Dans l'exemple ci-dessous, nous allons initialiser un tableau en escalier contenant deux tableaux l'un pour les noms et l'autre pour les nombres, puis en accédant à un élément de chaque

Dim OuterArray() As Variant
Dim Names() As Variant
Dim Numbers() As Variant
'arrays are declared variant so we can access attribute any data type to its elements

Names = Array("Person1", "Person2", "Person3")
Numbers = Array("001", "002", "003")

OuterArray = Array(Names, Numbers)
'Directly giving OuterArray an array containing both Names and Numbers arrays inside

Debug.Print OuterArray(0)(1)
Debug.Print OuterArray(1)(1)
'accessing elements inside the jagged by giving the coordenades of the element

Création dynamique et lecture de tableaux dentelés

Nous pouvons aussi être plus dynamiques dans notre approche de la construction des baies, imaginez que nous ayons une fiche de données client dans Excel et que nous souhaitons construire un tableau pour afficher les détails du client.

   Name -   Phone   -  Email  - Customer Number 
Person1 - 153486231 - 1@STACK - 001
Person2 - 153486242 - 2@STACK - 002
Person3 - 153486253 - 3@STACK - 003
Person4 - 153486264 - 4@STACK - 004
Person5 - 153486275 - 5@STACK - 005

Nous allons construire dynamiquement un tableau d'en-tête et un tableau Customers, l'en-tête contiendra les titres des colonnes et le tableau Customers contiendra les informations de chaque client / ligne en tant que tableaux.

Dim Headers As Variant
' headers array with the top section of the customer data sheet
    For c = 1 To 4
        If IsEmpty(Headers) Then
            ReDim Headers(0)
            Headers(0) = Cells(1, c).Value
        Else
            ReDim Preserve Headers(0 To UBound(Headers) + 1)
            Headers(UBound(Headers)) = Cells(1, c).Value
        End If
    Next
    
Dim Customers As Variant
'Customers array will contain arrays of customer values
Dim Customer_Values As Variant
'Customer_Values will be an array of the customer in its elements (Name-Phone-Email-CustNum)
    
    For r = 2 To 6
    'iterate through the customers/rows
        For c = 1 To 4
        'iterate through the values/columns
            
            'build array containing customer values
            If IsEmpty(Customer_Values) Then
                ReDim Customer_Values(0)
                Customer_Values(0) = Cells(r, c).Value
            ElseIf Customer_Values(0) = "" Then
                Customer_Values(0) = Cells(r, c).Value
            Else
                ReDim Preserve Customer_Values(0 To UBound(Customer_Values) + 1)
                Customer_Values(UBound(Customer_Values)) = Cells(r, c).Value
            End If
        Next
        
        'add customer_values array to Customers Array
        If IsEmpty(Customers) Then
            ReDim Customers(0)
            Customers(0) = Customer_Values
        Else
            ReDim Preserve Customers(0 To UBound(Customers) + 1)
            Customers(UBound(Customers)) = Customer_Values
        End If
        
        'reset Custumer_Values to rebuild a new array if needed
        ReDim Customer_Values(0)
    Next

    Dim Main_Array(0 To 1) As Variant
    'main array will contain both the Headers and Customers
    
    Main_Array(0) = Headers
    Main_Array(1) = Customers

To better understand the way to Dynamically construct a one dimensional array please check Dynamic Arrays (Array Resizing and Dynamic Handling) on the Arrays documentation.

Le résultat de l'extrait ci-dessus est un Jagged Array avec deux tableaux l'un de ces tableaux avec 4 éléments, 2 niveaux d'indentation, et l'autre étant lui-même un autre Jagged Array contenant 5 tableaux de 4 éléments chacun et 3 niveaux d'indentation, voir ci-dessous la structure:

Main_Array(0) - Headers - Array("Name","Phone","Email","Customer Number")
          (1) - Customers(0) - Array("Person1",153486231,"1@STACK",001)
                Customers(1) - Array("Person2",153486242,"2@STACK",002)
                ...
                Customers(4) - Array("Person5",153486275,"5@STACK",005)

Pour accéder aux informations, vous devez tenir compte de la structure de Jagged Array que vous créez. Dans l'exemple ci-dessus, vous pouvez voir que le Main Array contient un tableau d'en- Headers et un tableau de tableaux ( Customers ). accéder aux éléments.

Nous allons maintenant lire les informations du Main Array et imprimer chacune des informations du client en tant que Info Type: Info .

For n = 0 To UBound(Main_Array(1))
    'n to iterate from fisrt to last array in Main_Array(1)
    
    For j = 0 To UBound(Main_Array(1)(n))
        'j will iterate from first to last element in each array of Main_Array(1)
        
        Debug.Print Main_Array(0)(j) & ": " & Main_Array(1)(n)(j)
        'print Main_Array(0)(j) which is the header and Main_Array(0)(n)(j) which is the element in the customer array
        'we can call the header with j as the header array has the same structure as the customer array
    Next
Next

N'OUBLIEZ PAS de garder une trace de la structure de votre tableau Jagged, dans l'exemple ci-dessus pour accéder au nom d'un client en accédant à Main_Array -> Customers -> CustomerNumber -> Name qui "Person4" trois niveaux, pour renvoyer "Person4" vous aurez besoin. l'emplacement des clients dans Main_Array, puis l'emplacement du client quatre sur le tableau Customers Jagged et enfin l'emplacement de l'élément dont vous avez besoin, dans ce cas Main_Array(1)(3)(0) qui est Main_Array(Customers)(CustomerNumber)(Name) .

Tableaux multidimensionnels

Tableaux multidimensionnels

Comme leur nom l'indique, les tableaux multidimensionnels sont des tableaux contenant plus d'une dimension, généralement deux ou trois, mais peuvent comporter jusqu'à 32 dimensions.

Un multi-tableau fonctionne comme une matrice avec différents niveaux, par exemple une comparaison entre une, deux et trois dimensions.

One Dimension est votre tableau typique, il ressemble à une liste d'éléments.

Dim 1D(3) as Variant

*1D - Visually*
(0)
(1)
(2)

Two Dimensions ressemblerait à une grille de Sudoku ou à une feuille Excel. Lors de l'initialisation du tableau, vous définiriez le nombre de lignes et de colonnes que le tableau aurait.

Dim 2D(3,3) as Variant
'this would result in a 3x3 grid 

*2D - Visually*
(0,0) (0,1) (0,2)
(1,0) (1,1) (1,2)
(2,0) (2,1) (2,2)

Three Dimensions commencerait à ressembler à Rubik's Cube. Lors de l'initialisation du tableau, vous définiriez des lignes, des colonnes et des couches / profondeurs.

Dim 3D(3,3,2) as Variant
'this would result in a 3x3x3 grid

*3D - Visually*
       1st layer                 2nd layer                  3rd layer
         front                     middle                     back
(0,0,0) (0,0,1) (0,0,2) ¦ (1,0,0) (1,0,1) (1,0,2) ¦ (2,0,0) (2,0,1) (2,0,2)
(0,1,0) (0,1,1) (0,1,2) ¦ (1,1,0) (1,1,1) (1,1,2) ¦ (2,1,0) (2,1,1) (2,1,2)
(0,2,0) (0,2,1) (0,2,2) ¦ (1,2,0) (1,2,1) (1,2,2) ¦ (2,2,0) (2,2,1) (2,2,2)

D'autres dimensions pourraient être considérées comme la multiplication de la 3D, de sorte qu'un 4D (1,3,3,3) serait deux tableaux 3D côte à côte.

Tableau à deux dimensions

La création

L'exemple ci-dessous sera une compilation d'une liste d'employés, chaque employé aura un ensemble d'informations sur la liste (Prénom, Nom, Adresse, Email, Téléphone ...), l'exemple sera essentiellement stocké sur le tableau ( employé, information) étant le (0,0) est le prénom du premier employé.

Dim Bosses As Variant
'set bosses as Variant, so we can input any data type we want

Bosses = [{"Jonh","Snow","President";"Ygritte","Wild","Vice-President"}]
'initialise a 2D array directly by filling it with information, the redult wil be a array(1,2) size 2x3 = 6 elements

Dim Employees As Variant
'initialize your Employees array as variant
'initialize and ReDim the Employee array so it is a dynamic array instead of a static one, hence treated differently by the VBA Compiler
ReDim Employees(100, 5)
'declaring an 2D array that can store 100 employees with 6 elements of information each, but starts empty
'the array size is 101 x 6 and contains 606 elements

For employee = 0 To UBound(Employees, 1)
'for each employee/row in the array, UBound for 2D arrays, which will get the last element on the array
'needs two parameters 1st the array you which to check and 2nd the dimension, in this case 1 = employee and 2 = information
    For information_e = 0 To UBound(Employees, 2)
    'for each information element/column in the array
        
        Employees(employee, information_e) = InformationNeeded ' InformationNeeded would be the data to fill the array
        'iterating the full array will allow for direct attribution of information into the element coordinates
    Next
Next

Redimensionnement

Redimensionnement ou ReDim Preserve un multi-tableau comme la norme pour un tableau One-Dimension obtiendrait une erreur, au lieu de cela, les informations doivent être transférées dans un tableau temporaire de la même taille que l'original plus le nombre de lignes / colonnes à ajouter. Dans l'exemple ci-dessous, nous verrons comment initialiser un tableau temporaire, transférer les informations du tableau d'origine, remplir les éléments vides restants et remplacer le tableau temporaire par le tableau d'origine.

Dim TempEmp As Variant
'initialise your temp array as variant
ReDim TempEmp(UBound(Employees, 1) + 1, UBound(Employees, 2))
'ReDim/Resize Temp array as a 2D array with size UBound(Employees)+1 = (last element in Employees 1st dimension) + 1,
'the 2nd dimension remains the same as the original array. we effectively add 1 row in the Employee array

'transfer
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    For info = LBound(Employees, 2) To UBound(Employees, 2)
        'to transfer Employees into TempEmp we iterate both arrays and fill TempEmp with the corresponding element value in Employees
        TempEmp(emp, info) = Employees(emp, info)
    
    Next
Next

'fill remaining
'after the transfers the Temp array still has unused elements at the end, being that it was increased
'to fill the remaining elements iterate from the last "row" with values to the last row in the array
'in this case the last row in Temp will be the size of the Employees array rows + 1, as the last row of Employees array is already filled in the TempArray

For emp = UBound(Employees, 1) + 1 To UBound(TempEmp, 1)
    For info = LBound(TempEmp, 2) To UBound(TempEmp, 2)
        
        TempEmp(emp, info) = InformationNeeded & "NewRow"
    
    Next
Next

'erase Employees, attribute Temp array to Employees and erase Temp array
Erase Employees
Employees = TempEmp
Erase TempEmp

Modification des valeurs d'élément

Pour modifier / modifier les valeurs d’un élément donné, il suffit d’appeler la coordonnée pour la modifier et de lui donner une nouvelle valeur: Employees(0, 0) = "NewValue"

Vous pouvez également parcourir les conditions d'utilisation des coordonnées pour faire correspondre les valeurs correspondant aux paramètres nécessaires:

For emp = 0 To UBound(Employees)
    If Employees(emp, 0) = "Gloria" And Employees(emp, 1) = "Stephan" Then
    'if value found
        Employees(emp, 1) = "Married, Last Name Change"
        Exit For
        'don't iterate through a full array unless necessary
    End If
Next

En train de lire

L'accès aux éléments du tableau peut être effectué à l'aide d'une boucle imbriquée (itération de chaque élément), d'une boucle et d'une coordonnée (itération des lignes et accès direct aux colonnes) ou d'un accès direct aux deux coordonnées.

'nested loop, will iterate through all elements
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    For info = LBound(Employees, 2) To UBound(Employees, 2)
        Debug.Print Employees(emp, info)
    Next
Next

'loop and coordinate, iteration through all rows and in each row accessing all columns directly
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    Debug.Print Employees(emp, 0)
    Debug.Print Employees(emp, 1)
    Debug.Print Employees(emp, 2)
    Debug.Print Employees(emp, 3)
    Debug.Print Employees(emp, 4)
    Debug.Print Employees(emp, 5)
Next

'directly accessing element with coordinates
Debug.Print Employees(5, 5)

Rappelez - vous , il est toujours utile de garder une carte de tableau lors de l'utilisation de tableaux multidimensionnels, ils peuvent facilement devenir une confusion.

Tableau à trois dimensions

Pour le tableau 3D, nous utiliserons les mêmes prémisses que le tableau 2D, en plus de stocker l'employé et les informations, mais aussi de construire dans lequel ils travaillent.

Le tableau 3D aura les employés (peuvent être considérés comme des lignes), les informations (colonnes) et le bâtiment qui peuvent être considérés comme des feuilles différentes sur un document Excel, ils ont la même taille entre eux, mais chaque feuille a un ensemble d'informations différent dans ses cellules / éléments. Le tableau 3D contiendra un nombre n de tableaux 2D.

La création

Un tableau 3D a besoin de 3 coordonnées pour être initialisé Dim 3Darray(2,5,5) As Variant la première coordonnée du tableau sera le nombre de feuilles de construction (différents ensembles de lignes et de colonnes), la deuxième coordonnée définira les lignes et la troisième Colonnes. Le Dim ci-dessus donnera un tableau 3D avec 108 éléments ( 3*6*6 ), avec 3 ensembles de tableaux 2D différents.

Dim ThreeDArray As Variant
'initialise your ThreeDArray array as variant
ReDim ThreeDArray(1, 50, 5)
'declaring an 3D array that can store two sets of 51 employees with 6 elements of information each, but starts empty
'the array size is 2 x 51 x 6 and contains 612 elements

For building = 0 To UBound(ThreeDArray, 1)
    'for each building/set in the array
    For employee = 0 To UBound(ThreeDArray, 2)
    'for each employee/row in the array
        For information_e = 0 To UBound(ThreeDArray, 3)
        'for each information element/column in the array
            
            ThreeDArray(building, employee, information_e) = InformationNeeded ' InformationNeeded would be the data to fill the array
        'iterating the full array will allow for direct attribution of information into the element coordinates
        Next
    Next
Next

Redimensionnement

Le redimensionnement d'un tableau 3D est similaire au redimensionnement d'un 2D, créez d'abord un tableau Temporary avec la même taille que l'original en ajoutant un dans la coordonnée du paramètre à augmenter, le premier augmentera le nombre d'ensembles dans le tableau, le second et les troisièmes coordonnées augmenteront le nombre de lignes ou de colonnes dans chaque ensemble.

L'exemple ci-dessous augmente le nombre de lignes dans chaque ensemble par un et remplit ces éléments récemment ajoutés avec de nouvelles informations.

Dim TempEmp As Variant
'initialise your temp array as variant
ReDim TempEmp(UBound(ThreeDArray, 1), UBound(ThreeDArray, 2) + 1, UBound(ThreeDArray, 3))
'ReDim/Resize Temp array as a 3D array with size UBound(ThreeDArray)+1 = (last element in Employees 2nd dimension) + 1,
'the other dimension remains the same as the original array. we effectively add 1 row in the for each set of the 3D array

'transfer
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        For info = LBound(ThreeDArray, 3) To UBound(ThreeDArray, 3)
            'to transfer ThreeDArray into TempEmp by iterating all sets in the 3D array and fill TempEmp with the corresponding element value in each set of each row
            TempEmp(building, emp, info) = ThreeDArray(building, emp, info)
        
        Next
    Next
Next

'fill remaining
'to fill the remaining elements we need to iterate from the last "row" with values to the last row in the array in each set, remember that the first empty element is the original array Ubound() plus 1
For building = LBound(TempEmp, 1) To UBound(TempEmp, 1)
    For emp = UBound(ThreeDArray, 2) + 1 To UBound(TempEmp, 2)
        For info = LBound(TempEmp, 3) To UBound(TempEmp, 3)
            
            TempEmp(building, emp, info) = InformationNeeded & "NewRow"
        
        Next
    Next
Next

'erase Employees, attribute Temp array to Employees and erase Temp array
Erase ThreeDArray
ThreeDArray = TempEmp
Erase TempEmp

Modification des valeurs des éléments et lecture

La lecture et la modification des éléments du tableau 3D peuvent se faire de la même façon que nous le faisons avec le tableau 2D, il suffit de régler le niveau supplémentaire dans les boucles et les coordonnées.

Do
' using Do ... While for early exit
    For building = 0 To UBound(ThreeDArray, 1)
        For emp = 0 To UBound(ThreeDArray, 2)
            If ThreeDArray(building, emp, 0) = "Gloria" And ThreeDArray(building, emp, 1) = "Stephan" Then
            'if value found
                ThreeDArray(building, emp, 1) = "Married, Last Name Change"
                Exit Do
                'don't iterate through all the array unless necessary
            End If
        Next
    Next
Loop While False

'nested loop, will iterate through all elements
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        For info = LBound(ThreeDArray, 3) To UBound(ThreeDArray, 3)
            Debug.Print ThreeDArray(building, emp, info)
        Next
    Next
Next

'loop and coordinate, will iterate through all set of rows and ask for the row plus the value we choose for the columns
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        Debug.Print ThreeDArray(building, emp, 0)
        Debug.Print ThreeDArray(building, emp, 1)
        Debug.Print ThreeDArray(building, emp, 2)
        Debug.Print ThreeDArray(building, emp, 3)
        Debug.Print ThreeDArray(building, emp, 4)
        Debug.Print ThreeDArray(building, emp, 5)
    Next
Next

'directly accessing element with coordinates
Debug.Print Employees(0, 5, 5)