ada
Enumerazione

Sintassi

• function Enumeration ' Image (Argument: Enumeration'Base) return String;
• function Enumeration ' Img return String; - GNAT
• function Enumeration'Val (Argument: Universal_Integer) return Enumeration'Base;
• function Enumeration'Pos (Argument: Enumeration'Base) return Universal_Integer;
• function Enumeration'Enum_Rep (Argument: Enumeration'Base) return Universal_Integer;
• function Literal 'Enum_Rep return Universal_Integer; - GNAT
• funzione Letterale 'Indirizzo return System.Address;
• per Enumeration use (Literal_1 => Universal_Integer , Literal_n => Universal_Integer );
• ( Literal in Enumeration) restituisce Boolean;

Iterazione di letterali

Un letterale all'interno di un'enumerazione è di tipo discreto, quindi è possibile utilizzare l'attributo Image per scoprire quale letterale è come una forma di testo. Si noti che questo stampa la stessa parola come nel codice (ma in maiuscolo).

with Ada.Text_IO; use Ada.Text_IO;

procedure Main is
   type Fruit is (Banana, Pear, Orange, Melon);
begin
   for I in Fruit loop
      Put (Fruit'Image (I));
      New_Line;
   end loop;
end;

Risultato

BANANA
PEAR
ORANGE
MELON

Utilizzando il pacchetto Enumeration_IO

Invece di attribuire Image e Ada.Text_IO.Put su letterali di enumerazione, possiamo usare solo il pacchetto generico Ada.Text_IO.Enumeration_IO per stampare i letterali.

with Ada.Text_IO; use Ada.Text_IO;

procedure Main is
   type Fruit is (Banana, Pear, Orange, Melon);
   package Fruit_IO is new Enumeration_IO (Fruit); use Fruit_IO;
begin
   for I in Fruit loop
      Put (I);
      New_Line;
   end loop;
end;

Risultato

BANANA
PEAR
ORANGE
MELON

Maiuscole minuscole per i caratteri maiuscoli

L' Image attributo capitalizza tutti i caratteri dei valori letterali di enumerazione. La funzione Case_Rule_For_Names applica in maiuscolo per il primo carattere e fa il resto in minuscolo.

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Strings.Maps.Constants; use Ada.Strings.Maps.Constants;
with Ada.Strings.Fixed; use Ada.Strings.Fixed;

procedure Main is
   type Fruit is (Banana, Pear, Orange, Melon);
   function Case_Rule_For_Names (Item : String) return String is
   begin
      return Translate (Item (Item'First .. Item'First), Upper_Case_Map) & Translate (Item (Item'First + 1 .. Item'Last), Lower_Case_Map);
   end;
begin
   for I in Fruit loop
      Put (Case_Rule_For_Names (Fruit'Image (I)));
      New_Line;
   end loop;
end;

Risultato

Banana
Pear
Orange
Melon

Title Case, Using Enumeration_IO, For a Subrange

Combinando il cambiamento di maiuscole / minuscole con Enumeration_IO e utilizzando un buffer di testo per l'immagine. Il primo personaggio è manipolato sul posto.

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Characters.Handling; use Ada.Characters.Handling;

procedure Main is
    type Fruit is (Banana, Pear, Orange, Melon);
    package Fruit_IO is new Enumeration_IO (Fruit);
    Buffer : String (1 .. Fruit'Width);
begin
   for I in Fruit range Pear .. Fruit'Last loop
       Fruit_IO.Put (To => Buffer,
                     Item => I,
                     Set => Lower_Case);
       Buffer (Buffer'First) := To_Upper (Buffer (Buffer'First));
       Put_Line (Buffer);
   end loop;
end;

Risultato

Pear  
Orange
Melon