ABAP
Expressions régulières

Remplacer

L'instruction REPLACE peut fonctionner directement avec des expressions régulières:

DATA(lv_test) = 'The quick brown fox'.
REPLACE ALL OCCURRENCES OF REGEX '\wo' IN lv_test WITH 'XX'.

La variable lv_test évaluera à The quick bXXwn XXx .

Recherche

L'instruction FIND peut fonctionner directement avec des expressions régulières:

DATA(lv_test) = 'The quick brown fox'.

FIND REGEX '..ck' IN lv_test.
" sy-subrc == 0

FIND REGEX 'a[sdf]g' IN lv_test.
" sy-subrc == 4

Expressions régulières orientées objet

Pour les opérations regex plus avancées, il est préférable d'utiliser CL_ABAP_REGEX et ses classes associées.

DATA: lv_test  TYPE string,
      lo_regex TYPE REF TO cl_abap_regex.

lv_test = 'The quick brown fox'.
CREATE OBJECT lo_regex
  EXPORTING
    pattern = 'q(...)\w'.

DATA(lo_matcher) = lo_regex->create_matcher( text = lv_test ).
WRITE: / lo_matcher->find_next( ).      " X
WRITE: / lo_matcher->get_submatch( 1 ). " uic
WRITE: / lo_matcher->get_offset( ).     " 4

Évaluation des expressions régulières avec une fonction de prédicat

La fonction de prédicat matches peut être utilisée pour évaluer des chaînes à la volée sans utiliser de déclaration d'objet.

IF matches( val = 'Not a hex string'
            regex = '[0-9a-f]*' ).
  cl_demo_output=>display( 'This will not display' ).
ELSEIF matches( val = '6c6f7665'
                regex = '[0-9a-f]*' ).
  cl_demo_output=>display( 'This will display' ).
ENDIF.

Obtenir des sous-modèles à l'aide des expressions OO-Regular

En utilisant la méthode GET_SUBMATCH de la classe CL_ABAP_MATCHER , nous pouvons obtenir les données dans les groupes / sous-groupes.

Objectif: récupérer le jeton à droite du mot-clé "Type".

DATA: lv_pattern TYPE string VALUE 'type\s+(\w+)',
      lv_test TYPE string VALUE 'data lwa type mara'.

CREATE OBJECT ref_regex
  EXPORTING
        pattern     = lv_pattern
        ignore_case = c_true.

ref_regex->create_matcher(
    EXPORTING
        text    = lv_test
    RECEIVING
        matcher = ref_matcher
       ).

ref_matcher->get_submatch(
            EXPORTING
                 index = 0
            RECEIVING
                 submatch = lv_smatch.

La variable résultante lv_smatch contient la valeur MARA .