access-vba
Włącz / wyłącz klawisz Shift na DB Open
Szukaj…
Uwagi
Ten kod wyłączy możliwość przytrzymania klawisza Shift podczas otwierania bazy danych w celu pominięcia domyślnego otwierania formularza i umożliwienia użytkownikowi dostępu do okienka nawigacji i edytora VB. W bazach danych, w których nie chcesz, aby użytkownicy mieli dostęp do któregokolwiek z nich (wraz z wyłączeniem korzystania ze specjalnych kluczy w bieżących opcjach bazy danych), ten kod pomoże utrzymać bazę danych zablokowaną.
Zasadniczo poniższy kod jest umieszczony we własnym module, który można nazwać modułem basEnableDisableShift, ale jest to tylko sugestia i można go umieścić w dowolnym module, który już masz.
Aby wyłączyć klawisz Shift, na ekranie edytora VB wpisz „DisableShift” w oknie natychmiastowym i naciśnij Enter. Następnie otrzymasz wiadomość z informacją, że klawisz Shift został wyłączony.
Aby ponownie włączyć klawisz Shift, musisz ponownie powrócić do ekranu edytora VB, wpisać „EnableShift” w oknie natychmiastowym i nacisnąć Enter. Ponownie otrzymasz komunikat w oknie natychmiastowym informujący, że klawisz Shift został włączony.
UWAGA: Nie jest to niezawodny sposób włączania i wyłączania klawisza Shift, ale jeśli wdrażasz bazę danych dla użytkowników, którzy nie są biegli w MS Access i VBA, powinna być pomocna w zapobieganiu uzyskiwania dostępu do edytora VB i / lub okienko nawigacji w bazie danych.
Wyłącz kod funkcji zmiany biegów
Function DisableShift()
'This function disable the shift at startup. This action causes
'the Autoexec macro and Startup properties to always be executed.
On Error GoTo errDisableShift
Dim db As DAO.Database
Dim prop As DAO.Property
Const conPropNotFound = 3270
Set db = CurrentDb()
'This next line disables the shift key on startup.
db.Properties("AllowByPassKey") = False
'The function is successful.
Debug.Print "Disabled Shift Key - Successful"
Exit Function
errDisableShift:
'The first part of this error routine creates the "AllowByPassKey
'property if it does not exist.
If Err = conPropNotFound Then
Set prop = db.CreateProperty("AllowByPassKey", _
dbBoolean, False)
db.Properties.Append prop
Resume Next
Else
MsgBox "Function 'ap_DisableShift' did not complete successfully."
GoTo ExitHere
End If
ExitHere:
Set prop = Nothing
Set db = Nothing
Exit Function
End Function
Włącz kod funkcji zmiany biegów
Function EnableShift()
'This function enables the SHIFT key at startup. This action causes
'the Autoexec macro and the Startup properties to be bypassed
'if the user holds down the SHIFT key when the user opens the database.
On Error GoTo errEnableShift
Dim db As DAO.Database
Dim prop As DAO.Property
Const conPropNotFound = 3270
Set db = CurrentDb()
'This next line of code disables the SHIFT key on startup.
db.Properties("AllowByPassKey") = True
'function successful
Debug.Print "Enabled Shift Key - Successful"
GoTo ExitHere
errEnableShift:
'The first part of this error routine creates the "AllowByPassKey
'property if it does not exist.
If Err = conPropNotFound Then
Set prop = db.CreateProperty("AllowByPassKey", _
dbBoolean, True)
db.Properties.Append prop
Resume Next
Else
MsgBox "Function 'ap_DisableShift' did not complete successfully."
GoTo ExitHere
End If
ExitHere:
Set prop = Nothing
Set db = Nothing
Exit Function
End Function