Visual Basic .NET Language
एक्सटेंशन के तरीके

टिप्पणियों

एक विस्तार विधि बनाना

एक्सटेंशन विधियाँ उन पुस्तकालयों के व्यवहार को विस्तारित करने के लिए उपयोगी होती हैं जो हमारे पास नहीं हैं।

वे संकलक की शुगर के लिए उदाहरण के तरीकों के समान उपयोग किए जाते हैं:

Sub Main()
    Dim stringBuilder = new StringBuilder()

    'Extension called directly on the object.
    stringBuilder.AppendIf(true, "Condition was true")

    'Extension called as a regular method. This defeats the purpose
    'of an extension method but should be noted that it is possible.
    AppendIf(stringBuilder, true, "Condition was true")

End Sub

<Extension>
Public Function AppendIf(stringBuilder As StringBuilder, condition As Boolean, text As String) As StringBuilder
    If(condition) Then stringBuilder.Append(text)

    Return stringBuilder
End Function

प्रयोग करने योग्य विस्तार विधि के लिए, विधि को Extension विशेषता की आवश्यकता होती है और Module में घोषित करने की आवश्यकता होती है।

विस्तार विधियों के साथ भाषा को अधिक कार्यात्मक बनाना

विस्तार पद्धति का एक अच्छा उपयोग भाषा को अधिक कार्यात्मक बनाना है

Sub Main()
    Dim strings = { "One", "Two", "Three" }

    strings.Join(Environment.NewLine).Print()
End Sub

<Extension>
Public Function Join(strings As IEnumerable(Of String), separator As String) As String
    Return String.Join(separator, strings)
End Function

<Extension>
Public Sub Print(text As String)
    Console.WriteLine(text)
End Sub

पैडिंग न्यूमेरिक्स

Public Module Usage
  Public Sub LikeThis()
    Dim iCount As Integer
    Dim sCount As String

    iCount = 245
    sCount = iCount.PadLeft(4, "0")

    Console.WriteLine(sCount)
    Console.ReadKey()
  End Sub
End Module



Public Module Padding
  <Extension>
  Public Function PadLeft(Value As Integer, Length As Integer) As String
    Return Value.PadLeft(Length, Space(Length))
  End Function



  <Extension>
  Public Function PadRight(Value As Integer, Length As Integer) As String
    Return Value.PadRight(Length, Space(Length))
  End Function



  <Extension>
  Public Function PadLeft(Value As Integer, Length As Integer, Character As Char) As String
    Return CStr(Value).PadLeft(Length, Character)
  End Function



  <Extension>
  Public Function PadRight(Value As Integer, Length As Integer, Character As Char) As String
    Return CStr(Value).PadRight(Length, Character)
  End Function
End Module

मजबूत नाम से विधानसभा संस्करण प्राप्त करना

एक एक्सटेंशन विधि को एक्सटेंशन के रूप में और एक नियमित विधि के रूप में कॉल करने का उदाहरण।

public Class MyClass  
  Sub Main()
        
        'Extension called directly on the object.
        Dim Version = Assembly.GetExecutingAssembly.GetVersionFromAssembly()

        'Called as a regular method.
        Dim Ver = GetVersionFromAssembly(SomeOtherAssembly)

    End Sub
End Class

एक मॉड्यूल में विस्तार विधि। यदि मॉड्यूल एक dll में संकलित हैं और किसी अन्य असेंबली में संदर्भित किया जाएगा, तो मॉड्यूल को सार्वजनिक करें।

Public Module Extensions
    ''' <summary>
    ''' Returns the version number from the specified assembly using the assembly's strong name.
    ''' </summary>
    ''' <param name="Assy">[Assembly] Assembly to get the version info from.</param>
    ''' <returns>[String]</returns>
    <Extension>
    Friend Function GetVersionFromAssembly(ByVal Assy As Assembly) As String
        Return Split(Split(Assy.FullName,",")(1),"=")(1)
    End Function
End Module