ada
Números de salida
Buscar..
Introducción
Los paquetes estándar de Ada proporcionan la salida de todos los tipos numéricos. El formato de salida se puede ajustar de muchas maneras.
Observaciones
Observe cómo cada vez que un paquete genérico se crea una instancia con un tipo numérico. Además, hay dos valores predeterminados que deben configurarse para toda la instancia y también formas de anular el Width , por ejemplo, al llamar a Put con este parámetro.
Imprimir enteros, generosamente usando espacio.
Las instancias de Integer_IO tienen una variable de configuración Default_Width que tomará la cantidad de caracteres que tomará cada número de salida.
with Ada.Text_IO; use Ada.Text_IO;
procedure Print_Integer is
subtype Count is Integer range -1_000_000 .. 1_000_000;
package Count_IO is new Integer_IO (Count);
X : Count;
begin
Count_IO.Default_Width := 12;
X := Count'First;
while X < Count'Last loop
Count_IO.Put (X);
Count_IO.Put (X + 1);
New_Line;
X := X + 500_000;
end loop;
end Print_Integer;
Resultado
-1000000
-500000
0
500000
Imprimir números enteros, utilizando Base 16 (hexadecimal)
Una variable de configuración Default_Base se establece en la instancia de Ada.Text_IO.Integer_IO ; también, Default_Width se establece para que la salida no pueda tener espacio inicial.
with Ada.Text_IO; use Ada.Text_IO;
procedure Print_Hex is
subtype Count is Integer range -1_000_000 .. 1_000_000;
package Count_IO is new Integer_IO (Count);
X : Count;
begin
Count_IO.Default_Width := 1;
Count_IO.Default_Base := 16;
X := Count'First;
while X < Count'Last loop
Count_IO.Put (X);
New_Line;
X := X + 500_000;
end loop;
end Print_Hex;
Resultado
-16#F4240#
-16#7A120#
16#0#
16#7A120#
Imprimir números de punto fijo decimal, también conocido como dinero
Ada.Text_IO.Editing ofrece el formato de valores de puntos fijos decimales utilizando "cadenas de imagen". Estos describen la salida utilizando caracteres "mágicos" para separadores, signos de moneda, etc.
with Ada.Text_IO.Editing; use Ada.Text_IO;
procedure Print_Value is
Max_Count : constant := 1_000_000;
type Fruit is (Banana, Orange, Pear);
subtype Count is Integer range -Max_Count .. +Max_Count;
type Money is delta 0.001 digits 10;
package Fruit_IO is new Enumeration_IO (Fruit);
package Money_IO is new Editing.Decimal_Output
(Money,
Default_Currency => "CHF",
Default_Separator => ''');
Inventory : constant array (Fruit) of Count :=
(Banana => +27_420,
Orange => +140_600,
Pear => -10_000);
Price_List : constant array (Fruit) of Money :=
(Banana => 0.07,
Orange => 0.085,
Pear => 0.21);
Format : constant Editing.Picture :=
Editing.To_Picture ("<###BZ_ZZZ_ZZ9.99>");
begin
Fruit_IO.Default_Width := 12;
for F in Inventory'Range loop
Fruit_IO.Put (F);
Put (" | ");
Money_IO.Put (Item => Inventory (F) * Price_List (F),
Pic => Format);
New_Line;
end loop;
end Print_Value;
Resultado
BANANA | CHF 1'919.40
ORANGE | CHF 11'951.00
PEAR | (CHF 2'100.00)
Imprimir varios artículos en una línea
Combine las instancias de los paquetes _IO , use el correcto con su tipo numérico.
with Ada.Text_IO; use Ada.Text_IO;
procedure Print_Inventory is
type Fruit is (Banana, Orange, Pear);
subtype Count is Integer range -1_000_000 .. 1_000_000;
package Fruit_IO is new Enumeration_IO (Fruit);
package Count_IO is new Integer_IO (Count);
Inventory : constant array (Fruit) of Count :=
(Banana => 27_420,
Orange => 140_600,
Pear => -10_000);
begin
Fruit_IO.Default_Width := 12;
for F in Inventory'Range loop
Fruit_IO.Put (F);
Put (" | ");
Count_IO.Put (Inventory (F));
New_Line;
end loop;
end Print_Inventory;
Resultado
BANANA | 27420
ORANGE | 140600
PEAR | -10000