Intel x86 Assembly Language & Microarchitecture
Механизмы системного вызова

.NET Framework algorithm Android C Language C# Language C++ Java Language GNU/Linux Python Language Visual Basic .NET Language

Вызов BIOS

Как взаимодействовать с BIOS

Базовая система ввода / вывода или BIOS - это то, что контролирует компьютер до запуска любой операционной системы. Для доступа к услугам, предоставляемым BIOS, код сборки использует прерывания . Прерывание принимает форму

int <interrupt> ; interrupt must be a literal number, not in a register or memory

Номер прерывания должен быть между 0 и 255 (0x00 - 0xFF) включительно.

Большинство вызовов BIOS используют регистр AH в качестве параметра «выбор функции» и используют регистр AL в качестве параметра данных. Функция, выбранная AH зависит от вызываемого прерывания. Некоторые вызовы BIOS требуют одного 16-битного параметра в AX или вообще не принимают параметры и просто вызываются прерыванием. У некоторых есть еще больше параметров, которые передаются в других регистрах.

Регистры, используемые для вызовов BIOS, являются фиксированными и не могут быть взаимозаменяемы с другими регистрами.

Использование вызовов BIOS с функцией выбора

Общий синтаксис прерывания BIOS с использованием параметра выбора функции:

mov ah, <function>
mov al, <data>
int <interrupt>

Примеры

Как написать символ на дисплей:

mov ah, 0x0E             ; Select 'Write character' function
mov al, <char>           ; Character to write
int 0x10                 ; Video services interrupt

Как читать символ с клавиатуры (блокировка):

mov ah, 0x00             ; Select 'Blocking read character' function
int 0x16                 ; Keyboard services interrupt
mov <ascii_char>, al     ; AL contains the character read
mov <scan_code>, ah      ; AH contains the BIOS scan code

Как читать один или несколько секторов с внешнего диска (с использованием адресации CHS):

mov ah, 0x02             ; Select 'Drive read' function
mov bx, <destination>    ; Destination to write to, in ES:BX
mov al, <num_sectors>    ; Number of sectors to read at a time
mov dl, <drive_num>      ; The external drive's ID
mov cl, <start_sector>   ; The sector to start reading from
mov dh, <head>           ; The head to read from
mov ch, <cylinder>       ; The cylinder to read from
int 0x13                 ; Drive services interrupt
jc <error_handler>       ; Jump to error handler on CF set

Как читать систему RTC (часы реального времени):

mov ah, 0x00             ; Select 'Read RTC' function
int 0x1A                 ; RTC services interrupt
shl ecx, 16              ; Clock ticks are split in the CX:DX pair, so shift ECX left by 16...
or cx, dx                ; and add in the low half of the pair
mov <new_day>, al        ; AL is non-zero if the last call to this function was before midnight
                         ; Now ECX holds the clock ticks (approx. 18.2/sec) since midnight
                         ; and <new_day> is non-zero if we passed midnight since the last read

Как прочитать системное время из RTC:

mov ah, 0x02             ; Select 'Read system time' function
int 0x1A                 ; RTC services interrupt
                         ; Now CH contains hour, CL minutes, DH seconds, and DL the DST flag,
                         ; all encoded in BCD (DL is zero if in standard time)
                         ; Now we can decode them into a string (we'll ignore DST for now)

mov al, ch               ; Get hour
shr al, 4                ; Discard one's place for now
add al, 48               ; Add ASCII code of digit 0
mov [CLOCK_STRING+0], al ; Set ten's place of hour
mov al, ch               ; Get hour again
and al, 0x0F             ; Discard ten's place this time
add al, 48               ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+1], al ; Set one's place of hour

mov al, cl               ; Get minute
shr al, 4                ; Discard one's place for now
add al, 48               ; Add ASCII code of digit 0
mov [CLOCK_STRING+3], al ; Set ten's place of minute
mov al, cl               ; Get minute again
and al, 0x0F             ; Discard ten's place this time
add al, 48               ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+4], al ; Set one's place of minute

mov al, dh               ; Get second
shr al, 4                ; Discard one's place for now
add al, 48               ; Add ASCII code of digit 0
mov [CLOCK_STRING+6], al ; Set ten's place of second
mov al, dh               ; Get second again
and al, 0x0F             ; Discard ten's place this time
add al, 48               ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+7], al ; Set one's place of second
...
db CLOCK_STRING "00:00:00", 0   ; Place in some separate (non-code) area

Как читать системную дату из RTC:

mov ah, 0x04             ; Select 'Read system date' function
int 0x1A                 ; RTC services interrupt
                         ; Now CH contains century, CL year, DH month, and DL day, all in BCD
                         ; Decoding to a string is similar to the RTC Time example above

Как получить размер смежной низкой памяти:

int 0x12                 ; Conventional memory interrupt (no function select parameter)
and eax, 0xFFFF          ; AX contains kilobytes of conventional memory; clear high bits of EAX
shl eax, 10              ; Multiply by 1 kilobyte (1024 bytes = 2^10 bytes)
                         ; EAX contains the number of bytes available from address 0000:0000

Как перезагрузить компьютер:

int 0x19                 ; That's it! One call. Just make sure nothing has overwritten the
                         ; interrupt vector table, since this call does NOT restore them to the
                         ; default values of normal power-up. This means this call will not
                         ; work too well in an environment with an operating system loaded.

Обработка ошибок

Некоторые вызовы BIOS не могут быть реализованы на каждом компьютере и не гарантируются. Часто нереализованное прерывание возвращает 0x86 или 0x80 в регистр AH . Почти каждое прерывание установит флаг переноса (CF) на условие ошибки. Это позволяет легко перейти к обработчику ошибок с помощью jc условного перехода. (См. Условные прыжки )