groovy
Грубая правда (правда)

замечания

Булевая оценка чисел

для чисел нулевое значение оценивается как false, а не ноль - true

    int i = 0
...
    if (i)
        print "some ${i}"
    else
        print "nothing"

будет печатать "ничего"

Строковые булевские оценки

строка (включая GStrings) оценивает значение true, если не null и не пусто, false, если значение null или пустое

def s = ''
...
if (s) 
    println 's is not empty'
else
    println 's is empty'

напечатает: 's is empty'

Булевая оценка коллекций и карт

Коллекции и карты оценивают значение true, если не null, а не пустое и false, если значение null или пустое

/* an empty map example*/
def userInfo = [:]
if (!userInfo)
    userInfo << ['user': 'Groot', 'species' : 'unknown' ]

добавит user: 'Groot' , species : 'unknown' качестве пользовательской информации по умолчанию, поскольку карта userInfo пуста (обратите внимание, что карта здесь не равна нулю)

С нулевым объектом код немного отличается, мы не можем вызывать << on userInfo, потому что он имеет значение null, мы должны выполнить назначение (см. Также булевскую оценку объекта):

/* an example with a null object (def does not implies Map type) */
def userInfo = null
if (!userInfo)
    userInfo = ['user': 'Groot', 'species' : 'unknown' ]

И с пустой картой:

/* The same example with a null Map */
Map<String,String> userInfo = null
if (!userInfo)
    userInfo = ['user': 'Groot', 'species' : 'unknown' ]

Объектная логическая оценка

ссылка на нулевой объект оценивается как false, а не нулевая ссылка на true, но для строк, коллекций, итераторов и перечислений она также учитывает размер.

def m = null

if (!m)
    println "empty"
else
    println "${m}"

будет печатать "пустые"

def m = [:]

if (!m)
    println "empty"
else
    println "${m}"

Карта не является нулевой, но пустой, этот код будет печатать «пустой»,

После

m << ['user' : 'Groot' ]

он распечатает карту:

[user:Groot]

Переопределение булевой оценки в определенном пользователем классе

Иногда может быть полезно иметь конкретное определение типа буфера в вашей собственной программе для каких-либо объектов.

/** an oversimplified robot controller */
class RunController {
    
    def complexCondition
    int position = 0
    
    def asBoolean() {
        return complexCondition(this);
    }
    def advanceTo(step) {
        position += step
    }
}
def runController = new RunController(complexCondition : { c -> c.position < 10 } )

assert runController
runController.advanceTo(5)
assert runController
runController.advanceTo(5)
// The limit has been reached : the controller evaluates to false
assert !runController

В этом коде показан избыточный контроллер робота, который проверяет, что положение робота не превышает 10 (с закрытием для оценки состояния)

Оценка персонажа

Символ оценивает значение true, если оно не равно нулю, false, если ноль

assert ! new Character((char)0)
assert ! new Character('\u0000Hello Zero Char'.charAt(0))
assert  new Character('Hello'.charAt(0))

Оценка соответствия

Matcher вычисляет значение true, если он может найти хотя бы одно совпадение, false, если совпадение не найдено

// a match is found => true
assert 'foo' =~ /[a-z]/
// the regexp does not match fully => no match => false
assert !( 'foo' ==~ /[a-z]/ )
// a match is found => true
assert 'foo' =~ /o/
// no match => false
assert !( 'foo' =~ /[A-Z]/ )

Оценка закрытия

Оценка закрытия - это оценка результата закрытия.

Все правила применяются: если закрытие возвращает нулевое число, нулевое число или пустую строку, коллекцию, карту или массив, она вычисляет значение false в противном случае в значение true.

// Closure return non zero number => true
assert { 42 }()
// closure returns 0 => false
assert ! ( { 0 }())
// closure returns null => false
assert !( { }())