Intel x86 Assembly Language & Microarchitecture
Systeemoproepmechanismen
Zoeken…
BIOS-oproepen
Hoe te communiceren met het BIOS
Het Basic Input / Output System, of BIOS, is wat de computer bestuurt voordat een besturingssysteem wordt uitgevoerd. Voor toegang tot services die door het BIOS worden geleverd, gebruikt assemblagecode interrupts . Een onderbreking neemt de vorm aan van
int <interrupt> ; interrupt must be a literal number, not in a register or memory
Het onderbrekingsnummer moet tussen 0 en 255 (0x00 - 0xFF) liggen.
De meeste BIOS-aanroepen gebruiken het AH register als een parameter voor "functieselectie" en gebruiken het AL register als gegevensparameter. De functie geselecteerd door AH afhankelijk van de opgeroepen interrupt. Sommige BIOS-aanroepen vereisen een enkele 16-bit parameter in AX , of accepteren helemaal geen parameters en worden eenvoudigweg aangeroepen door de interrupt. Sommige hebben zelfs nog meer parameters, die worden doorgegeven in andere registers.
De registers die worden gebruikt voor BIOS-oproepen zijn vast en kunnen niet worden uitgewisseld met andere registers.
BIOS-oproepen gebruiken met functieselectie
De algemene syntaxis voor een BIOS-interrupt met behulp van een functie select parameter is:
mov ah, <function>
mov al, <data>
int <interrupt>
Voorbeelden
Een teken naar het scherm schrijven:
mov ah, 0x0E ; Select 'Write character' function
mov al, <char> ; Character to write
int 0x10 ; Video services interrupt
Een teken van het toetsenbord lezen (blokkeren):
mov ah, 0x00 ; Select 'Blocking read character' function
int 0x16 ; Keyboard services interrupt
mov <ascii_char>, al ; AL contains the character read
mov <scan_code>, ah ; AH contains the BIOS scan code
Een of meer sectoren van een externe schijf lezen (met CHS-adressering):
mov ah, 0x02 ; Select 'Drive read' function
mov bx, <destination> ; Destination to write to, in ES:BX
mov al, <num_sectors> ; Number of sectors to read at a time
mov dl, <drive_num> ; The external drive's ID
mov cl, <start_sector> ; The sector to start reading from
mov dh, <head> ; The head to read from
mov ch, <cylinder> ; The cylinder to read from
int 0x13 ; Drive services interrupt
jc <error_handler> ; Jump to error handler on CF set
Hoe het systeem RTC (Real Time Clock) te lezen:
mov ah, 0x00 ; Select 'Read RTC' function
int 0x1A ; RTC services interrupt
shl ecx, 16 ; Clock ticks are split in the CX:DX pair, so shift ECX left by 16...
or cx, dx ; and add in the low half of the pair
mov <new_day>, al ; AL is non-zero if the last call to this function was before midnight
; Now ECX holds the clock ticks (approx. 18.2/sec) since midnight
; and <new_day> is non-zero if we passed midnight since the last read
Hoe de systeemtijd uit de RTC te lezen:
mov ah, 0x02 ; Select 'Read system time' function
int 0x1A ; RTC services interrupt
; Now CH contains hour, CL minutes, DH seconds, and DL the DST flag,
; all encoded in BCD (DL is zero if in standard time)
; Now we can decode them into a string (we'll ignore DST for now)
mov al, ch ; Get hour
shr al, 4 ; Discard one's place for now
add al, 48 ; Add ASCII code of digit 0
mov [CLOCK_STRING+0], al ; Set ten's place of hour
mov al, ch ; Get hour again
and al, 0x0F ; Discard ten's place this time
add al, 48 ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+1], al ; Set one's place of hour
mov al, cl ; Get minute
shr al, 4 ; Discard one's place for now
add al, 48 ; Add ASCII code of digit 0
mov [CLOCK_STRING+3], al ; Set ten's place of minute
mov al, cl ; Get minute again
and al, 0x0F ; Discard ten's place this time
add al, 48 ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+4], al ; Set one's place of minute
mov al, dh ; Get second
shr al, 4 ; Discard one's place for now
add al, 48 ; Add ASCII code of digit 0
mov [CLOCK_STRING+6], al ; Set ten's place of second
mov al, dh ; Get second again
and al, 0x0F ; Discard ten's place this time
add al, 48 ; Add ASCII code of digit 0 again
mov [CLOCK_STRING+7], al ; Set one's place of second
...
db CLOCK_STRING "00:00:00", 0 ; Place in some separate (non-code) area
Hoe de systeemdatum van de RTC te lezen:
mov ah, 0x04 ; Select 'Read system date' function
int 0x1A ; RTC services interrupt
; Now CH contains century, CL year, DH month, and DL day, all in BCD
; Decoding to a string is similar to the RTC Time example above
De grootte van aaneengesloten weinig geheugen verkrijgen:
int 0x12 ; Conventional memory interrupt (no function select parameter)
and eax, 0xFFFF ; AX contains kilobytes of conventional memory; clear high bits of EAX
shl eax, 10 ; Multiply by 1 kilobyte (1024 bytes = 2^10 bytes)
; EAX contains the number of bytes available from address 0000:0000
Hoe de computer opnieuw op te starten:
int 0x19 ; That's it! One call. Just make sure nothing has overwritten the
; interrupt vector table, since this call does NOT restore them to the
; default values of normal power-up. This means this call will not
; work too well in an environment with an operating system loaded.
Foutafhandeling
Sommige BIOS-oproepen worden mogelijk niet op elke machine geïmplementeerd en werken niet gegarandeerd. Vaak retourneert een niet-geïmplementeerde interrupt 0x86 of 0x80 in register AH . Zowat elke onderbreking zal de draagvlag (CF) op een foutconditie zetten. Dit maakt het gemakkelijk om naar een foutafhandelaar te springen met de jc voorwaardelijke sprong. (Zie voorwaardelijke sprongen )
Referenties
Een vrij uitgebreide lijst met BIOS-oproepen en andere interrupts is de onderbrekingslijst van Ralf Brown . Een HTML-versie kan worden gevonden hier .
Onderbrekingen waarvan vaak wordt aangenomen dat ze beschikbaar zijn, staan in een lijst op Wikipedia .
Een meer diepgaand overzicht van algemeen beschikbare interrupts is te vinden op osdev.org