progress-4gl
अस्थायी-टेबल

परिचय

एक साधारण टेम्प-टेबल को परिभाषित करना

यह TEMP-TABLE की परिभाषा है, जिसका नाम ttTempTable है, जिसमें तीन फ़ील्ड हैं। NO-UNDO इंगित करता है कि किसी पूर्ववत संचालन की आवश्यकता नहीं है (यह आमतौर पर आप तब तक करना चाहते हैं जब तक कि आपको वास्तव में विपरीत की आवश्यकता न हो)।

DEFINE TEMP-TABLE ttTempTable NO-UNDO
    FIELD field1 AS INTEGER
    FIELD field2 AS CHARACTER
    FIELD field3 AS LOGICAL.

एक सूचकांक के साथ एक अस्थायी तालिका

यदि आप उनके खिलाफ क्वेरीज़ चलाने की योजना बनाते हैं, तो टैंप-टेबल को सूचकांकों के साथ बनाया जा सकता है (और चाहिए)।

इस तालिका में एक सूचकांक (इंडेक्स 1) है जिसमें एक फ़ील्ड (फ़ील्ड 1) है। यह सूचकांक प्राथमिक और अद्वितीय है (जिसका अर्थ है कि दो रिकॉर्ड फ़ील्ड 1 की समान सामग्री नहीं हो सकते हैं)।

DEFINE TEMP-TABLE ttTempTable NO-UNDO
    FIELD field1 AS INTEGER
    FIELD field2 AS CHARACTER
    FIELD field3 AS LOGICAL
    INDEX index1 IS PRIMARY UNIQUE field1 .

अधिक सूचकांक - सूचकांक ...

आप प्रत्येक अस्थायी-तालिका के लिए कई सूचकांकों को परिभाषित कर सकते हैं। यदि आपको उनकी आवश्यकता है - उन्हें परिभाषित करें। मूल रूप से आपकी क्वेरी और / या क्रम क्रम से मेल खाने वाला एक सूचकांक प्रदर्शन में मदद करेगा!

DEFINE TEMP-TABLE ttWithIndex NO-UNDO
    FIELD field1 AS INTEGER
    FIELD field2 AS CHARACTER
    FIELD field3 AS LOGICAL
    INDEX field1 field1.

DEFINE TEMP-TABLE ttWithoutIndex NO-UNDO
    FIELD field1 AS INTEGER
    FIELD field2 AS CHARACTER
    FIELD field3 AS LOGICAL.

DEFINE VARIABLE i              AS INTEGER     NO-UNDO.
DEFINE VARIABLE iWithCreate    AS INTEGER     NO-UNDO.
DEFINE VARIABLE iWithFind      AS INTEGER     NO-UNDO.
DEFINE VARIABLE iWithoutCreate AS INTEGER     NO-UNDO.
DEFINE VARIABLE iWithoutFind   AS INTEGER     NO-UNDO.

ETIME(TRUE).
DO i = 1 TO 1000:
    CREATE ttWithIndex.
    ttWithIndex.field1 = i.
END.
iWithCreate = ETIME.

ETIME(TRUE).
DO i = 1 TO 1000:
    CREATE ttWithoutIndex.
    ttWithoutIndex.field1 = i.
END.
iWithoutCreate = ETIME.

RELEASE ttWithIndex.
RELEASE ttWithoutIndex.

ETIME(TRUE).
DO i = 1 TO 1000:
    FIND FIRST ttWithIndex WHERE ttWithIndex.field1 = i NO-ERROR.
END.
iWithFind = ETIME.

ETIME(TRUE).
DO i = 1 TO 1000:
    FIND FIRST ttWithoutIndex WHERE ttWithoutIndex.field1 = i NO-ERROR.
END.
iWithoutFind = ETIME.

MESSAGE 
    "With index took" iWithFind "ms to find and" iWithCreate "ms to create" SKIP 
    "Without index took" iWithoutFind "ms to find and" iWithoutCreate "ms to create"
    VIEW-AS ALERT-BOX.

इंडेक्स के साथ खोज करना इंडेक्स की तुलना में लगभग 70 गुना तेज था! यह सिर्फ एक रन है, इसलिए वैज्ञानिक प्रमाण नहीं है लेकिन आपका इंडेक्स सेटअप प्रभावी होगा।

इनपुट और आउटपुट टेम्प-टेबल

कार्यक्रमों, प्रक्रियाओं और कार्यों के अंदर और बाहर टेम्‍प-टेबल पास करना बहुत सरल है।

यह आसान हो सकता है यदि आप बड़ी संख्या में डेटा संसाधित करने की प्रक्रिया चाहते हैं, तो आप आसानी से स्ट्रिंग या समान स्टोर कर सकते हैं। आप टेम्प-टेबल को INPUT , OUTPUT और INPUT-OUTPUT डेटा के रूप में पास कर सकते हैं।

एक टेम्‍प-टेबल इनपुट करना और दूसरा आउटपुट देना:

DEFINE TEMP-TABLE ttRequest NO-UNDO
    FIELD fieldA AS CHARACTER
    FIELD fieldB AS CHARACTER.

/* Define a temp-table with the same fields and indices */
DEFINE TEMP-TABLE ttResponse NO-UNDO LIKE ttRequest.

/* A procedure that simply swap the values of fieldA and fieldB */
PROCEDURE swapFields:
    DEFINE INPUT  PARAMETER TABLE FOR ttRequest.
    DEFINE OUTPUT PARAMETER TABLE FOR ttResponse.

    FOR EACH ttRequest:
        CREATE ttResponse.
        ASSIGN 
            ttResponse.fieldA = ttRequest.fieldB
            ttResponse.fieldB = ttRequest.fieldA.
    END.
END PROCEDURE.

CREATE ttRequest.
ASSIGN ttRequest.fieldA = "A"
       ttRequest.fieldB = "B".

CREATE ttRequest.
ASSIGN ttRequest.fieldA = "B"
       ttRequest.fieldB = "C".

CREATE ttRequest.
ASSIGN ttRequest.fieldA = "C"
       ttRequest.fieldB = "D".

/* Call the procedure */
RUN swapFields ( INPUT  TABLE ttRequest
               , OUTPUT TABLE ttResponse).

FOR EACH ttResponse:
    DISPLAY ttResponse.
END.

परिणाम:

fieldA--------fieldB--------

B             A
C             B
D             C

एक अस्थायी तालिका इनपुट:

DEFINE TEMP-TABLE ttCalculate NO-UNDO
    FIELD num1     AS INTEGER
    FIELD num2     AS INTEGER
    FIELD response AS DECIMAL.

PROCEDURE pythagoras:
    DEFINE INPUT-OUTPUT PARAMETER TABLE FOR ttCalculate.

    FOR EACH ttCalculate:
        ttCalculate.response = SQRT( EXP(num1, 2) + EXP(num2, 2)).
    END.

END PROCEDURE.

CREATE ttCalculate.
ASSIGN ttCalculate.num1 = 3
       ttCalculate.num2 = 4.

CREATE ttCalculate.
ASSIGN ttCalculate.num1 = 6
       ttCalculate.num2 = 8.

CREATE ttCalculate.
ASSIGN ttCalculate.num1 = 12
       ttCalculate.num2 = 16.

/* Call the procedure */
RUN pythagoras ( INPUT-OUTPUT  TABLE ttCalculate ).

FOR EACH ttCalculate:
    DISPLAY ttCalculate.
END.

परिणाम:

----------num1-- ----------num2-- -------response-

         3                4             5.00
         6                8            10.00
        12               16            20.00

कार्यों के लिए पासिंग

DEFINE TEMP-TABLE ttNumbers NO-UNDO
    FIELD num1     AS INTEGER
    FIELD num2     AS INTEGER
    INDEX index1 num1 num2.

DEFINE VARIABLE iNum AS INTEGER     NO-UNDO.

/* Forward declare the function */
FUNCTION hasAPair RETURNS LOGICAL (INPUT TABLE ttNumbers) FORWARD.

DO iNum = 1 TO 100:
    CREATE ttNumbers.
    ASSIGN ttNumbers.num1 = RANDOM(1,100)
           ttNumbers.num2 = RANDOM(1,100).
END.

MESSAGE hasAPair(INPUT TABLE ttNumbers) VIEW-AS ALERT-BOX.


/* Function to check if two records has the same value in num1 and num2 */
FUNCTION hasAPair RETURNS LOGICAL (INPUT TABLE ttNumbers):

    FIND FIRST ttNumbers WHERE ttNumbers.num1 = ttNumbers.num2 NO-ERROR.
    IF AVAILABLE ttNumbers THEN
        RETURN TRUE.
    ELSE 
        RETURN FALSE.

END FUNCTION.

प्रोग्राम फ़ाइलों को पास करना

आप दूसरे और .p-प्रोग्रामों से उसी तरह से टेम्प-टेबल पास करते हैं, जिस तरह से आप उन्हें अन्य प्रक्रियाओं में पास करते हैं। अंतर केवल इतना है कि कॉलिंग और कॉलिंग प्रोग्राम दोनों में एक ही टेम्प-टेबल घोषणा होनी चाहिए। एक आसान तरीका यह है कि टेम्प-टेबल प्रोग्राम को तीसरी फ़ाइल में स्टोर किया जाए - एक ऐसा प्रोग्राम जो दोनों प्रोग्राम्स में उपयोग किया जाता है।

टेम्प-टेबल परिभाषा वाली फाइल शामिल करें: / * ttFile.i * / DEFINE TEMP-TABLE TtFile NO-UNDO FIELD fName as CHARACTER FORMAT "x (20)" FIELD isADirectory AS LogICAL।

एक अस्थायी तालिका में सभी फ़ाइलों की जाँच कार्यक्रम। क्या वे निर्देशिका हैं?

/* checkFiles.p */
{ttFile.i}

DEFINE INPUT-OUTPUT PARAMETER TABLE FOR ttFile.

FOR EACH ttFile:
    FILE-INFO:FILE-NAME = ttFile.fName.

    IF FILE-INFO:FILE-TYPE BEGINS "D" THEN
        ttFile.isADirectory = TRUE.
END.

मुख्य कार्यक्रम:

{ttFile.i}

CREATE ttFile.
ASSIGN ttFile.fname = "c:\temp\".

CREATE ttFile.
ASSIGN ttFile.fname = "c:\Windows\".

CREATE ttFile.
ASSIGN ttFile.fname = "c:\Windoose\".

RUN checkFiles.p(INPUT-OUTPUT TABLE ttFile).

FOR EACH ttFile:
    DISPLAY ttFile.
END.

परिणाम:

fName----------------- isADirector

c:\temp\               yes
c:\Windows\            yes
c:\Windoose\           no