gradle
Wtyczki Gradle

Prosta wtyczka stopniowa z `buildSrc`

Prosty przykład, jak utworzyć niestandardową wtyczkę i DSL dla swojego projektu gradle.
W tym przykładzie wykorzystano jeden z trzech możliwych sposobów tworzenia wtyczek.
Trzy sposoby to:

• inline
• buildSrc
• samodzielne wtyczki

Ten przykład pokazuje tworzenie wtyczki z folderu buildSrc .

Ten przykład utworzy pięć plików

// project's build.gradle
build.gradle
// build.gradle to build the `buildSrc` module
buildSrc/build.gradle
// file name will be the plugin name used in the `apply plugin: $name`
// where name would be `sample` in this example
buildSrc/src/main/resources/META-INF/gradle-plugins/sample.properties
// our DSL (Domain Specific Language) model
buildSrc/src/main/groovy/so/docs/gradle/plugin/SampleModel.groovy
// our actual plugin that will read the values from the DSL
buildSrc/src/main/groovy/so/docs/gradle/plugin/SamplePlugin.groovy

build.gradle:

group 'so.docs.gradle'
version '1.0-SNAPSHOT'

apply plugin: 'groovy'
// apply our plugin... calls SamplePlugin#apply(Project)
apply plugin: 'sample'

repositories {
    mavenCentral()
}

dependencies {
    compile localGroovy()
}

// caller populates the extension model applied above
sample {
    product = 'abc'
    customer = 'zyx'
}

// dummy task to limit console output for example
task doNothing <<{}

buildSrc / build.gradle

apply plugin: 'groovy'

repositories {
    mavenCentral()
}

dependencies {
    compile localGroovy()
}

buildSrc / src / main / groovy / so / docs / gradle / plugin / SamplePlugin.groovy:

package so.docs.gradle.plugin

import org.gradle.api.Plugin
import org.gradle.api.Project

class SamplePlugin implements Plugin<Project> {
    @Override
    void apply(Project target) {
        // create our extension on the project for our model
        target.extensions.create('sample', SampleModel)
        // once the script has been evaluated the values are available
        target.afterEvaluate {
            // here we can do whatever we need to with our values
            println "populated model: $target.extensions.sample"
        }
    }
}

buildSrc / src / main / groovy / so / docs / gradle / plugin / SampleModel.groovy:

package so.docs.gradle.plugin

// define our DSL model
class SampleModel {
    public String product;
    public String customer;

    @Override
    public String toString() {
        final StringBuilder sb = new StringBuilder("SampleModel{");
        sb.append("product='").append(product).append('\'');
        sb.append(", customer='").append(customer).append('\'');
        sb.append('}');
        return sb.toString();
    }
}

buildSrc / src / main / resources / META-INF / gradle-plugins / sample.properties

implementation-class=so.docs.gradle.plugin.SamplePlugin

Korzystając z tej konfiguracji możemy zobaczyć wartości dostarczone przez dzwoniącego w twoim bloku DSL

 $ ./gradlew -q doNothing
SampleModel{product='abc', customer='zyx'}

Jak napisać samodzielną wtyczkę

Aby utworzyć niestandardową samodzielną wtyczkę Gradle za pomocą Java (możesz także użyć Groovy), musisz utworzyć taką strukturę:

plugin
|-- build.gradle
|-- settings.gradle
|-- src
    |-- main
    |   |-- java
    |   |-- resources
    |       |-- META-INF
    |           |-- gradle-plugins
    |-- test

Ustaw konfigurację stopni

W pliku build.gradle definiujesz swój projekt.

apply plugin: 'java'
apply plugin: 'maven'

dependencies {
    compile gradleApi()
} 

Wtyczka java zostanie użyta do napisania kodu Java.
gradleApi() da nam wszystkie metody i właściwości potrzebne do utworzenia wtyczki Gradle.

W pliku settings.gradle :

rootProject.name = 'myplugin' 

Określi identyfikator artefaktu w Maven.
Jeśli plik settings.gradle nie znajduje się w katalogu wtyczki, domyślną wartością będzie nazwa katalogu.

Utwórz wtyczkę

Zdefiniuj klasę w pliku src/main/java/org/sample/MyPlugin.java implementującym interfejs Plugin .

import org.gradle.api.Plugin;
import org.gradle.api.Project;

public class MyPlugin implements Plugin<Project> {

    @Override
    public void apply(Project project) {
         project.getTasks().create("myTask", MyTask.class);
    }

} 

Zdefiniuj zadanie rozszerzające klasę DefaultTask :

import org.gradle.api.DefaultTask;
import org.gradle.api.tasks.TaskAction;

public class MyTask extends DefaultTask {

    @TaskAction
    public void myTask() {
        System.out.println("Hello World");
    }
}

Deklaracja klasy wtyczek

W folderze META-INF/gradle-plugins musisz utworzyć plik właściwości definiujący właściwość implementation-class która identyfikuje klasę implementacji wtyczki.

W META-INF/gradle-plugins/testplugin.properties

implementation-class=org.sample.MyPlugin.java

Zauważ, że nazwa pliku właściwości odpowiada identyfikatorowi wtyczki .

Jak go zbudować i opublikować

Zmień plik build.gradle , dodając informacje, aby załadować wtyczkę do repozytorium maven:

apply plugin: 'java'
apply plugin: 'maven'

dependencies {
    compile gradleApi()
}

repositories {
    jcenter()
}


group = 'org.sample'
version = '1.0'

uploadArchives {
    repositories {
        mavenDeployer {
        repository(url: mavenLocal().url)
        }
    }
} 

Możesz zbudować i opublikować wtyczkę Gradle w repozytorium Maven zdefiniowanym w pliku plugin/build.gradle za pomocą następującego polecenia.

$ ./gradlew clean uploadArchives 

Jak tego użyć

Aby użyć wtyczki dodaj w build.gradle swojego projektu:

buildscript {
     repositories {
         mavenLocal()
     }
 dependencies {
    classpath group: 'org.sample',    // Defined in the build.gradle of the plugin
              name: 'myplugin',       // Defined by the rootProject.name 
              version: '1.0'
    }
 }

apply plugin: 'testplugin'            // Defined by the properties filename

Następnie możesz wywołać zadanie za pomocą:

 $ ./gradlew myTask