excel-vba
워크 시트에서 마지막으로 사용한 행 또는 열 찾기 방법

비고

열에 마지막으로 비어 있지 않은 셀 찾기

이 예에서는 데이터 세트의 마지막 비어 있지 않은 행을 반환하는 메소드를 살펴 보겠습니다.

이 방법은 데이터 세트 내의 빈 영역에 관계없이 작동합니다.

그러나 병합 된 셀 이 관련된 경우 End 메서드가 병합 된 영역에 대해 "중지"되어 병합 된 영역의 첫 번째 셀을 반환하므로 주의 해야합니다 .

또한 숨겨진 행의 비어 있지 않은 셀은 고려되지 않습니다.

Sub FindingLastRow()
    Dim wS As Worksheet, LastRow As Long
    Set wS = ThisWorkbook.Worksheets("Sheet1")
    
    'Here we look in Column A
    LastRow = wS.Cells(wS.Rows.Count, "A").End(xlUp).Row
    Debug.Print LastRow
End Sub

위에 표시된 제한 사항을 해결하려면 다음 줄을 사용하십시오.
LastRow = wS.Cells(wS.Rows.Count, "A").End(xlUp).Row

다음으로 대체 될 수 있습니다 :

1. 마지막으로 사용한 "Sheet1" 행 :
   LastRow = wS.UsedRange.Row - 1 + wS.UsedRange.Rows.Count .

2. "Sheet1" 의 열 "A" 의 마지막 비어 있지 않은 셀의 경우 :

    Dim i As Long
    For i = LastRow To 1 Step -1
        If Not (IsEmpty(Cells(i, 1))) Then Exit For
    Next i
    LastRow = i
   

명명 된 범위를 사용하여 마지막 행 찾기

Sheet에 명명 된 범위가 있고 해당 동적 명명 된 범위의 마지막 행을 동적으로 가져 오려는 경우에 사용합니다. 또한 명명 된 범위가 첫 번째 행에서 시작하지 않는 경우를 다룹니다.

Sub FindingLastRow()
    
Dim sht As Worksheet
Dim LastRow As Long
Dim FirstRow As Long

Set sht = ThisWorkbook.Worksheets("form")

'Using Named Range "MyNameRange"
FirstRow = sht.Range("MyNameRange").Row

' in case "MyNameRange" doesn't start at Row 1
LastRow = sht.Range("MyNameRange").Rows.count + FirstRow - 1

End Sub

최신 정보:
예기치 않은 결과를 생성하므로 불연속 행이있는 명명 된 범위에 대해 @Jeeped가 잠재적 인 허점을 지적했습니다. 해당 문제를 해결하기 위해 코드는 다음과 같이 수정됩니다.
Asumptions : targes 시트 = form 라는 범위 = MyNameRange

Sub FindingLastRow()
    Dim rw As Range, rwMax As Long
    For Each rw In Sheets("form").Range("MyNameRange").Rows
        If rw.Row > rwMax Then rwMax = rw.Row
    Next
    MsgBox "Last row of 'MyNameRange' under Sheets 'form': " & rwMax
End Sub

범위 내의 마지막 셀의 행을 가져옵니다.

'if only one area (not multiple areas):
With Range("A3:D20")
    Debug.Print .Cells(.Cells.CountLarge).Row
    Debug.Print .Item(.Cells.CountLarge).Row 'using .item is also possible
End With 'Debug prints: 20

'with multiple areas (also works if only one area):
Dim rngArea As Range, LastRow As Long
With Range("A3:D20, E5:I50, H20:R35")
    For Each rngArea In .Areas
        If rngArea(rngArea.Cells.CountLarge).Row > LastRow Then 
            LastRow = rngArea(rngArea.Cells.CountLarge).Row
        End If
    Next
    Debug.Print LastRow 'Debug prints: 50
End With

워크 시트에서 비어 있지 않은 마지막 열 찾기

Private Sub Get_Last_Used_Row_Index()
    Dim wS As Worksheet
    
    Set wS = ThisWorkbook.Sheets("Sheet1")
    Debug.Print LastCol_1(wS)
    Debug.Print LastCol_0(wS)
End Sub

워크 시트에 데이터가 없는지 알고 싶다면 2 가지 옵션 중에서 선택할 수 있습니다.

• 아니오 : LastCol_1 사용 : wS.Cells(...,LastCol_1(wS)) 내에서 직접 사용할 수 있습니다.
• 예 : Use LastCol_0 : 사용하기 전에 함수에서 얻은 결과가 0인지 아닌지 테스트해야합니다

Public Function LastCol_1(wS As Worksheet) As Double
    With wS
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            LastCol_1 = .Cells.Find(What:="*", _
                                After:=.Range("A1"), _
                                Lookat:=xlPart, _
                                LookIn:=xlFormulas, _
                                SearchOrder:=xlByColumns, _
                                SearchDirection:=xlPrevious, _
                                MatchCase:=False).Column
        Else
            LastCol_1 = 1
        End If
    End With
End Function

Err 개체의 속성은 함수가 끝나면 자동으로 0으로 다시 설정됩니다.

Public Function LastCol_0(wS As Worksheet) As Double
    On Error Resume Next
    LastCol_0 = wS.Cells.Find(What:="*", _
                            After:=ws.Range("A1"), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByColumns, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Column
End Function

Range.CurrentRegion의 마지막 셀

Range.CurrentRegion 은 빈 셀로 둘러싸인 직사각형 범위 영역입니다. ="" 또는 ' 와 같은 수식이있는 빈 셀은 공백으로 간주되지 않습니다 ( ISBLANK Excel 함수로도).

Dim rng As Range, lastCell As Range
Set rng = Range("C3").CurrentRegion       ' or Set rng = Sheet1.UsedRange.CurrentRegion
Set lastCell = rng(rng.Rows.Count, rng.Columns.Count)

워크 시트에서 비어 있지 않은 마지막 행 찾기

Private Sub Get_Last_Used_Row_Index()
    Dim wS As Worksheet
    
    Set wS = ThisWorkbook.Sheets("Sheet1")
    Debug.Print LastRow_1(wS)
    Debug.Print LastRow_0(wS)
End Sub

워크 시트에 데이터가 없는지 알고 싶다면 2 가지 옵션 중에서 선택할 수 있습니다.

• NO : LastRow_1 사용 : wS.Cells(LastRow_1(wS),...) 내에서 직접 사용할 수 있습니다 wS.Cells(LastRow_1(wS),...)
• 예 : Use LastRow_0 : 사용하기 전에 함수에서 얻은 결과가 0인지 아닌지 테스트해야합니다.

Public Function LastRow_1(wS As Worksheet) As Double
    With wS
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            LastRow_1 = .Cells.Find(What:="*", _
                                After:=.Range("A1"), _
                                Lookat:=xlPart, _
                                LookIn:=xlFormulas, _
                                SearchOrder:=xlByRows, _
                                SearchDirection:=xlPrevious, _
                                MatchCase:=False).Row
        Else
            LastRow_1 = 1
        End If
    End With
End Function

Public Function LastRow_0(wS As Worksheet) As Double
    On Error Resume Next
    LastRow_0 = wS.Cells.Find(What:="*", _
                            After:=ws.Range("A1"), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Row
End Function

행에 마지막으로 비어 있지 않은 셀 찾기

이 예제에서는 한 행의 마지막 비어 있지 않은 열을 반환하는 메서드를 살펴 보겠습니다.

이 방법은 데이터 세트 내의 빈 영역에 관계없이 작동합니다.

그러나 병합 된 셀 이 관련된 경우 End 메서드가 병합 된 영역에 대해 "중지"되어 병합 된 영역의 첫 번째 셀을 반환하므로 주의 해야합니다 .

또한 숨겨진 열의 비어 있지 않은 셀은 고려되지 않습니다.

Sub FindingLastCol()
    Dim wS As Worksheet, LastCol As Long
    Set wS = ThisWorkbook.Worksheets("Sheet1")
    
    'Here we look in Row 1
    LastCol = wS.Cells(1, wS.Columns.Count).End(xlToLeft).Column
    Debug.Print LastCol
End Sub

워크 시트에서 마지막 비어 있지 않은 셀 찾기 - 성능 (배열)

• 배열을 사용하는 첫 번째 함수는 훨씬 빠릅니다.
• 선택적 매개 변수없이 호출하면 기본적으로 .ThisWorkbook.ActiveSheet
• 범위가 비어 있으면 Nothing 대신 Cell( 1, 1 ) 이 기본값으로 반환됩니다.

속도:

GetMaxCell (Array): Duration: 0.0000790063 seconds
GetMaxCell (Find ): Duration: 0.0002903480 seconds

. MicroTimer로 측정되었습니다.

Public Function GetLastCell(Optional ByVal ws As Worksheet = Nothing) As Range
    Dim uRng As Range, uArr As Variant, r As Long, c As Long
    Dim ubR As Long, ubC As Long, lRow As Long

    If ws Is Nothing Then Set ws = Application.ThisWorkbook.ActiveSheet
    Set uRng = ws.UsedRange
    uArr = uRng
    If IsEmpty(uArr) Then
        Set GetLastCell = ws.Cells(1, 1):   Exit Function
    End If
    If Not IsArray(uArr) Then
        Set GetLastCell = ws.Cells(uRng.Row, uRng.Column):  Exit Function
    End If
    ubR = UBound(uArr, 1):  ubC = UBound(uArr, 2)
    For r = ubR To 1 Step -1    '----------------------------------------------- last row
        For c = ubC To 1 Step -1
            If Not IsError(uArr(r, c)) Then
                If Len(Trim$(uArr(r, c))) > 0 Then
                    lRow = r:   Exit For
                End If
            End If
        Next
        If lRow > 0 Then Exit For
    Next
    If lRow = 0 Then lRow = ubR
    For c = ubC To 1 Step -1    '----------------------------------------------- last col
        For r = lRow To 1 Step -1
            If Not IsError(uArr(r, c)) Then
                If Len(Trim$(uArr(r, c))) > 0 Then
                    Set GetLastCell = ws.Cells(lRow + uRng.Row - 1, c + uRng.Column - 1)
                    Exit Function
                End If
            End If
        Next
    Next
End Function

'Returns last cell (max row & max col) using Find

Public Function GetMaxCell2(Optional ByRef rng As Range = Nothing) As Range 'Using Find

    Const NONEMPTY As String = "*"

    Dim lRow As Range, lCol As Range

    If rng Is Nothing Then Set rng = Application.ThisWorkbook.ActiveSheet.UsedRange

    If WorksheetFunction.CountA(rng) = 0 Then
        Set GetMaxCell2 = rng.Parent.Cells(1, 1)
    Else
        With rng
            Set lRow = .Cells.Find(What:=NONEMPTY, LookIn:=xlFormulas, _
                                        After:=.Cells(1, 1), _
                                        SearchDirection:=xlPrevious, _
                                        SearchOrder:=xlByRows)
            If Not lRow Is Nothing Then
                Set lCol = .Cells.Find(What:=NONEMPTY, LookIn:=xlFormulas, _
                                            After:=.Cells(1, 1), _
                                            SearchDirection:=xlPrevious, _
                                            SearchOrder:=xlByColumns)

                Set GetMaxCell2 = .Parent.Cells(lRow.Row, lCol.Column)
            End If
        End With
    End If
End Function

.

MicroTimer :

Private Declare PtrSafe Function getFrequency Lib "Kernel32" Alias "QueryPerformanceFrequency" (cyFrequency As Currency) As Long
Private Declare PtrSafe Function getTickCount Lib "Kernel32" Alias "QueryPerformanceCounter" (cyTickCount As Currency) As Long

Function MicroTimer() As Double
    Dim cyTicks1 As Currency
    Static cyFrequency As Currency

    MicroTimer = 0
    If cyFrequency = 0 Then getFrequency cyFrequency        'Get frequency
    getTickCount cyTicks1                                   'Get ticks
    If cyFrequency Then MicroTimer = cyTicks1 / cyFrequency 'Returns Seconds
End Function