cython
Envolviendo Código C

Usando funciones de una biblioteca C personalizada

Tenemos una biblioteca de C llamada my_random que produce números aleatorios a partir de una distribución personalizada. Proporciona dos funciones que queremos usar: set_seed(long seed) y rand() (y muchas más que no necesitamos). Para usarlos en Cython necesitamos

1. definir una interfaz en el archivo .pxd y
2. llamar a la función en el archivo .pyx.

Código

test_extern.pxd

# extern blocks define interfaces for Cython to C code
cdef extern from "my_random.h":
    double rand()
    void c_set_seed "set_seed" (long seed) # rename C version of set_seed to c_set_seed to avoid naming conflict

test_extern.pyx

def set_seed (long seed):
    """Pass the seed on to the c version of set_seed in my_random."""
    c_set_seed(seed)

cpdef get_successes (int x, double threshold):
    """Create a list with x results of rand <= threshold
    
    Use the custom rand function from my_random.
    """
    cdef:
        list successes = []
        int i
    for i in range(x):
        if rand() <= threshold:
            successes.append(True)
        else:
            successes.append(False)
    return successes