AutoHotkey
Scripts Hotkey

Syntaxe

• raccourcis clavier::
• ::abréviation::
• Revenir

Paramètres

Raccourci clavier

Pour créer un raccourci clavier qui envoie la séquence de touches 'Hello World' en appuyant sur Ctrl + J dans la fenêtre active (peut être démontré dans le Bloc-notes, par exemple)

^j::
    Send, Hello World
Return

Hotstring

Pour créer un script pour remplacer une phrase, utilisez la syntaxe ::abbreviation:: hotstring. Cela remplacera btw par by the way chaque fois que vous entrez btw puis la touche espace.

::btw::by the way

Si vous voulez créer un script de connexion pour vous connecter plus rapidement, vous pouvez créer un script comme celui-ci (le fichier n'est pas chiffré, donc toute information de votre script sera visible par toute personne ayant accès au fichier).

::lmi::user{tab}password{enter}

Touches multiples

Pour exécuter un script lorsque plusieurs touches sont enfoncées, utilisez les touches & entre les touches.

Numpad0 & Numpad1::
    MsgBox You pressed 0 and 1
return

Raccourcis contextuels et Hotstrings

Pour créer un raccourci clavier ou une chaîne de raccourci qui ne se déclenche que lorsque certaines fenêtres sont actives ou existantes, vous pouvez placer une ou plusieurs des directives suivantes avant la définition du raccourci clavier:

#IfWinActive [, WinTitle, WinText]
#IfWinExist [, WinTitle, WinText]
#IfWinNotActive [, WinTitle, WinText]
#IfWinNotExist [, WinTitle, WinText]

Exemple: Vous voulez stackoverflow.com à envoyer chaque fois que vous tapez so (et un espace après que) dans Google Chrome, mais ignorer la combinaison de chaîne dans une autre fenêtre.

#IfWinActive, ahk_class Chrome_WidgetWin_1
::so::stackoverflow.com

En utilisant #If [, Expression ] , vous ne pouvez déclencher un raccourci que lorsqu'une expression arbitraire est vraie, par exemple:

#If A_Hour < 9
F1::
    MsgBox, It is too early to ask for help!
return

Touches de remappage

L'exemple suivant remappe la clé Z sur Y et inversement, par exemple si vous souhaitez utiliser la disposition QWERTY sur un clavier QWERTZ.

z::y
y::z

Touches d'activation commutables

Le script suivant entre des chaînes prédéfinies sur les touches de raccourci si le verrouillage de défilement est actif. Cela peut être utile si vous collez souvent un certain nombre de chaînes répétées. Raccourcis inclus pour l'actualisation du script (par exemple, si vous devez modifier des chaînes pouvant être collées).

; refresh script hotkey
Numpad9:: 
    GetKeyState, state, ScrollLock, T
    if ( state = "D" )
        Reload
Return

Numpad1:: 
    GetKeyState, state, ScrollLock, T
    if ( state = "D" )
        Send,         Hello 
Return

Numpad2:: 
    GetKeyState, state, ScrollLock, T
    if ( state = "D" )
        Send,         World
Return
;...