common-lisp
CLOS - Common Lisp Object System

부모없이 기본 CLOS 클래스 만들기

CLOS 클래스는 다음에 의해 설명됩니다.

• 이름
• 수퍼 클래스 목록
• 슬롯 목록
• 문서와 같은 추가 옵션

각 슬롯에는 다음이 있습니다.

• 이름
• 초기화 양식 (선택 사항)
• 초기화 인수 (옵션)
• 유형 (선택 사항)
• 문서화 문자열 (선택 사항)
• 접근 자, 판독기 및 / 또는 기록기 기능 (선택 사항)
• 할당과 같은 추가 옵션

예:

(defclass person ()
  ((name
    :initform      "Erika Mustermann" 
    :initarg       :name 
    :type          string
    :documentation "the name of a person"
    :accessor      person-name)
   (age
    :initform      25
    :initarg       :age
    :type          number
    :documentation "the age of a person"
    :accessor      person-age))
  (:documentation "a CLOS class for persons with name and age"))

기본 인쇄 방법 :

(defmethod print-object ((p person) stream)
  "The default print-object method for a person"
  (print-unreadable-object (p stream :type t :identity t)
    (with-slots (name age) p
      (format stream "Name: ~a, age: ~a" name age))))

인스턴스 생성 :

CL-USER > (make-instance 'person)
#<PERSON Name: Erika Mustermann, age: 25 4020169AB3>

CL-USER > (make-instance 'person :name "Max Mustermann" :age 24)
#<PERSON Name: Max Mustermann, age: 24 4020169FEB>

믹스 인 및 인터페이스

Common Lisp에는 일부 언어 (예 : Java)가 제공하는 인터페이스가 없으므로 Common Lisp가 다중 상속 및 일반 함수를 지원한다는 점에서 해당 유형의 인터페이스가 필요하지 않습니다. 그러나 mixin 클래스를 사용하면 동일한 유형의 패턴을 쉽게 구현할 수 있습니다. 이 예제는 몇 가지 해당 제네릭 함수가있는 컬렉션 인터페이스의 사양을 보여줍니다.

;; Specification of the COLLECTION "interface"

(defclass collection () ()
  (:documentation "A collection mixin."))

(defgeneric collection-elements (collection)
  (:documentation "Returns a list of the elements in the collection."))

(defgeneric collection-add (collection element)
  (:documentation "Adds an element to the collection."))

(defgeneric collection-remove (collection element)
  (:documentation "Removes the element from the collection, if it is present."))

(defgeneric collection-empty-p (collection)
  (:documentation "Returns whether the collection is empty or not."))

(defmethod collection-empty-p ((c collection))
  "A 'default' implementation of COLLECTION-EMPTY-P that tests
whether the list returned by COLLECTION-ELEMENTS is the empty
list."
  (endp (collection-elements c)))

인터페이스의 구현은 수퍼 클래스 중 하나 인 mixin과 적절한 제네릭 함수의 정의를 가진 클래스 일뿐입니다. (이 시점에서 mixin 클래스는 실제로 클래스가 "인터페이스"를 구현한다는 의도를 전달하는 데에만 사용됩니다.이 예제는 몇 가지 일반적인 함수와 설명서에서 작동합니다. 클래스.)

;; Implementation of a sorted-set class

(defclass sorted-set (collection)
  ((predicate
    :initarg :predicate
    :reader sorted-set-predicate)
   (test
    :initarg :test
    :initform 'eql
    :reader sorted-set-test)
   (elements
    :initform '()
    :accessor sorted-set-elements
    ;; We can "implement" the COLLECTION-ELEMENTS function, that is,
    ;; define a method on COLLECTION-ELEMENTS, simply by making it
    ;; a reader (or accessor) for the slot.
    :reader collection-elements)))

(defmethod collection-add ((ss sorted-set) element)
  (unless (member element (sorted-set-elements ss)
                  :test (sorted-set-test ss))
    (setf (sorted-set-elements ss)
          (merge 'list
                 (list element)
                 (sorted-set-elements ss)
                 (sorted-set-predicate ss)))))

(defmethod collection-remove ((ss sorted-set) element)
  (setf (sorted-set-elements ss)
        (delete element (sorted-set-elements ss))))

마지막으로, "인터페이스"함수를 사용할 때 sorted-set 클래스의 인스턴스를 사용하는 모습을 볼 수 있습니다.

(let ((ss (make-instance 'sorted-set :predicate '<)))
  (collection-add ss 3)
  (collection-add ss 4)
  (collection-add ss 5)
  (collection-add ss 3)
  (collection-remove ss 5)
  (collection-elements ss))
;; => (3 4)