Buscar..
Sintaxis
- cierre.currir (parámetro)
- cierre.rcurry (parámetro)
- cierre.ncurry (índice, parámetros ...)
Observaciones
Hacer un cierre produce un nuevo cierre con uno o más de sus parámetros que tienen un valor fijo
El cierre a la izquierda o la derecha de un cierre que no tiene parámetros o un índice basado en el cierre de un cierre que tiene menos de dos parámetros lanza una
IllegalArgumentException
Currying izquierda
def pow = { base, exponent ->
base ** exponent
}
assert pow(3, 2) == 9
def pow2 = pow.curry(2) //base == 2
assert pow2(3) == 8
Currying derecho
def dividable = { a, b ->
a % b == 0
}
assert dividable(2, 3) == false
assert dividable(4, 2) == true
def even = dividable.rcurry(2) // b == 2
assert even(2) == true
assert even(3) == false
Índice basado en currying
def quatNorm = { a, b, c, d ->
Math.sqrt(a*a + b*b + c*c + d*d)
}
assert quatNorm(1, 4, 4, -4) == 7.0
def complexNorm = quatNorm.ncurry(1, 0, 0) // b, c == 0
assert complexNorm(3, 4) == 5.0
Cierre de curry sin parámetro explícito.
def noParam = {
"I have $it"
}
def noParamCurry = noParam.curry(2)
assert noParamCurry() == 'I have 2'
Cierre de curry sin parámetros.
def honestlyNoParam = { ->
"I Don't have it"
}
// The following all throw IllegalArgumentException
honestlyNoParam.curry('whatever')
honestlyNoParam.rcurry('whatever')
honestlyNoParam.ncurry(0, 'whatever')
Modified text is an extract of the original Stack Overflow Documentation
Licenciado bajo CC BY-SA 3.0
No afiliado a Stack Overflow