Ricerca…


introduzione

La ricorsività è un metodo di programmazione in cui i sottoprogrammi chiamano se stessi. È molto conveniente risolvere alcuni tipi di problemi in modo elegante e generico. VHDL supporta la ricorsione. La maggior parte dei sintetizzatori logici lo supportano. In alcuni casi l'hardware dedotto è ancora migliore (più veloce, stessa dimensione) rispetto alla descrizione equivalente basata su loop.

Calcolo del peso di Hamming di un vettore

-- loop-based version
function hw_loop(v: std_logic_vector) return natural is
  variable h: natural;
begin
  h := 0;
  for i in v'range loop
    if v(i) = '1' then
      h := h + 1;
    end if;
  end loop;
  return h;
end function hw_loop;

-- recursive version
function hw_tree(v: std_logic_vector) return natural is
  constant size: natural := v'length;
  constant vv: std_logic_vector(size - 1 downto 0) := v;
  variable h: natural;
begin
  h := 0;
  if size = 1 and vv(0) = '1' then
    h := 1;
  elsif size > 1 then
    h := hw_tree(vv(size - 1 downto size / 2)) + hw_tree(vv(size / 2 - 1 downto 0));
  end if;
  return h;
end function hw_tree;


Modified text is an extract of the original Stack Overflow Documentation
Autorizzato sotto CC BY-SA 3.0
Non affiliato con Stack Overflow