Intel x86 Assembly Language & Microarchitecture
Mechanizmy wywoływania systemu
Szukaj…
Wywołania BIOS
Jak wchodzić w interakcje z BIOS-em
Podstawowy system wejścia / wyjścia, czyli BIOS, kontroluje komputer przed uruchomieniem dowolnego systemu operacyjnego. Aby uzyskać dostęp do usług świadczonych przez BIOS, kod asemblacyjny używa przerwań . Przerwanie ma postać
int <interrupt> ; interrupt must be a literal number, not in a register or memory
Numer przerwania musi wynosić od 0 do 255 (0x00 - 0xFF) włącznie.
Większość wywołań BIOS używa rejestru AH jako parametru „wyboru funkcji” i rejestru AL jako parametru danych. Funkcja wybrana przez AH zależy od wywołanego przerwania. Niektóre wywołania BIOS-u wymagają pojedynczego 16-bitowego parametru w AX lub w ogóle nie akceptują parametrów i są po prostu wywoływane przez przerwanie. Niektóre mają jeszcze więcej parametrów, które są przekazywane w innych rejestrach.
Rejestry używane do wywołań BIOS są stałe i nie można ich zamieniać z innymi rejestrami.
Korzystanie z wywołań systemu BIOS z funkcją wyboru funkcji
Ogólna składnia przerwania systemu BIOS przy użyciu parametru wyboru funkcji jest następująca:
mov ah, <function>
mov al, <data>
int <interrupt>
Przykłady
Jak napisać znak na wyświetlaczu:
mov ah, 0x0E ; Select 'Write character' function
mov al, <char> ; Character to write
int 0x10 ; Video services interrupt
Jak odczytać znak z klawiatury (blokowanie):
mov ah, 0x00 ; Select 'Blocking read character' function
int 0x16 ; Keyboard services interrupt
mov <ascii_char>, al ; AL contains the character read
mov <scan_code>, ah ; AH contains the BIOS scan code
Jak odczytać jeden lub więcej sektorów z dysku zewnętrznego (przy użyciu adresowania CHS):
mov ah, 0x02 ; Select 'Drive read' function
mov bx, <destination> ; Destination to write to, in ES:BX
mov al, <num_sectors> ; Number of sectors to read at a time
mov dl, <drive_num> ; The external drive's ID
mov cl, <start_sector> ; The sector to start reading from
mov dh, <head> ; The head to read from
mov ch, <cylinder> ; The cylinder to read from
int 0x13 ; Drive services interrupt
jc <error_handler> ; Jump to error handler on CF set
Jak odczytać system RTC (zegar czasu rzeczywistego):
mov ah, 0x00 ; Select 'Read RTC' function
int 0x1A ; RTC services interrupt
shl ecx, 16 ; Clock ticks are split in the CX:DX pair, so shift ECX left by 16...
or cx, dx ; and add in the low half of the pair
mov <new_day>, al ; AL is non-zero if the last call to this function was before midnight
; Now ECX holds the clock ticks (approx. 18.2/sec) since midnight
; and <new_day> is non-zero if we passed midnight since the last read
Jak odczytać czas systemowy z RTC:
mov ah, 0x02 ; Select 'Read system time' function
int 0x1A ; RTC services interrupt
; Now CH contains hour, CL minutes, DH seconds, and DL the DST flag,
; all encoded in BCD (DL is zero if in standard time)
; Now we can decode them into a string (we'll ignore DST for now)
mov al, ch ; Get hour
shr al, 4 ; Discard one's place for now
add al, 48 ; Add ASCII code of digit 0
mov [CLOCK_STRING+0], al ; Set ten's place of hour
mov al, ch ; Get hour again
and al, 0x0F ; Discard ten's place this time
add al, 48 ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+1], al ; Set one's place of hour
mov al, cl ; Get minute
shr al, 4 ; Discard one's place for now
add al, 48 ; Add ASCII code of digit 0
mov [CLOCK_STRING+3], al ; Set ten's place of minute
mov al, cl ; Get minute again
and al, 0x0F ; Discard ten's place this time
add al, 48 ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+4], al ; Set one's place of minute
mov al, dh ; Get second
shr al, 4 ; Discard one's place for now
add al, 48 ; Add ASCII code of digit 0
mov [CLOCK_STRING+6], al ; Set ten's place of second
mov al, dh ; Get second again
and al, 0x0F ; Discard ten's place this time
add al, 48 ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+7], al ; Set one's place of second
...
db CLOCK_STRING "00:00:00", 0 ; Place in some separate (non-code) area
Jak odczytać datę systemową z RTC:
mov ah, 0x04 ; Select 'Read system date' function
int 0x1A ; RTC services interrupt
; Now CH contains century, CL year, DH month, and DL day, all in BCD
; Decoding to a string is similar to the RTC Time example above
Jak uzyskać rozmiar ciągłej niskiej ilości pamięci:
int 0x12 ; Conventional memory interrupt (no function select parameter)
and eax, 0xFFFF ; AX contains kilobytes of conventional memory; clear high bits of EAX
shl eax, 10 ; Multiply by 1 kilobyte (1024 bytes = 2^10 bytes)
; EAX contains the number of bytes available from address 0000:0000
Jak ponownie uruchomić komputer:
int 0x19 ; That's it! One call. Just make sure nothing has overwritten the
; interrupt vector table, since this call does NOT restore them to the
; default values of normal power-up. This means this call will not
; work too well in an environment with an operating system loaded.
Obsługa błędów
Niektóre wywołania systemu BIOS mogą nie być zaimplementowane na każdym komputerze i nie ma gwarancji, że będą działać. Często niezaimplementowane przerwanie zwraca 0x86 lub 0x80 w rejestrze AH . Prawie każde przerwanie ustawi flagę przenoszenia (CF) na warunek błędu. Ułatwia to przejście do modułu obsługi błędów za pomocą skoku warunkowego jc . (Zobacz skoki warunkowe )
Bibliografia
Dość wyczerpującą listą wywołań BIOS-u i innych przerwań jest lista przerw Ralfa Browna . Wersję HTML można znaleźć tutaj .
Przerwania często uważane za dostępne znajdują się na liście na Wikipedii .
Bardziej szczegółowy przegląd powszechnie dostępnych przerwań można znaleźć na stronie osdev.org