common-lisp
Variabili lessicali vs speciali

Le variabili speciali globali sono speciali ovunque

Quindi queste variabili useranno il binding dinamico.

(defparameter count 0)
;; All uses of count will refer to this one 

(defun handle-number (number)
  (incf count)
  (format t "~&~d~%" number))
  
(dotimes (count 4)
  ;; count is shadowed, but still special
  (handle-number count))
  
(format t "~&Calls: ~d~%" count)
==>
0
2
Calls: 0

Assegna a variabili speciali nomi distinti per evitare questo problema:

(defparameter *count* 0)

(defun handle-number (number)
  (incf *count*)
  (format t "~&~d~%" number))
  
(dotimes (count 4)
  (handle-number count))
  
(format t "~&Calls: ~d~%" *count*)
==>
0
1
2
3
Calls: 4

Nota 1: non è possibile rendere una variabile globale non speciale in un determinato ambito. Non esiste una dichiarazione per rendere una variabile lessicale .

Nota 2: è possibile dichiarare una variabile speciale in un contesto locale utilizzando la dichiarazione special . Se non esiste una dichiarazione speciale globale per quella variabile, la dichiarazione è solo localmente e può essere ombreggiata.

(defun bar ()
  (declare (special a))
  a)                       ; value of A is looked up from the dynamic binding

(defun foo ()
  (let ((a 42))            ; <- this variable A is special and
                           ;    dynamically bound
    (declare (special a))
    (list (bar)
          (let ((a 0))     ; <- this variable A is lexical
            (bar)))))


> (foo)
(42 42)