F#
Diskriminerade fackföreningar

Namnge delar av tuples inom diskriminerade fackföreningar

När du definierar diskriminerade fackföreningar kan du namnge element i tupeltyper och använda dessa namn under mönstermatchning.

type Shape = 
    | Circle of diameter:int
    | Rectangle of width:int * height:int

let shapeIsTenWide = function
    | Circle(diameter=10) 
    | Rectangle(width=10) -> true
    | _ -> false

Dessutom namnge elementen i diskriminerade fackföreningar förbättrar koden läsbarhet och interoperabilitet med C # - förutsatt att namnen kommer att användas för egenskaper 'namn och konstruktörer parametrar. Standardgenererade namn i interopkod är "Item", "Item1", "Item2" ...

Grundläggande diskriminerad användning av unionen

Diskriminerade fackföreningar i F # erbjuder ett sätt att definiera typer som kan innehålla ett antal olika datatyper. Deras funktionalitet liknar C ++ fackföreningar eller VB-varianter, men med den extra fördelen att de är typsäkra.

// define a discriminated union that can hold either a float or a string
type numOrString = 
    | F of float
    | S of string

let str = S "hi" // use the S constructor to create a string
let fl = F 3.5 // use the F constructor to create a float

// you can use pattern matching to deconstruct each type
let whatType x = 
    match x with
        | F f -> printfn "%f is a float" f
        | S s -> printfn "%s is a string" s

whatType str // hi is a string
whatType fl // 3.500000 is a float

Fackföreningar i Enum-stil

Typinformation behöver inte inkluderas i fall av diskriminerad fackförening. Genom att utelämna typinformation kan du skapa en union som helt enkelt representerar en uppsättning val, liknande enum.

// This union can represent any one day of the week but none of 
// them are tied to a specific underlying F# type
type DayOfWeek = Monday | Tuesday | Wednesday | Thursday | Friday | Saturday | Sunday

Konvertering till och från strängar med Reflektion

Ibland är det nödvändigt att konvertera en diskriminerad union till och från en sträng:

module UnionConversion 
    open Microsoft.FSharp.Reflection
    
    let toString (x: 'a) = 
        match FSharpValue.GetUnionFields(x, typeof<'a>) with
        | case, _ -> case.Name

    let fromString<'a> (s : string) =
        match FSharpType.GetUnionCases typeof<'a> |> Array.filter (fun case -> case.Name = s) with 
        | [|case|] -> Some(FSharpValue.MakeUnion(case, [||])) :?> 'a)
        | _ -> None

Enskilt fall diskriminerad fackförening

Ett enskilt fall diskriminerat fackförbund är som alla andra diskriminerade fackföreningar förutom att det bara har ett fall.

// Define single-case discriminated union type.
type OrderId = OrderId of int
// Construct OrderId type.
let order = OrderId 123
// Deconstruct using pattern matching. 
// Parentheses used so compiler doesn't think it is a function definition.   
let (OrderId id) = order

Det är användbart för att säkerställa typsäkerhet och används ofta i F # i motsats till C # och Java där det är mer omkostnader att skapa nya typer.

Följande två definitioner av alternativ typ resulterar i att samma enskilt diskriminerade fackförening förklaras:

type OrderId = | OrderId of int

type OrderId =
      | OrderId of int

Använda diskriminerade fackföreningar i enstaka fall som poster

Ibland är det användbart att skapa facktyper med bara ett fall för att implementera rekordliknande typer:

type Point = Point of float * float

let point1 = Point(0.0, 3.0)

let point2 = Point(-2.5, -4.0)

Dessa blir mycket användbara eftersom de kan sönderdelas via mönstermatchning på samma sätt som tupelargument kan:

let (Point(x1, y1)) = point1
// val x1 : float = 0.0
// val y1 : float = 3.0

let distance (Point(x1,y1)) (Point(x2,y2)) =
    pown (x2-x1) 2 + pown (y2-y1) 2 |> sqrt
// val distance : Point -> Point -> float

distance point1 point2
// val it : float = 7.433034374

RequireQualifiedAccess

Med attributet RequireQualifiedAccess måste fackföreningar hänvisas till som MyUnion.MyCase istället för bara MyCase . Detta förhindrar namnkollisioner i det bifogade namnområdet eller modulen:

type [<RequireQualifiedAccess>] Requirements =
    None | Single | All

// Uses the DU with qualified access
let noRequirements = Requirements.None

// Here, None still refers to the standard F# option case
let getNothing () = None

// Compiler error unless All has been defined elsewhere
let invalid = All

Om till exempel System har öppnats hänvisar Single till System.Single . Det finns ingen kollision med fackföreningen Requirements.Single . Requirements.Single .

Rekursiva diskriminerade fackföreningar

Rekursiv typ

Diskriminerade fackföreningar kan vara rekursiva, det vill säga att de kan hänvisa till sig själva i sin definition. Det främsta exemplet här är ett träd:

type Tree =
    | Branch of int * Tree list
    | Leaf of int

Som ett exempel, låt oss definiera följande träd:

    1
  2   5
3   4

Vi kan definiera detta träd med vår rekursiva diskriminerade förening enligt följande:

let leaf1 = Leaf 3
let leaf2 = Leaf 4
let leaf3 = Leaf 5

let branch1 = Branch (2, [leaf1; leaf2])
let tip = Branch (1, [branch1; leaf3])

Iterera över trädet är då bara en fråga om mönstermatchning:

let rec toList tree =
    match tree with
    | Leaf x -> [x]
    | Branch (x, xs) -> x :: (List.collect toList xs)

let treeAsList = toList tip // [1; 2; 3; 4; 5]

Ömsesidigt beroende rekursiva typer

Ett sätt att uppnå rekursion är att ha kapslade ömsesidigt beroende typer.

// BAD
type Arithmetic = {left: Expression; op:string; right: Expression}
// illegal because until this point, Expression is undefined
type Expression = 
| LiteralExpr of obj
| ArithmeticExpr of Arithmetic

Att definiera en posttyp direkt i en diskriminerad förening avskrivs:

// BAD
type Expression = 
| LiteralExpr of obj
| ArithmeticExpr of {left: Expression; op:string; right: Expression}
// illegal in recent F# versions

Du kan använda and nyckelordet för att kedja inbördes beroende definitioner:

// GOOD
type Arithmetic = {left: Expression; op:string; right: Expression}
and Expression = 
| LiteralExpr of obj
| ArithmeticExpr of Arithmetic