access-vba
DB 열기시 Shift 키 사용 / 사용 안 함

.NET Framework C# Language excel-vba HTML MySQL Regular Expressions SQL Microsoft SQL Server Visual Basic .NET Language VBA
수색…


비고

이 코드는 사용자가 기본 양식 열기를 건너 뛰고 탐색 창 및 VB 편집기에 대한 사용자 액세스를 허용하도록 데이터베이스를 열 때 Shift 키를 누른 상태로 유지하는 기능을 해제합니다. DB에서는 사용자가 현재 데이터베이스 옵션에서 특수 키 사용을 해제하는 것과 함께 이들 중 하나에 액세스하지 못하게하려는 경우이 코드는 데이터베이스를 잠긴 상태로 유지하는 데 도움이됩니다.

일반적으로 아래 코드는 basEnableDisableShift 모듈이라는 자체 모듈에 배치되지만 이는 단지 제안 일 뿐이며 이미 가지고있는 모듈에 배치 할 수 있습니다.

Shift 키를 사용하지 않으려면 VB Editor 화면에서 직접 실행 창에 'DisableShift'를 입력하고 Enter 키를 누릅니다. 그런 다음 Shift 키가 비활성화되었음을 알리는 메시지가 나타납니다.

Shift 키를 다시 사용하려면 다시 한번 VB Editor 화면으로 돌아가서 직접 실행 창에 'EnableShift'를 입력하고 Enter 키를 누릅니다. Shift 키가 활성화되었음을 알리는 직접 실행 창에 메시지가 다시 나타납니다.

참고 : Shift 키를 사용하거나 사용하지 않도록 설정하는 것은 어리석지 않습니다. 그러나 MS Access 및 VBA에 익숙하지 않은 사용자에게 데이터베이스를 배포하는 경우에는 사용자가 VB Editor에 액세스하지 못하게하고 / 또는 탐색 창을 엽니 다.

시프트 기능 코드 사용 중지

Function DisableShift()
'This function disable the shift at startup. This action causes
'the Autoexec macro and Startup properties to always be executed.

On Error GoTo errDisableShift

    Dim db As DAO.Database
    Dim prop As DAO.Property
    Const conPropNotFound = 3270

    Set db = CurrentDb()

    'This next line disables the shift key on startup.
    db.Properties("AllowByPassKey") = False

    'The function is successful.
    Debug.Print "Disabled Shift Key - Successful"
    Exit Function

errDisableShift:
    'The first part of this error routine creates the "AllowByPassKey
    'property if it does not exist.
    If Err = conPropNotFound Then
        Set prop = db.CreateProperty("AllowByPassKey", _
        dbBoolean, False)
        db.Properties.Append prop
        Resume Next
        Else
            MsgBox "Function 'ap_DisableShift' did not complete successfully."
            GoTo ExitHere
    End If

ExitHere:
    Set prop = Nothing
    Set db = Nothing
    Exit Function

End Function

시프트 기능 코드 사용

Function EnableShift()
'This function enables the SHIFT key at startup. This action causes
'the Autoexec macro and the Startup properties to be bypassed
'if the user holds down the SHIFT key when the user opens the database.

On Error GoTo errEnableShift

    Dim db As DAO.Database
    Dim prop As DAO.Property
    Const conPropNotFound = 3270

    Set db = CurrentDb()

    'This next line of code disables the SHIFT key on startup.
    db.Properties("AllowByPassKey") = True

    'function successful
    Debug.Print "Enabled Shift Key - Successful"
    GoTo ExitHere

errEnableShift:
    'The first part of this error routine creates the "AllowByPassKey
    'property if it does not exist.
    If Err = conPropNotFound Then
        Set prop = db.CreateProperty("AllowByPassKey", _
        dbBoolean, True)
        db.Properties.Append prop
        Resume Next
        Else
            MsgBox "Function 'ap_DisableShift' did not complete successfully."
            GoTo ExitHere
    End If

ExitHere:
    Set prop = Nothing
    Set db = Nothing
    Exit Function

End Function


Modified text is an extract of the original Stack Overflow Documentation
아래 라이선스 CC BY-SA 3.0
와 제휴하지 않음 Stack Overflow