Elm Language
Sottoscrizioni

CSS F# Haskell Language HTML JavaScript Node.js React Regular Expressions Ruby on Rails SVG
Ricerca…


Osservazioni

Gli abbonamenti sono mezzi per ascoltare gli input. Porte in entrata , eventi di tastiera o mouse, messaggi WebSocket, geolocalizzazione e modifiche alla visibilità della pagina, tutti possono fungere da input.

Abbonamento di base all'evento Time.every con "annulla iscrizione"

0.18.0

Il modello viene passato alle iscrizioni, il che significa che ogni modifica dello stato può modificare gli abbonamenti. 

import Html exposing ( Html, div, text, button )
import Html.Events exposing ( onClick )
import Time

main : Program Never Model Msg
main =
    Html.program
        { init = init
        , update = update
        , subscriptions = subscriptions
        , view = view
        }

-- MODEL

type alias Model =
    { time: Time.Time
    , suspended: Bool
    }

init : (Model, Cmd Msg)
init =
    ( Model 0 False, Cmd.none )

-- UPDATE

type Msg
    = Tick Time.Time
    | SuspendToggle

update : Msg -> Model -> ( Model, Cmd Msg )
update msg model =
    case msg of
        Tick newTime ->
            ( { model | time = newTime }, Cmd.none )

        SuspendToggle ->
            ( { model | suspended = not model.suspended }, Cmd.none )

-- SUBSCRIPTIONS

subscriptions : Model -> Sub Msg
subscriptions model =
    if model.suspended then
        Sub.none
    else
        Time.every Time.second Tick

-- VIEW

view : Model -> Html Msg
view model =
    div []
        [ div [] [ text <| toString model ]
        , button [ onClick SuspendToggle ] [ text ( if model.suspended then "Resume" else "Suspend" ) ]
        ]


Modified text is an extract of the original Stack Overflow Documentation
Autorizzato sotto CC BY-SA 3.0
Non affiliato con Stack Overflow