common-lisp
Musterabgleich

Überblick

Die zwei Hauptbibliotheken, die Musterabgleich in Common Lisp bereitstellen, sind Optima und Trivia . Beide bieten eine ähnliche übereinstimmende API und Syntax. Trivia bietet jedoch eine einheitliche Schnittstelle, um das Matching und defpattern .

Senden von Clack-Anforderungen

Da eine Clack-Anforderung als Plist dargestellt wird, können Sie den Musterabgleich als Einstiegspunkt in die Clack-App verwenden, um die Anfrage an die entsprechenden Controller weiterzuleiten

(defvar *app*
  (lambda (env)
    (match env
      ((plist :request-method :get
              :request-uri uri)
       (match uri
         ("/" (top-level))
         ((ppcre "/tag/(\\w+)/$" name) (tag-page name)))))))

Hinweis: Um *app* zu starten, übergeben wir es an Clackup. ej (clack:clackup *app*)

defun-match

Mit Pattern Matching kann man Funktionsdefinition und Pattern Matching ähnlich wie SML miteinander verflechten.

(trivia:defun-match fib (index)
  "Return the corresponding term for INDEX."
  (0 1)
  (1 1)
  (index (+ (fib (1- index)) (fib (- index 2)))))

(fib 5)
;; => 8

Konstruktormuster

Cons-Zellen, Strukturen, Vektoren, Listen usw. können mit Konstruktormustern abgeglichen werden.

(loop for i from 1 to 30
      do (format t "~5<~a~;~>"
                 (match (cons (mod i 3)
                              (mod i 5))
                   ((cons 0 0) "Fizzbuzz")
                   ((cons 0 _) "Fizz")
                   ((cons _ 0) "Buzz")
                   (_ i)))
      when (zerop (mod i 5)) do (terpri))
; 1    2    Fizz 4    Buzz 
; Fizz 7    8    Fizz Buzz 
; 11   Fizz 13   14   Fizzbuzz
; 16   17   Fizz 19   Buzz 
; Fizz 22   23   Fizz Buzz 
; 26   Fizz 28   29   Fizzbuzz

Guard-Muster

Schutzmuster können verwendet werden, um zu überprüfen, ob ein Wert eine beliebige Testform erfüllt.

(dotimes (i 5)
  (format t "~d: ~a~%"
          i (match i
              ((guard x (oddp x)) "Odd!")
              (_ "Even!"))))
; 0: Even!
; 1: Odd!
; 2: Even!
; 3: Odd!
; 4: Even!