ActionScript 3
外部ファイルのロード

備考

ローダーで外部画像/ SWFを読み込む

1. Loaderオブジェクトを作成する：

   var loader:Loader = new Loader();   //import 
   

2. ローダーにリスナーを追加します。標準のものは、完全なio /セキュリティエラーです

   loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadComplete); //when the loader is done loading, call this function
   loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, loadIOError); //if the file isn't found
   loader.contentLoaderInfo.addEventListener(SecurityErrorEvent.SECURITY_ERROR, loadSecurityError); //if the file isn't allowed to be loaded
   

3. 目的のファイルをロードします。

    loader.load(new URLRequest("image.png"));
   

4. イベントハンドラを作成する：

    function loadComplete(e:Event):void {
        //load complete
        //the loader is actually a display object itself, so you can just add it to the display list
        addChild(loader) 
        //or addChild(loader.content) to add the root content of what was loaded;
    }
        
    function loadIOError(e:IOErrorEvent):void {
        //the file failed to load, 
    }
       
    function loadSecurityError(e:SecurityError):void {
        //the file wasn't allowed to load
    }
   

Loaderクラスを使用したロードは非同期です。つまり、 loader.loadを呼び出した後、ファイルがロードされている間、アプリケーションは実行を継続します。ローダーがEvent.COMPLETEイベントをディスパッチするまで、ローダーのコンテンツは使用できません。

輸入が必要：

import flash.display.Loader;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.SecurityErrorEvent;
import flash.net.URLRequest;

FileStreamを使用したテキストファイルのロード（AIRランタイムのみ）

UTFテキストファイルを同期して読み込む方法の簡単な例。

import flash.filesystem.File;
import flash.filesystem.FileMode;
import flash.filesystem.FileStream;

//First, get a reference to the file you want to load
var myFile:File = File.documentsDirectory.resolvePath("lifestory.txt");

//Create a FileStream object
fileStream = new FileStream(); 

//open the file
fileStream.open(myFile, FileMode.READ);

//read the data and assign it to a local variable
var fileText:String = fileStream.readUTF();

//close the current filestream
fileStream.close();