ms-access
Параметрированные запросы

Вступление

Уязвимый подход: объединенная строка SQL со ссылками на форму

Это типичный подход для начинающих разработчиков, создающих SQL-запросы. Они уязвимы для атак типа Bobby Tables типа SQL Injection.

Dim strSQL As String

strSQL = "INSERT INTO Employees chrFirstName, chrLastName, chrPhone " _
         & "VALUES ('" & Me!txtFirstName & "','" & Me!txtLastName & "','" & Me!txtPhone & "');"

CurrentDb.Execute strSQL

QueryDef Parameterized Query Approach

Такой подход не позволит пользователю встраивать второй оператор SQL в их ввод для выполнения.

Dim strSQL As String
Dim db As DAO.Database
Dim qdf As DAO.QueryDef

strSQL = "PARAMETERS [FirstName] Text(255), [LastName] Text(255), [Phone] Text(255); " _
         & "INSERT INTO Employees (chrFirstName, chrLastName, chrPhone) " _
         & "VALUES ([FirstName], [LastName], [Phone]);"

Set db = CurrentDb

Set qdf = db.CreateQueryDef("", strSQL)
qdf.Parameters("FirstName") = Me!txtFirstName
qdf.Parameters("LastName") = Me!txtLastName
qdf.Parameters("Phone") = Me!txtPhone
qdf.Execute

Me!txtFirstName = vbNullString
Me!txtLastName = vbNullString
Me!txtPhone = vbNullString

qdf.Close
db.Close
Set qdf = Nothing
Set db = Nothing

Допустимые типы параметров:

• DATETIME : для дат (параметр ожидает VBA Date )
• SHORT , LONG : для целых чисел ( SHORT ожидает Integer, LONG ожидает Long)
• SINGLE , DOUBLE : для плавающей запятой (ожидайте Single и Double соответственно)
• VARCHAR или TEXT : для строк
• MEMO или LONGTEXT : для строк длиной более 255 символов