visual-foxpro
VFP взаимодействует с .NET.
Поиск…
Вступление
В этом разделе будет обсуждаться взаимодействие между VFP и .NET.
Использование wwDotNetBridge для запуска кода .NET
С помощью wwDotNetBridge от West Wind вы можете легко получить доступ к .NET-коду в программе VFP.
В белой бумаге есть все подробности, но этот краткий пример поможет проиллюстрировать основные шаги по запуску метода в сборке .NET.
Обратите внимание: wwDotNetBridge может напрямую обращаться к простым свойствам, таким как строки, int и т. Д. Чтобы получить доступ к более сложным структурам, таким как списки, вам сначала нужно использовать функцию CreateArray wwDotNetBridge для преобразования структуры .NET в массив VFP COM (как показано на внизу этого примера).
*!* Load WestWind .NET wrapper library (wwdotnetbridge.prg assumed to be in the search path)
IF (!wwDotNetBridge())
RETURN .F.
ENDIF
lowwDotNetBridge = CREATEOBJECT("wwDotNetBridge","V4")
*!* Load .NET Assembly (include full or relative path if necessary)
IF !lowwDotNetBridge.LoadAssembly("SomeDotNetAssembly.dll")
lcAssemblyLoadError = "LoadAssembly error: " + lowwDotNetBridge.cErrorMsg
=MESSAGEBOX(lcAssemblyLoadError, MB_ICONSTOP, "Error")
RETURN .F.
ENDIF
*!* Parameters to pass to class constructor
*!* You can pass up to 5 paramenters to the constructor
lcParameter1 = "StringParameter1"
lcParameter2 = "StringParameter2"
lnParameter3 = 3
lcParameter4 = .NULL.
*!* Get an instance of the assembly class
loAssemblyReference = lowwDotNetBridge.CreateInstance("MyDotNetProject.MyDotNetClass", ;
lcParameter1, lcParameter2, lnParameter3, lcParameter4)
IF lowwDotNetBridge.lError
lcAssemblyLoadError = "An error occurred loading the class: " + lowwDotNetBridge.cErrorMsg
RETURN .F.
ENDIF
*!* Usage Example
*!* This example runs a method that return a boolean
*!* and populates a List<string> (SomeStringList).
*!*
*!* The assembly has a public property named "LastErrorMessage"
*!* with details about any handled exceptions/problems.
IF (!loAssemblyReference.SomePublicMethod())
msg = "There was a problem executing the method:" + CRLF + ;
loAssemblyReference.LastErrorMessage
=MESSAGEBOX(msg, MB_ICONSTOP, "Error")
RETURN .F.
ENDIF
*!* At this point the string list (SomeStringList) should be populated
*!* wwDotNetBridge can convert that list to a VFP COM array (0-based)
laVFPArrayOfStrings = lowwDotNetBridge.CreateArray()
laVFPArrayOfStrings.FromEnumerable(loAssemblyReference.SomeStringList)
FOR x = 0 TO laVFPArrayOfStrings.Count-1
? laVFPArrayOfStrings.Item(x)
ENDFOR
Modified text is an extract of the original Stack Overflow Documentation
Лицензировано согласно CC BY-SA 3.0
Не связан с Stack Overflow