scheme
विभिन्न सॉर्टिंग एल्गोरिदम का कार्यान्वयन

जल्दी से सुलझाएं

क्विकॉर्ट O(n log n) की एक औसत केस जटिलता O(n log n) और O(n^2) सबसे खराब स्थिति जटिलता के साथ एक सामान्य सॉर्टिंग एल्गोरिथ्म है। अन्य O(n log n) विधियों पर इसका लाभ यह है कि इसे अंदर-बाहर निष्पादित किया जा सकता है।

क्विकॉर्ट एक चुने हुए धुरी मूल्य पर इनपुट को विभाजित करता है, सूची को उन मूल्यों में अलग करता है जो उन से कम हैं और उन मूल्यों से अधिक हैं जो धुरी से अधिक (या बराबर) हैं। सूची को विभाजित करना आसानी से filter साथ किया जाता है।

इसका उपयोग करते हुए, क्विकॉर्ट की एक योजना कार्यान्वयन निम्नलिखित की तरह लग सकता है:

(define (quicksort lst)
  (cond
    ((or (null? lst) ; empty list is sorted
         (null? (cdr lst))) ; single-element list is sorted
     lst)
    (else
      (let ((pivot (car lst)) ; Select the first element as the pivot
            (rest (cdr lst)))
        (append
          (quicksort ; Recursively sort the list of smaller values
            (filter (lambda (x) (< x pivot)) rest)) ; Select the smaller values
          (list pivot) ; Add the pivot in the middle
          (quicksort ; Recursively sort the list of larger values
            (filter (lambda (x) (>= x pivot)) rest))))))) ; Select the larger and equal values

मर्ज़ सॉर्ट

मर्ज क्रमबद्ध औसत मामले जटिलता के साथ एक आम छँटाई एल्गोरिथ्म है O(n log n) और की एक सबसे खराब स्थिति जटिलता O(n log n) । यद्यपि इसे इन-प्लेस निष्पादित नहीं किया जा सकता है, यह सभी मामलों में O(n log n) जटिलता की गारंटी देता है।

मर्ज सॉर्ट बार-बार इनपुट को दो में विभाजित करता है, जब तक कि एक खाली सूची या एकल-तत्व सूची नहीं पहुंच जाती है। बंटवारे के पेड़ के नीचे तक पहुंचने के बाद, यह फिर से अपने तरीके से काम करता है, दो छंटे हुए बंटवारे को एक दूसरे में विलय कर देता है, जब तक कि एक एकल छंटनी सूची शेष न हो।

इसका उपयोग करते हुए, मर्ज सॉर्ट का एक योजना कार्यान्वयन निम्नलिखित की तरह लग सकता है:

;; Merge two sorted lists into a single sorted list
(define (merge list1 list2)
  (cond
    ((null? list1)
     list2)
    ((null? list2)
     list1)
    (else
      (let ((head1 (car list1))
            (head2 (car list2)))
        ; Add the smaller element to the front of the merge list
        (if (<= head1 head2)
          (cons
            head1
            ; Recursively merge
            (merge (cdr list1) list2))
          (cons
            head2
            ; Recursively merge
            (merge list1 (cdr list2))))))))

(define (split-list lst)
  (let ((half (quotient (length lst) 2)))
    ; Create a pair of the first and second halves of the list
    (cons
      (take lst half)
      (drop lst half))))

(define (merge-sort lst)
  (cond
    ((or (null? lst) ; empty list is sorted, so merge up
         (null? (cdr lst))) ; single-element list is sorted, so merge up
     lst)
    (else
      (let ((halves (split-list lst)))
        ; Recursively split until the bottom, then merge back up to sort
        (merge (merge-sort (car halves))
               (merge-sort (cdr halves)))))))