common-lisp
La coincidencia de patrones
Buscar..
Visión general
Las dos bibliotecas principales que proporcionan la coincidencia de patrones en Common Lisp son Optima y Trivia . Ambos proporcionan una API y una sintaxis similares. Sin embargo, trivia proporciona una interfaz unificada para extender la coincidencia, defpattern .
Despachando solicitudes de Clack
Debido a que una solicitud de clack se representa como una lista, podemos usar la coincidencia de patrones como punto de entrada a la aplicación de clack como una forma de enrutar la solicitud a sus controladores apropiados
(defvar *app*
(lambda (env)
(match env
((plist :request-method :get
:request-uri uri)
(match uri
("/" (top-level))
((ppcre "/tag/(\\w+)/$" name) (tag-page name)))))))
Nota: Para iniciar *app* lo pasamos a clackup. ej (clack:clackup *app*)
defun-match
El uso de la coincidencia de patrones permite vincular la definición de la función y la coincidencia de patrones, similar a SML.
(trivia:defun-match fib (index)
"Return the corresponding term for INDEX."
(0 1)
(1 1)
(index (+ (fib (1- index)) (fib (- index 2)))))
(fib 5)
;; => 8
Patrones de constructor
Las celdas, estructuras, vectores, listas y demás pueden combinarse con patrones de constructor.
(loop for i from 1 to 30
do (format t "~5<~a~;~>"
(match (cons (mod i 3)
(mod i 5))
((cons 0 0) "Fizzbuzz")
((cons 0 _) "Fizz")
((cons _ 0) "Buzz")
(_ i)))
when (zerop (mod i 5)) do (terpri))
; 1 2 Fizz 4 Buzz
; Fizz 7 8 Fizz Buzz
; 11 Fizz 13 14 Fizzbuzz
; 16 17 Fizz 19 Buzz
; Fizz 22 23 Fizz Buzz
; 26 Fizz 28 29 Fizzbuzz
Patrón de guardia
Los patrones de guardia se pueden usar para verificar que un valor satisfaga una forma de prueba arbitraria.
(dotimes (i 5)
(format t "~d: ~a~%"
i (match i
((guard x (oddp x)) "Odd!")
(_ "Even!"))))
; 0: Even!
; 1: Odd!
; 2: Even!
; 3: Odd!
; 4: Even!