Intel x86 Assembly Language & Microarchitecture
पूर्णांक में दशमलव स्ट्रिंग परिवर्तित करना

टिप्पणियों

function string_to_integer(str):
    result = 0
    for (each characters in str, left to right):
        result = result * 10
        add ((code of the character) - (code of character 0)) to result
    return result

IA-32 असेंबली, GAS, cdecl कॉलिंग कन्वेंशन

# make this routine available outside this translation unit
.globl string_to_integer

string_to_integer:
    # function prologue
    push %ebp
    mov %esp, %ebp
    push %esi

    # initialize result (%eax) to zero
    xor %eax, %eax
    # fetch pointer to the string
    mov 8(%ebp), %esi

    # clear high bits of %ecx to be used in addition
    xor %ecx, %ecx
    # do the conversion
string_to_integer_loop:
    # fetch a character
    mov (%esi), %cl
    # exit loop when hit to NUL character
    test %cl, %cl
    jz string_to_integer_loop_end
    # multiply the result by 10
    mov $10, %edx
    mul %edx
    # convert the character to number and add it
    sub $'0', %cl
    add %ecx, %eax
    # proceed to next character
    inc %esi
    jmp string_to_integer_loop
string_to_integer_loop_end:

    # function epilogue
    pop %esi
    leave
    ret

यह गैस शैली कोड पहला तर्क है, जो पूर्णांक के लिए इस फ़ंक्शन कॉल करने से पहले ढेर पर धकेल दिया जाता है, और के माध्यम से इसे वापस के रूप में दिया दशमलव स्ट्रिंग में परिवर्तित कर देंगे %eax । %esi का मूल्य बच जाता है क्योंकि यह कैली-सेव रजिस्टर है और इसका उपयोग किया जाता है।

कोड को सरल बनाने के लिए अतिप्रवाह / रैपिंग और अमान्य वर्णों की जाँच नहीं की जाती है।

C में, इस कोड का उपयोग इस तरह किया जा सकता है (मान लिया गया कि unsigned int और संकेत 4-बाइट लंबे हैं):

#include <stdio.h>

unsigned int string_to_integer(const char* str);

int main(void) {
    const char* testcases[] = {
        "0",
        "1",
        "10",
        "12345",
        "1234567890",
        NULL
    };
    const char** data;
    for (data = testcases; *data != NULL; data++) {
        printf("string_to_integer(%s) = %u\n", *data, string_to_integer(*data));
    }
    return 0;
}

नोट: कुछ वातावरण में, विधानसभा कोड में दो string_to_integer को C कोड के साथ काम करने देने के लिए _string_to_integer (अंडरस्कोर जोड़ें) में बदलना होगा।

16-बिट अहस्ताक्षरित पूर्णांक पढ़ने के लिए MS-DOS, TASM / MASM फ़ंक्शन

इनपुट से 16-बिट अहस्ताक्षरित पूर्णांक पढ़ें।

यह फ़ंक्शन बफर स्ट्रिंग को पढ़ने के लिए 21 / AH = 0Ah इंटरप्ट सेवा का उपयोग करता है।
एक बफ़र किए गए स्ट्रिंग का उपयोग उपयोगकर्ता को समीक्षा करने देता है कि उन्होंने इसे प्रसंस्करण के लिए कार्यक्रम में पास करने से पहले क्या टाइप किया था।
छह अंक तक पढ़े जाते हैं (जैसे 65535 = 2 ¹⁶ - 1 में छह अंक होते हैं)।

अंक से संख्या में मानक रूपांतरण करने के अलावा, यह फ़ंक्शन अमान्य इनपुट और अतिप्रवाह (संख्या 16 बिट्स फिट करने के लिए बहुत बड़ी) का भी पता लगाता है।

मान लौटाएं

फ़ंक्शन AX में पढ़ी गई संख्या को लौटाता है। झंडे ZF , CF , OF बताती हैं कि आपरेशन सफलतापूर्वक या नहीं और क्यों पूरा किया।

ZF का उपयोग जल्दी से वैध बनाम अमान्य इनपुट को अलग बताने के लिए किया जा सकता है।

प्रयोग

call read_uint16
jo _handle_overflow            ;Number too big (Optional, the test below will do)
jnz _handle_invalid            ;Number format is invalid

;Here AX is the number read

कोड

;Returns:
  ;
  ;If the number is correctly converted:
  ;   ZF = 1, CF = 0, OF = 0
  ;   AX = number
  ;
  ;If the user input an invalid digit:
  ;   ZF = 0, CF = 1, OF = 0
  ;   AX = Partially converted number
  ;
  ;If the user input a number too big
  ;   ZF = 0, CF = 1, OF = 1
  ;   AX = 07fffh
  ;
  ;ZF/CF can be used to discriminate valid vs invalid inputs
  ;OF can be used to discrimate the invalid inputs (overflow vs invalid digit)
  ;
  read_uint16:
    push bp   
    mov bp, sp

    ;This code is an example in Stack Overflow Documentation project.
    ;x86/Converting Decimal strings to integers


    ;Create the buffer structure on the stack

    sub sp, 06h                ;Reserve 6 byte on the stack (5 + CR)
    push 0006h                 ;Header

    push ds
    push bx
    push cx
    push dx

    ;Set DS = SS

    mov ax, ss
    mov ds, ax                           
                  

    ;Call Int 21/AH=0A

    lea dx, [bp-08h]            ;Address of the buffer structure
    mov ah, 0ah
    int 21h

    ;Start converting

    lea si, [bp-06h]
    xor ax, ax
    mov bx, 10
    xor cx, cx

   _r_ui16_convert:

    ;Get current char

    mov cl, BYTE PTR [si]
    inc si

    ;Check if end of string

    cmp cl, CR_CHAR
    je _r_ui16_end                      ;ZF = 1, CF = 0, OF = 0
   
    ;Convert char into digit and check

    sub cl, '0'
    jb _r_ui16_carry_end                ;ZF = 0, CF = 1, OF = X -> 0
    cmp cl, 9
    ja _r_ui16_carry_end                ;ZF = 0, CF = 0 -> 1, OF = X -> 0


    ;Update the partial result (taking care of overflow)

    ;AX = AX * 10
    mul bx

    ;DX:AX = DX:AX + CX
    add ax, cx
    adc dx, 0
       
    test dx, dx
   jz _r_ui16_convert            ;No overflow
   
    ;set OF and CF
    mov ax, 8000h
    dec ax                           
    stc

   jmp _r_ui16_end                      ;ZF = 0, CF = 1, OF = 1
    
   _r_ui16_carry_end:

    or bl, 1                ;Clear OF and ZF
    stc                     ;Set carry
 
    ;ZF = 0, CF = 1, OF = 0

   _r_ui16_end:
    ;Don't mess with flags hereafter!

    pop dx
    pop cx
    pop bx
    pop ds

    mov sp, bp

    pop bp
    ret

    CR_CHAR EQU 0dh

NASM पोर्टिंग

NASM को कोड पोर्ट करने के लिए PTR कीवर्ड को मेमोरी एक्सेस से हटा दें (जैसे कि mov cl, BYTE PTR [si] बन जाता है mov cl, BYTE [si] )

MS-DOS, TASM / MASM फ़ंक्शन बाइनरी, क्वाटर्नेरी, ऑक्टल, हेक्स में 16-बिट संख्या को प्रिंट करने के लिए

बाइनरी, क्वाटर्नेरी, ऑक्टल, हेक्साडेसिमल और दो की एक सामान्य शक्ति में एक संख्या प्रिंट करें

सभी आधार जो दो की शक्ति हैं, जैसे कि बाइनरी (2 ¹ ), चतुर्धातुक (2 ² ), अष्टाधारी (2 ³ ), हेक्साडेसिमल (2 ⁴ ) आधार, अंकों की प्रति ¹ अंक की एक अभिन्न संख्या है।
इस प्रकार अंक के प्रत्येक अंक ² को पुनः प्राप्त करने के लिए हम बस एलएसबी (दाएं) से शुरू होने वाले एन बिट्स की संख्या परिचय समूह को तोड़ते हैं।
उदाहरण के लिए चतुर्धातुक आधार के लिए, हम दो बिट्स के समूहों में 16-बिट संख्या को तोड़ते हैं। ऐसे 8 समूह हैं।
दो आधारों की सभी शक्ति में 16 बिट्स फिट करने वाले समूहों की एक अभिन्न संख्या होती है; उदाहरण के लिए, ऑक्टल बेस में 3 बिट्स के 5 समूह होते हैं, जो 16 में से 3 · 5 = 15 बिट्स होते हैं, जो 1 बिट ³ का एक आंशिक समूह छोड़ते हैं।

एल्गोरिथ्म सरल है, हम प्रत्येक समूह को एक और ऑपरेशन के बाद एक बदलाव के साथ अलग करते हैं।
यह प्रक्रिया समूहों के प्रत्येक आकार के लिए या दूसरे शब्दों में, दो की किसी भी आधार शक्ति के लिए काम करती है।

सही क्रम में अंकों को दिखाने के लिए फ़ंक्शन सबसे महत्वपूर्ण समूह (सबसे बाईं ओर) को अलग करके शुरू होता है, जिससे यह जानना महत्वपूर्ण है: क) एक समूह कितने बिट डी और बी) बिट स्थिति एस जहां सबसे बाईं ओर है समूह शुरू होता है।
इन मूल्यों को पूर्वनिर्मित किया जाता है और सावधानी से बनाए गए स्थिरांक में संग्रहीत किया जाता है।

पैरामीटर

पैरामीटर को स्टैक पर धकेलना चाहिए।
हर एक 16-बिट चौड़ा है।
उन्हें पुश के क्रम में दिखाया गया है।

प्रयोग

push 241
push BASE16
push 0
call print_pow2              ;Prints f1

push 241
push BASE16
push 1
call print_pow2              ;Prints 00f1

push 241
push BASE2
push 0
call print_pow2              ;Prints 11110001

TASM उपयोगकर्ताओं पर ध्यान दें : यदि आप EQU परिभाषित स्थिरांक को उस कोड के बाद डालते हैं जो उनका उपयोग करता है, तो TASM के /m ध्वज के साथ बहु-पास को सक्षम करें या आपको आगे संदर्भ संदर्भ ओवरराइड की आवश्यकता होगी ।

कोड

;Parameters (in order of push):
;
;number
;base (Use constants below)
;print leading zeros
print_pow2:
 push bp
 mov bp, sp

 push ax
 push bx
 push cx
 push dx
 push si
 push di

 ;Get parameters into the registers

 ;SI = Number (left) to convert
 ;CH = Amount of bits to shift for each digit (D)
 ;CL = Amount od bits to shift the number (S)
 ;BX = Bit mask for a digit

 mov si, WORD PTR [bp+08h]
 mov cx, WORD PTR [bp+06h]            ;CL = D, CH = S

 ;Computes BX = (1 << D)-1
 
 mov bx, 1
 shl bx, cl
 dec bx

 xchg cl, ch              ;CL = S, CH = D

_pp2_convert:
 mov di, si
 shr di, cl
 and di, bx         ;DI = Current digit

 or WORD PTR [bp+04h], di             ;If digit is non zero, [bp+04h] will become non zero
                      ;If [bp+04h] was non zero, result is non zero
 jnz _pp2_print                       ;Simply put, if the result is non zero, we must print the digit

 
 ;Here we have a non significant zero
 ;We should skip it BUT only if it is not the last digit (0 should be printed as "0" not
 ;an empty string)

 test cl, cl
 jnz _pp_continue


_pp2_print:
 ;Convert digit to digital and print it

 
 mov dl, BYTE PTR [DIGITS + di]
 mov ah, 02h
 int 21h


_pp_continue:
 ;Remove digit from the number

 sub cl, ch
jnc _pp2_convert

 pop di
 pop si
 pop dx
 pop cx
 pop bx
 pop ax

 pop bp
 ret 06h

डेटा

This data must be put in the data segment, the one reached by `DS`.

DIGITS    db    "0123456789abcdef"

;Format for each WORD is S D where S and D are bytes (S the higher one)
;D = Bits per digit  --> log2(BASE)
;S = Initial shift count --> D*[ceil(16/D)-1]

BASE2    EQU    0f01h
BASE4    EQU    0e02h
BASE8    EQU    0f03h
BASE16    EQU    0c04h

NASM पोर्टिंग

NASM पर कोड पोर्ट करने के लिए PTR कीवर्ड को मेमोरी एक्सेस से हटा दें (जैसे mov si, WORD PTR [bp+08h] mov si, WORD PTR [bp+08h] )

समारोह का विस्तार करना

फ़ंक्शन को आसानी से 2 ²⁵⁵ तक बढ़ाया जा सकता है, हालांकि 2 ¹⁶ से ऊपर का प्रत्येक आधार एक ही अंक प्रिंट करेगा क्योंकि संख्या केवल 16 बिट्स है।

आधार जोड़ने के लिए:

1. एक नया स्थिर BASEx परिभाषित करें जहाँ x 2 ^{n है} ।
   निचला बाइट, जिसका नाम D है , D = n है ।
   ऊपरी बाइट, जिसका नाम S है , उच्च समूह के बिट्स में स्थिति है। इसकी गणना S = n · (n16 / n ) - 1) के रूप में की जा सकती है।
2. स्ट्रिंग DIGITS में आवश्यक अंक जोड़ें।

उदाहरण: आधार 32 जोड़ना

हमारे पास D = 5 और S = 15 है, इसलिए हम BASE32 EQU 0f05h परिभाषित करते हैं।
फिर हम सोलह और अंक जोड़ते हैं: DIGITS db "0123456789abcdefghijklmnopqrstuv" ।

जैसा कि यह स्पष्ट होना चाहिए, DIGITS स्ट्रिंग को संपादित करके अंकों को बदला जा सकता है।

¹ यदि B एक आधार है, तो इसकी परिभाषा प्रति B अंक है। अंकों प्रति बिट्स की संख्या इस प्रकार लॉग ऑन है ₂ (बी)। दो आधारों की शक्ति के लिए यह ₂ (2 ⁿ ) = n लॉग करने के लिए सरल करता है जो परिभाषा द्वारा पूर्णांक है।

² इस संदर्भ में यह अनुमान लगाया जाता है कि विचाराधीन आधार दो आधार 2 ^एन की शक्ति है।

³ आधार B = 2 ^{n के} लिए बिट समूहों का एक अभिन्न नंबर होना चाहिए जो कि n होना चाहिए | 16 ( n भाग 16)। चूंकि 16 में एकमात्र कारक 2 है, इसलिए यह होना चाहिए कि n स्वयं दो की शक्ति है। तो B का फॉर्म 2 ^{2 k है} या समकक्ष लॉग ₂ ( लॉग ₂ ( B )) एक पूर्णांक होना चाहिए।

MS-DOS, TASM / MASM, दशमलव में 16-बिट संख्या मुद्रित करने के लिए कार्य करता है

दशमलव में 16-बिट अहस्ताक्षरित संख्या प्रिंट करें

अंक को प्रिंट करने के लिए इंटरप्ट सर्विस इंट 21 / AH = 02h का उपयोग किया जाता है।
संख्या से अंक तक मानक रूपांतरण div निर्देश के साथ किया जाता है, लाभांश शुरू में दस फिटिंग 16 बिट्स (10 ⁴ ) की उच्चतम शक्ति है और यह प्रत्येक पुनरावृत्ति पर कम शक्तियों के लिए कम हो जाता है।

पैरामीटर

मापदंडों को धक्का के क्रम में दिखाया गया है।
प्रत्येक एक 16 बिट्स है।

प्रयोग

push 241
push 0
call print_dec          ;prints 241

push 56
push 1
call print_dec          ;prints 00056

push 0
push 0
call print_dec          ;prints 0

कोड

;Parameters (in order of push):
;
;number
;Show leading zeros
print_dec:
 push bp
 mov bp, sp

 push ax
 push bx
 push cx
 push dx

 ;Set up registers:
 ;AX = Number left to print
 ;BX = Power of ten to extract the current digit
 ;DX = Scratch/Needed for DIV
 ;CX = Scratch

 mov ax, WORD PTR [bp+06h]
 mov bx, 10000d
 xor dx, dx

_pd_convert:     
 div bx                           ;DX = Number without highmost digit, AX = Highmost digit
 mov cx, dx                       ;Number left to print

 ;If digit is non zero or param for leading zeros is non zero
 ;print the digit
 or WORD PTR [bp+04h], ax
 jnz _pd_print

 ;If both are zeros, make sure to show at least one digit so that 0 prints as "0"
 cmp bx, 1
 jne _pd_continue

_pd_print:

 ;Print digit in AL

 mov dl, al
 add dl, '0'
 mov ah, 02h
 int 21h

_pd_continue:
 ;BX = BX/10
 ;DX = 0

 mov ax, bx
 xor dx, dx
 mov bx, 10d
 div bx
 mov bx, ax

 ;Put what's left of the number in AX again and repeat...
 mov ax, cx

 ;...Until the divisor is zero
 test bx, bx
jnz _pd_convert

 pop dx
 pop cx
 pop bx
 pop ax

 pop bp
 ret 04h

NASM पोर्टिंग

NASM को कोड पोर्ट करने के लिए मेमोरी एक्सेस से PTR कीवर्ड हटाएं (जैसे mov ax, WORD PTR [bp+06h] mov ax, WORD [bp+06h] )