Embarcadero Delphi
Запуск других программ

CreateProcess

Следующая функция инкапсулирует код для использования API-интерфейса CreateProcess для запуска других программ.

Он настраивается и может подождать, пока процесс вызова не завершится или не вернется немедленно.

Параметры:

• FileName - полный путь к исполняемому файлу
• Params - параметры командной строки или используйте пустую строку
• Folder - рабочая папка для вызываемой программы - если пустой путь будет извлечен из FileName
• WaitUntilTerminated - если истинная функция будет ждать завершения процесса
• WaitUntilIdle - если истинная функция вызовет функцию WaitForInputIdle и дождитесь, пока указанный процесс завершит обработку своего начального ввода и пока не будет ожидающих ввода пользователя
• RunMinimized - если истинный процесс будет запущен с минимальным
• ErrorCode - если функция не работает, это будет содержать обнаруженный код ошибки Windows

function ExecuteProcess(const FileName, Params: string; Folder: string; WaitUntilTerminated, WaitUntilIdle, RunMinimized: boolean;
  var ErrorCode: integer): boolean;
var
  CmdLine: string;
  WorkingDirP: PChar;
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
begin
  Result := true;
  CmdLine := '"' + FileName + '" ' + Params;
  if Folder = '' then Folder := ExcludeTrailingPathDelimiter(ExtractFilePath(FileName));
  ZeroMemory(@StartupInfo, SizeOf(StartupInfo));
  StartupInfo.cb := SizeOf(StartupInfo);
  if RunMinimized then
    begin
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW;
      StartupInfo.wShowWindow := SW_SHOWMINIMIZED;
    end;
  if Folder <> '' then WorkingDirP := PChar(Folder)
  else WorkingDirP := nil;
  if not CreateProcess(nil, PChar(CmdLine), nil, nil, false, 0, nil, WorkingDirP, StartupInfo, ProcessInfo) then
    begin
      Result := false;
      ErrorCode := GetLastError;
      exit;
    end;
  with ProcessInfo do
    begin
      CloseHandle(hThread);
      if WaitUntilIdle then WaitForInputIdle(hProcess, INFINITE);
      if WaitUntilTerminated then
        repeat
          Application.ProcessMessages;
        until MsgWaitForMultipleObjects(1, hProcess, false, INFINITE, QS_ALLINPUT) <> WAIT_OBJECT_0 + 1;
      CloseHandle(hProcess);
    end;
end;

Использование функции выше

var
  FileName, Parameters, WorkingFolder: string;
  Error: integer;
  OK: boolean;
begin
  FileName := 'C:\FullPath\myapp.exe';
  WorkingFolder := ''; // if empty function will extract path from FileName
  Parameters := '-p'; // can be empty 
  OK := ExecuteProcess(FileName, Parameters, WorkingFolder, false, false, false, Error);
  if not OK then ShowMessage('Error: ' + IntToStr(Error));
end;

Документация CreateProcess