खोज…
डिफॉल्ट प्रोफ़ाइल।
क्यूमेक एक बिल्ड ऑटोमेशन टूल है, जिसे क्यूटी फ्रेमवर्क के साथ शिप किया जाता है। यह सीएमके या जीएनयू ऑटोटूल जैसे उपकरणों के समान काम करता है, लेकिन इसे विशेष रूप से क्यूटी के साथ उपयोग करने के लिए डिज़ाइन किया गया है। जैसे कि यह क्यूटी पारिस्थितिकी तंत्र के साथ अच्छी तरह से एकीकृत है, विशेष रूप से क्यूटी निर्माता आईडीई।
यदि आप Qt Creator शुरू करते हैं और File -> New File or Project -> Application -> Qt Widgets application चुनते हैं, तो Qt Creator आपके लिए "pro" फाइल के साथ एक प्रोजेक्ट कंकाल उत्पन्न करेगा। "प्रो" फ़ाइल को फ़ाइलों को उत्पन्न करने के लिए क्यूमेक द्वारा संसाधित किया जाता है, जो बदले में अंतर्निहित बिल्ड सिस्टम (उदाहरण के लिए जीएनयू मेक या एनएमके ) द्वारा संसाधित होते हैं।
यदि आपने अपने प्रोजेक्ट का नाम "myapp" रखा है, तो "myapp.pro" फाइल दिखाई देगी। यहां बताया गया है कि ऐसी डिफ़ॉल्ट फ़ाइल कैसी लगती है, टिप्पणियों के साथ, जो प्रत्येक qmake चर का वर्णन करती है, गयी।
# Tells build system that project uses Qt Core and Qt GUI modules.
QT += core gui
# Prior to Qt 5 widgets were part of Qt GUI module. In Qt 5 we need to add Qt Widgets module.
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
# Specifies name of the binary.
TARGET = myapp
# Denotes that project is an application.
TEMPLATE = app
# List of source files (note: Qt Creator will take care about this list, you don't need to update is manually).
SOURCES += main.cpp\
mainwindow.cpp
# List of header files (note: Qt Creator will take care about this list).
HEADERS += mainwindow.h
# List of "ui" files for a tool called Qt Designer, which is embedded into Qt Creator in newer versions of IDE (note: Qt Creator will take care about this list).
FORMS += mainwindow.ui
एक निर्माण में स्रोत निर्देशिका संरचना को संरक्षित करना (अविवादित "object_parallel_to_source" विकल्प)।
यदि आप विभिन्न उपनिर्देशिकाओं में स्रोत फ़ाइलों को रखकर अपनी परियोजना को व्यवस्थित करना पसंद करते हैं, तो आपको पता होना चाहिए कि एक बिल्ड के दौरान qmake इस निर्देशिका संरचना को संरक्षित नहीं करेगा और यह सभी ".o" फ़ाइलों को एक ही निर्माण निर्देशिका में रखेगा। यह एक समस्या हो सकती है यदि आपके पास निम्नलिखित जैसे विभिन्न निर्देशिकाओं में फ़ाइल नाम परस्पर विरोधी थे।
src/file1.cpp
src/plugin/file1.cpp
अब qmake बिल्ड डायरेक्टरी में दो "file1.o" फाइल्स बनाने का निर्णय लेगा, जिससे उनमें से एक को दूसरे द्वारा अधिलेखित कर दिया जाएगा। बल्ब फेल हो जाएगा। इसे रोकने के लिए आप CONFIG += object_parallel_to_source कॉन्फ़िगरेशन विकल्प को अपनी "समर्थक" फ़ाइल में जोड़ सकते हैं। यह आपके स्रोत निर्देशिका संरचना को बनाए रखने वाली फ़ाइलों को बनाने के लिए qmake को बताएगा। इस तरह आपकी निर्माण निर्देशिका स्रोत निर्देशिका संरचना को दर्शाएगी और ऑब्जेक्ट फाइलें अलग-अलग उपनिर्देशिकाओं में बनाई जाएंगी।
src/file1.o
src/plugin/file1.o
पूरा उदाहरण।
QT += core
TARGET = myapp
TEMPLATE = app
CONFIG += object_parallel_to_source
SOURCES += src/file1.cpp \
src/plugin/file1.cpp
HEADERS += src/plugin/file1.h
ध्यान दें कि object_parallel_to_source CONFIG विकल्प आधिकारिक रूप से प्रलेखित नहीं है ।
सरल उदाहरण (लिनक्स)
Window.h
#include <QWidget>
class Window : public QWidget
{
Q_OBJECT
public:
Window(QWidget *parent = Q_NULLPTR) : QWidget(parent) {}
}
main.cpp
#include <QApplication>
#include "Window.h"
int main()
{
QApplication app;
Window window;
window.show();
return app.exec();
}
example.pro
# The QT variable controls what modules are included in compilation.
# Note that the 'core' and 'gui' modules are included by default.
# For widget-based GUI applications, the 'widgets' module needs to be added.
QT += widgets
HEADERS = Window.h # Everything added to the HEADER variable will be checked
# to see if moc needs to run on it, and it will be run if
# so.
SOURCES = main.cpp # Everything added to the SOURCES variable will be compiled
# and (in the simple example) added to the resulting
# executable.
कमांड लाइन
# Assuming you are in a folder that contains the above files.
> qmake # You can also add the example.pro file if needed
> make # qmake creates a Makefile, this runs make on it.
> ./example # The name of the executable defaults to the .pro file name.
SUBDIRS उदाहरण
क्यूमेक की SUBDIRS क्षमता का उपयोग पुस्तकालयों के एक सेट को संकलित करने के लिए किया जा सकता है, जिनमें से प्रत्येक दूसरे पर निर्भर करता है। SUBDIRS क्षमता के साथ विविधता दिखाने के लिए नीचे दिया गया उदाहरण थोड़ा जटिल है।
निर्देशिका संरचना
निम्नलिखित कुछ फाइलें संक्षिप्तता के हित में छोड़ी जाएंगी। उन्हें गैर-उपदिशा उदाहरण के रूप में प्रारूप माना जा सकता है।
project_dir/
-project.pro
-common.pri
-build.pro
-main.cpp
-logic/
----logic.pro
----some logic files
-gui/
----gui.pro
----gui files
project.pro
यह मुख्य फ़ाइल है जो उदाहरण को सक्षम करती है। यह वह फ़ाइल भी है जिसे कमांड लाइन पर qmake के साथ बुलाया जाएगा (नीचे देखें)।
TEMPLATE = subdirs # This changes to the subdirs function. You can't combine
# compiling code and the subdirs function in the same .pro
# file.
# By default, you assign a directory to the SUBDIRS variable, and qmake looks
# inside that directory for a <dirname>.pro file.
SUBDIRS = logic
# You can append as many items as desired. You can also specify the .pro file
# directly if need be.
SUBDIRS += gui/gui.pro
# You can also create a target that isn't a subdirectory, or that refers to a
# different file(*).
SUBDIRS += build
build.file = build.pro # This specifies the .pro file to use
# You can also use this to specify dependencies. In this case, we don't want
# the build target to run until after the logic and gui targets are complete.
build.depends = logic gui/gui.pro
(*) एक उपखंड लक्ष्य के लिए अन्य विकल्पों के लिए संदर्भ प्रलेखन देखें।
common.pri
#Includes common configuration for all subdirectory .pro files.
INCLUDEPATH += . ..
WARNINGS += -Wall
TEMPLATE = lib
# The following keeps the generated files at least somewhat separate
# from the source files.
UI_DIR = uics
MOC_DIR = mocs
OBJECTS_DIR = objs
तर्क / logic.pro
# Check if the config file exists
! include( ../common.pri ) {
error( "Couldn't find the common.pri file!" )
}
HEADERS += logic.h
SOURCES += logic.cpp
# By default, TARGET is the same as the directory, so it will make
# liblogic.so (in linux). Uncomment to override.
# TARGET = target
जीयूआई / gui.pro
! include( ../common.pri ) {
error( "Couldn't find the common.pri file!" )
}
FORMS += gui.ui
HEADERS += gui.h
SOURCES += gui.cpp
# By default, TARGET is the same as the directory, so it will make
# libgui.so (in linux). Uncomment to override.
# TARGET = target
build.pro
TEMPLATE = app
SOURCES += main.cpp
LIBS += -Llogic -Lgui -llogic -lgui
# This renames the resulting executable
TARGET = project
कमांड लाइन
# Assumes you are in the project_dir directory
> qmake project.pro # specific the .pro file since there are multiple here.
> make -n2 # This makes logic and gui concurrently, then the build Makefile.
> ./project # Run the resulting executable.
पुस्तकालय का उदाहरण
एक पुस्तकालय बनाने के लिए एक सरल उदाहरण (निष्पादन के बजाय, जो डिफ़ॉल्ट है)। TEMPLATE चर आपके द्वारा TEMPLATE जा रही परियोजना के प्रकार को निर्दिष्ट करता है। lib विकल्प मेकफाइल को लाइब्रेरी बनाने की अनुमति देता है।
library.pro
HEADERS += library.h
SOURCES += library.cpp
TEMPLATE = lib
# By default, qmake will make a shared library. Uncomment to make the library
# static.
# CONFIG += staticlib
# By default, TARGET is the same as the directory, so it will make
# liblibrary.so or liblibrary.a (in linux). Uncomment to override.
# TARGET = target
जब आप एक पुस्तकालय का निर्माण कर रहे हैं, तो आप CONFIG विकल्प dll (डिफ़ॉल्ट), staticlib या plugin जोड़ सकते हैं।
मौजूदा कोड से एक परियोजना फ़ाइल बनाना
आप मौजूदा स्रोत फ़ाइलों के साथ एक निर्देशिका है, तो आप उपयोग कर सकते हैं qmake साथ -project एक परियोजना फ़ाइल बनाने के लिए -option।
मान लेते हैं, फ़ोल्डर MyProgram में निम्नलिखित फाइलें हैं:
- main.cpp
- foo.h
- foo.cpp
- bar.h
- bar.cpp
- subdir / foobar.h
- subdir / foobar.cpp
फिर कॉल करके
qmake -project
एक फ़ाइल MyProgram.pro निम्नलिखित सामग्री के साथ बनाई गई है:
######################################################################
# Automatically generated by qmake (3.0) Mi. Sep. 7 23:36:56 2016
######################################################################
TEMPLATE = app
TARGET = MyProgram
INCLUDEPATH += .
# Input
HEADERS += bar.h foo.h subdir/foobar.h
SOURCES += bar.cpp foo.cpp main.cpp subdir/foobar.cpp
फिर कोड को इस सरल उदाहरण में वर्णित किया जा सकता है।