batch-file
Пакетные файлы и гибриды Powershell

Запуск Powershell с временными файлами

Это упоминалось в других гибридных темах снова и снова. Старая школа, но простой способ запустить Powershell:

• echo ИНГ сценарий Powershell во временный сценарий
• Выполнить временный скрипт
• Необязательно удалить временный скрипт

Это образец сценария.

@echo off
echo powershell-command>Temp.ps1
echo another line>>Temp.ps1
    rem echo the script into a temporary file

powershell -File Temp.ps1
    rem execute the temporary script

del Temp.ps1
    rem Optionally remove the temporary script

Для вышеописанного метода требуется множество выражений echo если требуется длинный скрипт, вот лучший метод, предложенный @Aacini

@echo off
setlocal

    rem Get the number of the "<resource>" line
for /F "delims=:" %%a in ('findstr /N "<resource>" "%~F0"') do set "start=%%a"

    rem Skip such number of lines and show the rest of this file
(for /F "usebackq skip=%start% delims=" %%a in ("%~F0") do echo %%a) > Temp.ps1

powershell -File Temp.ps1
del /f /s /q Temp.ps1

goto :EOF

<resource>
PS
Powershell script

Используйте команду POWERSHELL для выполнения 1-строчной команды Powershell

Используя команду POWERSHELL , мы можем выполнить команду из 1 строки непосредственно из пакетного скрипта без какого-либо временного файла.

Вот синтаксис.

powershell.exe -Command <yourPowershellCommandHere>

Вы также можете включить другие флаги, например -Nologo для улучшения фактического результата.

Powershell / пакетный гибрид без временных файлов

Это подход, предложенный пользователем roquo, который также может обрабатывать аргументы командной строки:

<# : batch portion
@echo off & setlocal

(for %%I in ("%~f0";%*) do @echo(%%~I) | ^
powershell -noprofile "$argv = $input | ?{$_}; iex (${%~f0} | out-string)"

goto :EOF
: end batch / begin powershell #>

"Result:"
$argv | %{ "`$argv[{0}]: $_" -f $i++ }

называется так:

psbatch.bat arg1 "Это arg2" arg3

будет производить:

Result:
$argv[0]: C:\Users\rojo\Desktop\test.bat
$argv[1]: arg1
$argv[2]: This is arg2
$argv[3]: arg3