Elixir Language
패턴 매칭

패턴 일치 기능

#You can use pattern matching to run different 
#functions based on which parameters you pass

#This example uses pattern matching to start, 
#run, and end a recursive function

defmodule Counter do
    def count_to do
        count_to(100, 0) #No argument, init with 100
    end

    def count_to(counter) do
        count_to(counter, 0) #Initialize the recursive function
    end

    def count_to(counter, value) when value == counter do
        #This guard clause allows me to check my arguments against
        #expressions. This ends the recursion when the value matches
        #the number I am counting to.
        :ok
    end

    def count_to(counter, value) do
        #Actually do the counting
        IO.puts value
        count_to(counter, value + 1)
    end
end

지도의 패턴 일치

%{username: username} = %{username: "John Doe", id: 1}
# username == "John Doe"

%{username: username, id: 2} = %{username: "John Doe", id: 1}
** (MatchError) no match of right hand side value: %{id: 1, username: "John Doe"}

목록의 패턴 일치

목록과 같은 엘릭서 데이터 구조에서 패턴 매치를 할 수도 있습니다.

기울기

목록에 일치하는 것은 아주 간단합니다.

[head | tail] = [1,2,3,4,5]
# head == 1
# tail == [2,3,4,5]

이 작업은 목록의 첫 번째 (또는 그 이상) 요소를 | (파이프)의 나머지 변수와 | .

목록의 특정 값을 일치시킬 수도 있습니다.

[1,2 | tail] = [1,2,3,4,5]
# tail = [3,4,5]

[4 | tail] = [1,2,3,4,5]
** (MatchError) no match of right hand side value: [1, 2, 3, 4, 5]

| 왼쪽에 여러 개의 연속 값을 바인드합니다. 또한 허용됩니다.

[a, b | tail] = [1,2,3,4,5]
# a == 1
# b == 2
# tail = [3,4,5]

더 복잡한 - 우리는 특정 값을 매치 할 수 있고 그것을 변수와 비교할 수 있습니다 :

iex(11)> [a = 1 | tail] = [1,2,3,4,5]
# a == 1

패턴 일치를 사용하여 목록 합계 가져 오기

defmodule Math do
  # We start of by passing the sum/1 function a list of numbers.
  def sum(numbers) do
    do_sum(numbers, 0)
  end

  # Recurse over the list when it contains at least one element.
  # We break the list up into two parts:
  #   head: the first element of the list
  #   tail: a list of all elements except the head
  # Every time this function is executed it makes the list of numbers
  # one element smaller until it is empty.
  defp do_sum([head|tail], acc) do
    do_sum(tail, head + acc)
  end

 # When we have reached the end of the list, return the accumulated sum
  defp do_sum([], acc), do: acc
end

익명 함수

f = fn
  {:a, :b} -> IO.puts "Tuple {:a, :b}"
  [] -> IO.puts "Empty list"
end

f.({:a, :b}) # Tuple {:a, :b}
f.([])       # Empty list

튜플

{ a, b, c } = { "Hello", "World", "!" }    

IO.puts a # Hello
IO.puts b # World
IO.puts c # !

# Tuples of different size won't match:

{ a, b, c } = { "Hello", "World" } # (MatchError) no match of right hand side value: { "Hello", "World" }

파일 읽기

패턴 일치는 터플을 반환하는 파일 읽기와 같은 작업에 유용합니다.

sample.txt 파일에 다음을 포함하는 This is a sample text .

{ :ok, file } = File.read("sample.txt")
# => {:ok, "This is a sample text"}

file
# => "This is a sample text"

그렇지 않으면, 파일이 존재하지 않는 경우 :

{ :ok, file } = File.read("sample.txt")
# => ** (MatchError) no match of right hand side value: {:error, :enoent}

{ :error, msg } = File.read("sample.txt")
# => {:error, :enoent}

익명 함수와 일치하는 패턴

fizzbuzz = fn
  (0, 0, _) -> "FizzBuzz"
  (0, _, _) -> "Fizz"
  (_, 0, _) -> "Buzz"
  (_, _, x) -> x
end

my_function = fn(n) ->
  fizzbuzz.(rem(n, 3), rem(n, 5), n)
end